configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(collectd, m4_esyscmd(./version-gen.sh))
   3 AC_CONFIG_SRCDIR(src/collectd.c)
   4 AC_CONFIG_HEADERS(src/config.h)
   5 AM_INIT_AUTOMAKE(dist-bzip2)
   6 AC_LANG(C)
   7
   8 AC_PREFIX_DEFAULT("/opt/collectd")
   9
  10 AC_SYS_LARGEFILE
  11
  12 #
  13 # Checks for programs.
  14 #
  15 AC_PROG_CC
  16 AC_PROG_CPP
  17 AC_PROG_INSTALL
  18 AC_PROG_LN_S
  19 AC_PROG_MAKE_SET
  20 AM_PROG_CC_C_O
  21 AM_CONDITIONAL(COMPILER_IS_GCC, test "x$GCC" = "xyes")
  22
  23 dnl configure libtool
  24 AC_DISABLE_STATIC
  25 AC_LIBLTDL_CONVENIENCE
  26 AC_SUBST(LTDLINCL)
  27 AC_SUBST(LIBLTDL)
  28 AC_LIBTOOL_DLOPEN
  29 AC_PROG_LIBTOOL
  30 AC_PROG_LEX
  31 AC_PROG_YACC
  32 PKG_PROG_PKG_CONFIG
  33 AC_CONFIG_SUBDIRS(libltdl)
  34
  35 AC_MSG_CHECKING([for kernel type ($host_os)])
  36 case $host_os in
  37         *linux*)
  38         AC_DEFINE([KERNEL_LINUX], 1, [True if program is to be compiled for a Linux kernel])
  39         ac_system="Linux"
  40         ;;
  41         *solaris*)
  42         AC_DEFINE([KERNEL_SOLARIS], 1, [True if program is to be compiled for a Solaris kernel])
  43         ac_system="Solaris"
  44         ;;
  45         *darwin*)
  46         ac_system="Darwin"
  47         ;;
  48         *openbsd*)
  49         ac_system="OpenBSD"
  50         ;;
  51         *)
  52         ac_system="unknown"
  53 esac
  54 AC_MSG_RESULT([$ac_system])
  55
  56 if test "x$ac_system" = "xLinux"
  57 then
  58         AC_ARG_VAR([KERNEL_DIR], [path to Linux kernel sources])
  59         if test -z "$KERNEL_DIR"
  60         then
  61                 KERNEL_DIR="/lib/modules/`uname -r`/source"
  62         fi
  63
  64         KERNEL_CFLAGS="-I$KERNEL_DIR/include"
  65         AC_SUBST(KERNEL_CFLAGS)
  66 fi
  67
  68 #
  69 # Checks for header files.
  70 #
  71 AC_HEADER_STDC
  72 AC_HEADER_SYS_WAIT
  73 AC_HEADER_DIRENT
  74
  75 AC_CHECK_HEADERS(stdio.h stdint.h stdbool.h errno.h math.h stdarg.h syslog.h fcntl.h signal.h assert.h sys/types.h sys/socket.h sys/select.h poll.h netdb.h arpa/inet.h sys/resource.h sys/param.h kstat.h regex.h sys/ioctl.h endian.h sys/isa_defs.h)
  76
  77 # For ping library
  78 AC_CHECK_HEADERS(netinet/in_systm.h, [], [],
  79 [#if HAVE_STDINT_H
  80 # include <stdint.h>
  81 #endif
  82 #if HAVE_SYS_TYPES_H
  83 # include <sys/types.h>
  84 #endif
  85 ])
  86 AC_CHECK_HEADERS(netinet/in.h, [], [],
  87 [#if HAVE_STDINT_H
  88 # include <stdint.h>
  89 #endif
  90 #if HAVE_SYS_TYPES_H
  91 # include <sys/types.h>
  92 #endif
  93 #if HAVE_NETINET_IN_SYSTM_H
  94 # include <netinet/in_systm.h>
  95 #endif
  96 ])
  97 AC_CHECK_HEADERS(netinet/ip.h, [], [],
  98 [#if HAVE_STDINT_H
  99 # include <stdint.h>
 100 #endif
 101 #if HAVE_SYS_TYPES_H
 102 # include <sys/types.h>
 103 #endif
 104 #if HAVE_NETINET_IN_SYSTM_H
 105 # include <netinet/in_systm.h>
 106 #endif
 107 #if HAVE_NETINET_IN_H
 108 # include <netinet/in.h>
 109 #endif
 110 ])
 111 AC_CHECK_HEADERS(netinet/ip_icmp.h, [], [],
 112 [#if HAVE_STDINT_H
 113 # include <stdint.h>
 114 #endif
 115 #if HAVE_SYS_TYPES_H
 116 # include <sys/types.h>
 117 #endif
 118 #if HAVE_NETINET_IN_SYSTM_H
 119 # include <netinet/in_systm.h>
 120 #endif
 121 #if HAVE_NETINET_IN_H
 122 # include <netinet/in.h>
 123 #endif
 124 #if HAVE_NETINET_IP_H
 125 # include <netinet/ip.h>
 126 #endif
 127 ])
 128 AC_CHECK_HEADERS(netinet/ip_var.h, [], [],
 129 [#if HAVE_STDINT_H
 130 # include <stdint.h>
 131 #endif
 132 #if HAVE_SYS_TYPES_H
 133 # include <sys/types.h>
 134 #endif
 135 #if HAVE_NETINET_IN_SYSTM_H
 136 # include <netinet/in_systm.h>
 137 #endif
 138 #if HAVE_NETINET_IN_H
 139 # include <netinet/in.h>
 140 #endif
 141 #if HAVE_NETINET_IP_H
 142 # include <netinet/ip.h>
 143 #endif
 144 ])
 145 AC_CHECK_HEADERS(netinet/ip6.h, [], [],
 146 [#if HAVE_STDINT_H
 147 # include <stdint.h>
 148 #endif
 149 #if HAVE_SYS_TYPES_H
 150 # include <sys/types.h>
 151 #endif
 152 #if HAVE_NETINET_IN_SYSTM_H
 153 # include <netinet/in_systm.h>
 154 #endif
 155 #if HAVE_NETINET_IN_H
 156 # include <netinet/in.h>
 157 #endif
 158 ])
 159 AC_CHECK_HEADERS(netinet/icmp6.h, [], [],
 160 [#if HAVE_STDINT_H
 161 # include <stdint.h>
 162 #endif
 163 #if HAVE_SYS_TYPES_H
 164 # include <sys/types.h>
 165 #endif
 166 #if HAVE_NETINET_IN_SYSTM_H
 167 # include <netinet/in_systm.h>
 168 #endif
 169 #if HAVE_NETINET_IN_H
 170 # include <netinet/in.h>
 171 #endif
 172 #if HAVE_NETINET_IP6_H
 173 # include <netinet/ip6.h>
 174 #endif
 175 ])
 176 AC_CHECK_HEADERS(netinet/tcp.h, [], [],
 177 [#if HAVE_STDINT_H
 178 # include <stdint.h>
 179 #endif
 180 #if HAVE_SYS_TYPES_H
 181 # include <sys/types.h>
 182 #endif
 183 #if HAVE_NETINET_IN_SYSTM_H
 184 # include <netinet/in_systm.h>
 185 #endif
 186 #if HAVE_NETINET_IN_H
 187 # include <netinet/in.h>
 188 #endif
 189 #if HAVE_NETINET_IP_H
 190 # include <netinet/ip.h>
 191 #endif
 192 ])
 193 AC_CHECK_HEADERS(netinet/udp.h, [], [],
 194 [#if HAVE_STDINT_H
 195 # include <stdint.h>
 196 #endif
 197 #if HAVE_SYS_TYPES_H
 198 # include <sys/types.h>
 199 #endif
 200 #if HAVE_NETINET_IN_SYSTM_H
 201 # include <netinet/in_systm.h>
 202 #endif
 203 #if HAVE_NETINET_IN_H
 204 # include <netinet/in.h>
 205 #endif
 206 #if HAVE_NETINET_IP_H
 207 # include <netinet/ip.h>
 208 #endif
 209 ])
 210
 211 # For cpu modules
 212 AC_CHECK_HEADERS(sys/dkstat.h)
 213 if test "x$ac_system" = "xDarwin"
 214 then
 215         AC_CHECK_HEADERS(mach/mach_init.h mach/host_priv.h mach/mach_error.h mach/mach_host.h mach/mach_port.h mach/mach_types.h mach/message.h mach/processor_set.h mach/processor.h mach/processor_info.h mach/task.h mach/thread_act.h mach/vm_region.h mach/vm_map.h mach/vm_prot.h mach/vm_statistics.h mach/kern_return.h)
 216         AC_CHECK_HEADERS(CoreFoundation/CoreFoundation.h IOKit/IOKitLib.h IOKit/IOTypes.h IOKit/ps/IOPSKeys.h IOKit/IOBSD.h IOKit/storage/IOBlockStorageDriver.h)
 217 fi
 218 AC_CHECK_HEADERS(sys/sysctl.h, [], [],
 219 [
 220 #if HAVE_SYS_TYPES_H
 221 #  include <sys/types.h>
 222 #endif
 223 #if HAVE_SYS_PARAM_H
 224 # include <sys/param.h>
 225 #endif
 226 ])
 227
 228 # For hddtemp module
 229 AC_CHECK_HEADERS(linux/major.h libgen.h)
 230
 231 # For the battery plugin
 232 AC_CHECK_HEADERS(IOKit/ps/IOPowerSources.h, [], [],
 233 [
 234 #if HAVE_IOKIT_IOKITLIB_H
 235 #  include <IOKit/IOKitLib.h>
 236 #endif
 237 #if HAVE_IOKIT_IOTYPES_H
 238 #  include <IOKit/IOTypes.h>
 239 #endif
 240 ])
 241
 242 # For the swap module
 243 AC_CHECK_HEADERS(sys/swap.h, [], [],
 244 [
 245 #if HAVE_SYS_TYPES_H
 246 #  include <sys/types.h>
 247 #endif
 248 #if HAVE_SYS_PARAM_H
 249 # include <sys/param.h>
 250 #endif
 251 ])
 252
 253 # For load module
 254 # For the processes plugin
 255 # For users module
 256 AC_CHECK_HEADERS(sys/loadavg.h linux/config.h utmp.h utmpx.h)
 257
 258 # For interface plugin
 259 AC_CHECK_HEADERS(ifaddrs.h)
 260 AC_CHECK_HEADERS(net/if.h, [], [],
 261 [
 262 #if HAVE_SYS_TYPES_H
 263 #  include <sys/types.h>
 264 #endif
 265 #if HAVE_SYS_SOCKET_H
 266 #  include <sys/socket.h>
 267 #endif
 268 ])
 269 AC_CHECK_HEADERS(linux/if.h, [], [],
 270 [
 271 #if HAVE_SYS_TYPES_H
 272 #  include <sys/types.h>
 273 #endif
 274 #if HAVE_SYS_SOCKET_H
 275 #  include <sys/socket.h>
 276 #endif
 277 ])
 278 AC_CHECK_HEADERS(linux/netdevice.h, [], [],
 279 [
 280 #if HAVE_SYS_TYPES_H
 281 #  include <sys/types.h>
 282 #endif
 283 #if HAVE_SYS_SOCKET_H
 284 #  include <sys/socket.h>
 285 #endif
 286 #if HAVE_LINUX_IF_H
 287 # include <linux/if.h>
 288 #endif
 289 ])
 290
 291 # For ipvs module
 292 have_net_ip_vs_h="no"
 293 have_ip_vs_h="no"
 294 if test "x$ac_system" = "xLinux"
 295 then
 296         SAVE_CFLAGS=$CFLAGS
 297         CFLAGS="$CFLAGS $KERNEL_CFLAGS"
 298
 299         AC_CHECK_HEADERS(net/ip_vs.h, [have_net_ip_vs_h="yes"])
 300         AC_CHECK_HEADERS(ip_vs.h, [have_ip_vs_h="yes"])
 301
 302         CFLAGS=$SAVE_CFLAGS
 303 fi
 304
 305 # For quota module
 306 AC_CHECK_HEADERS(sys/ucred.h, [], [],
 307 [
 308 #if HAVE_SYS_TYPES_H
 309 #  include <sys/types.h>
 310 #endif
 311 #if HAVE_SYS_PARAM_H
 312 # include <sys/param.h>
 313 #endif
 314 ])
 315
 316 # For mount interface
 317 AC_CHECK_HEADERS(sys/mount.h, [], [],
 318 [
 319 #if HAVE_SYS_TYPES_H
 320 #  include <sys/types.h>
 321 #endif
 322 #if HAVE_SYS_PARAM_H
 323 # include <sys/param.h>
 324 #endif
 325 ])
 326
 327 # For the email plugin
 328 AC_CHECK_HEADERS(linux/un.h, [], [],
 329 [
 330 #if HAVE_SYS_SOCKET_H
 331 #       include <sys/socket.h>
 332 #endif
 333 ])
 334
 335 AC_CHECK_HEADERS(pwd.h grp.h sys/un.h ctype.h limits.h sys/quota.h xfs/xqm.h fs_info.h fshelp.h paths.h mntent.h mnttab.h sys/fstyp.h sys/fs_types.h sys/mntent.h sys/mnttab.h sys/statfs.h sys/statvfs.h sys/vfs.h sys/vfstab.h kvm.h wordexp.h)
 336
 337 # For the dns plugin
 338 AC_CHECK_HEADERS(arpa/nameser.h)
 339 AC_CHECK_HEADERS(arpa/nameser_compat.h, [], [],
 340 [
 341 #if HAVE_ARPA_NAMESER_H
 342 # include <arpa/nameser.h>
 343 #endif
 344 ])
 345
 346 AC_CHECK_HEADERS(net/if_arp.h, [], [],
 347 [#if HAVE_SYS_SOCKET_H
 348 # include <sys/socket.h>
 349 #endif
 350 ])
 351 AC_CHECK_HEADERS(net/ppp_defs.h)
 352 AC_CHECK_HEADERS(net/if_ppp.h, [], [],
 353 [#if HAVE_NET_PPP_DEFS_H
 354 # include <net/ppp_defs.h>
 355 #endif
 356 ])
 357 AC_CHECK_HEADERS(netinet/if_ether.h, [], [],
 358 [#if HAVE_STDINT_H
 359 # include <stdint.h>
 360 #endif
 361 #if HAVE_SYS_TYPES_H
 362 # include <sys/types.h>
 363 #endif
 364 #if HAVE_SYS_SOCKET_H
 365 # include <sys/socket.h>
 366 #endif
 367 #if HAVE_NET_IF_H
 368 # include <net/if.h>
 369 #endif
 370 #if HAVE_NETINET_IN_H
 371 # include <netinet/in.h>
 372 #endif
 373 ])
 374
 375 # For the multimeter plugin
 376 have_termios_h="no"
 377 AC_CHECK_HEADERS(termios.h, [have_termios_h="yes"])
 378
 379 #
 380 # Checks for typedefs, structures, and compiler characteristics.
 381 #
 382 AC_C_CONST
 383 AC_TYPE_PID_T
 384 AC_TYPE_SIZE_T
 385 AC_TYPE_UID_T
 386 AC_HEADER_TIME
 387
 388 #
 389 # Checks for library functions.
 390 #
 391 AC_PROG_GCC_TRADITIONAL
 392 AC_CHECK_FUNCS(gettimeofday select strdup strtol getaddrinfo getnameinfo strchr memcpy strstr strcmp strncmp strncpy strlen strncasecmp strcasecmp openlog closelog)
 393
 394 AC_FUNC_STRERROR_R
 395
 396 AC_CACHE_CHECK([for strtok_r],
 397   [have_strtok_r_default],
 398   AC_LINK_IFELSE(
 399     AC_LANG_PROGRAM(
 400     [[[[
 401 #include <stdlib.h>
 402 #include <stdio.h>
 403 #include <string.h>
 404     ]]]],
 405     [[[[
 406       char buffer[] = "foo,bar,baz";
 407       char *token;
 408       char *dummy;
 409       char *saveptr;
 410
 411       dummy = buffer;
 412       saveptr = NULL;
 413       while ((token = strtok_r (dummy, ",", &saveptr)) != NULL)
 414       {
 415         dummy = NULL;
 416         printf ("token = %s;\n", token);
 417       }
 418     ]]]]),
 419     [have_strtok_r_default="yes"],
 420     [have_strtok_r_default="no"]
 421   )
 422 )
 423
 424 if test "x$have_strtok_r_default" = "xno"
 425 then
 426   SAVE_CFLAGS="$CFLAGS"
 427   CFLAGS="$CFLAGS -D_REENTRANT=1"
 428
 429   AC_CACHE_CHECK([if strtok_r needs _REENTRANT],
 430     [have_strtok_r_reentrant],
 431     AC_LINK_IFELSE(
 432       AC_LANG_PROGRAM(
 433       [[[[
 434 #include <stdlib.h>
 435 #include <stdio.h>
 436 #include <string.h>
 437       ]]]],
 438       [[[[
 439         char buffer[] = "foo,bar,baz";
 440         char *token;
 441         char *dummy;
 442         char *saveptr;
 443
 444         dummy = buffer;
 445         saveptr = NULL;
 446         while ((token = strtok_r (dummy, ",", &saveptr)) != NULL)
 447         {
 448           dummy = NULL;
 449           printf ("token = %s;\n", token);
 450         }
 451       ]]]]),
 452       [have_strtok_r_reentrant="yes"],
 453       [AC_MSG_FAILURE([strtok_r isn't available. Please file a bugreport!])]
 454     )
 455   )
 456 fi
 457
 458 AC_CHECK_FUNCS(getpwnam_r getgrnam_r setgroups regcomp regerror regexec regfree)
 459
 460 socket_needs_socket="no"
 461 AC_CHECK_FUNCS(socket, [], AC_CHECK_LIB(socket, socket, [socket_needs_socket="yes"], AC_MSG_ERROR(cannot find socket)))
 462 AM_CONDITIONAL(BUILD_WITH_LIBSOCKET, test "x$socket_needs_socket" = "xyes")
 463
 464 nanosleep_needs_rt="no"
 465 AC_CHECK_FUNCS(nanosleep, [], AC_CHECK_LIB(rt, nanosleep, [nanosleep_needs_rt="yes"], AC_MSG_ERROR(cannot find nanosleep)))
 466 AM_CONDITIONAL(BUILD_WITH_LIBRT, test "x$nanosleep_needs_rt" = "xyes")
 467
 468 AC_CHECK_FUNCS(sysctlbyname, [have_sysctlbyname="yes"], [have_sysctlbyname="no"])
 469 AC_CHECK_FUNCS(host_statistics, [have_host_statistics="yes"], [have_host_statistics="no"])
 470 AC_CHECK_FUNCS(processor_info, [have_processor_info="yes"], [have_processor_info="no"])
 471 AC_CHECK_FUNCS(thread_info, [have_thread_info="yes"], [have_thread_info="no"])
 472 AC_CHECK_FUNCS(statfs, [have_statfs="yes"], [have_statfs="no"])
 473 AC_CHECK_FUNCS(statvfs, [have_statvfs="yes"], [have_statvfs="no"])
 474 AC_CHECK_FUNCS(getifaddrs, [have_getifaddrs="yes"], [have_getifaddrs="no"])
 475 AC_CHECK_FUNCS(syslog, [have_syslog="yes"], [have_syslog="no"])
 476 AC_CHECK_FUNCS(getutent, [have_getutent="yes"], [have_getutent="no"])
 477 AC_CHECK_FUNCS(getutxent, [have_getutxent="yes"], [have_getutxent="no"])
 478
 479 # For load module
 480 AC_CHECK_FUNCS(getloadavg, [have_getloadavg="yes"], [have_getloadavg="no"])
 481
 482 # Check for NAN
 483 AC_ARG_WITH(nan-emulation, [AS_HELP_STRING([--with-nan-emulation], [use emulated NAN. For crosscompiling only.])],
 484 [
 485  if test "x$withval" = "xno"; then
 486          nan_type="none"
 487  else if test "x$withval" = "xyes"; then
 488          nan_type="zero"
 489  else
 490          nan_type="$withval"
 491  fi; fi
 492 ],
 493 [nan_type="none"])
 494 if test "x$nan_type" = "xnone"; then
 495   AC_CACHE_CHECK([whether NAN is defined by default],
 496     [have_nan_default],
 497     AC_COMPILE_IFELSE(
 498       AC_LANG_PROGRAM(
 499       [[
 500 #include <stdlib.h>
 501 #include <math.h>
 502 static float foo = NAN;
 503       ]],
 504       [[
 505        if (isnan (foo))
 506         return 0;
 507        else
 508         return 1;
 509       ]]),
 510       [have_nan_default="yes"],
 511       [have_nan_default="no"]
 512     )
 513   )
 514   if test "x$have_nan_default" = "xyes"
 515   then
 516     nan_type="default"
 517   fi
 518 fi
 519 if test "x$nan_type" = "xnone"; then
 520   AC_CACHE_CHECK([whether NAN is defined by __USE_ISOC99],
 521     [have_nan_isoc],
 522     AC_COMPILE_IFELSE(
 523       AC_LANG_PROGRAM(
 524       [[
 525 #include <stdlib.h>
 526 #define __USE_ISOC99 1
 527 #include <math.h>
 528 static float foo = NAN;
 529       ]],
 530       [[
 531        if (isnan (foo))
 532         return 0;
 533        else
 534         return 1;
 535       ]]),
 536       [have_nan_isoc="yes"],
 537       [have_nan_isoc="no"]
 538     )
 539   )
 540   if test "x$have_nan_isoc" = "xyes"
 541   then
 542     nan_type="isoc99"
 543   fi
 544 fi
 545 if test "x$nan_type" = "xnone"; then
 546   AC_CACHE_CHECK([whether NAN can be defined by 0/0],
 547     [have_nan_zero],
 548     AC_RUN_IFELSE(
 549       AC_LANG_PROGRAM(
 550       [[
 551 #include <stdlib.h>
 552 #include <math.h>
 553 #ifdef NAN
 554 # undef NAN
 555 #endif
 556 #define NAN (0.0 / 0.0)
 557 #ifndef isnan
 558 # define isnan(f) ((f) != (f))
 559 #endif
 560 static float foo = NAN;
 561       ]],
 562       [[
 563        if (isnan (foo))
 564         return 0;
 565        else
 566         return 1;
 567       ]]),
 568       [have_nan_zero="yes"],
 569       [have_nan_zero="no"]
 570     )
 571   )
 572   if test "x$have_nan_zero" = "xyes"
 573   then
 574     nan_type="zero"
 575   fi
 576 fi
 577
 578 if test "x$nan_type" = "xdefault"; then
 579   AC_DEFINE(NAN_STATIC_DEFAULT, 1,
 580     [Define if NAN is defined by default and can initialize static variables.])
 581 else if test "x$nan_type" = "xisoc99"; then
 582   AC_DEFINE(NAN_STATIC_ISOC, 1,
 583     [Define if NAN is defined by __USE_ISOC99 and can initialize static variables.])
 584 else if test "x$nan_type" = "xzero"; then
 585   AC_DEFINE(NAN_ZERO_ZERO, 1,
 586     [Define if NAN can be defined as (0.0 / 0.0)])
 587 else
 588   AC_MSG_ERROR([Didn't find out how to statically initialize variables to NAN. Sorry.])
 589 fi; fi; fi
 590
 591 AC_ARG_WITH(fp-layout, [AS_HELP_STRING([--with-fp-layout], [set the memory layout of doubles. For crosscompiling only.])],
 592 [
 593  if test "x$withval" = "xnothing"; then
 594         fp_layout_type="nothing"
 595  else if test "x$withval" = "xendianflip"; then
 596         fp_layout_type="endianflip"
 597  else if test "x$withval" = "xintswap"; then
 598         fp_layout_type="intswap"
 599  else
 600         AC_MSG_ERROR([Invalid argument for --with-fp-layout. Valid arguments are: nothing, endianflip, intswap]);
 601 fi; fi; fi
 602 ],
 603 [fp_layout_type="unknown"])
 604
 605 if test "x$fp_layout_type" = "xunknown"; then
 606   AC_CACHE_CHECK([if doubles are stored in x86 representation],
 607     [fp_layout_need_nothing],
 608     AC_RUN_IFELSE(
 609       AC_LANG_PROGRAM(
 610       [[[[
 611 #include <stdlib.h>
 612 #include <stdio.h>
 613 #include <stdint.h>
 614 #include <string.h>
 615       ]]]],
 616       [[[[
 617         uint64_t i0;
 618         uint64_t i1;
 619         uint8_t c[8];
 620         double d;
 621
 622         d = 8.642135e130;
 623         memcpy ((void *) &i0, (void *) &d, 8);
 624
 625         i1 = i0;
 626         memcpy ((void *) c, (void *) &i1, 8);
 627
 628         if ((c[0] == 0x2f) && (c[1] == 0x25)
 629                         && (c[2] == 0xc0) && (c[3] == 0xc7)
 630                         && (c[4] == 0x43) && (c[5] == 0x2b)
 631                         && (c[6] == 0x1f) && (c[7] == 0x5b))
 632                 return (0);
 633         else
 634                 return (1);
 635       ]]]]),
 636       [fp_layout_need_nothing="yes"],
 637       [fp_layout_need_nothing="no"]
 638     )
 639   )
 640   if test "x$fp_layout_need_nothing" = "xyes"; then
 641     fp_layout_type="nothing"
 642   fi
 643 fi
 644 if test "x$fp_layout_type" = "xunknown"; then
 645   AC_CACHE_CHECK([if endianflip converts to x86 representation],
 646     [fp_layout_need_endianflip],
 647     AC_RUN_IFELSE(
 648       AC_LANG_PROGRAM(
 649       [[[[
 650 #include <stdlib.h>
 651 #include <stdio.h>
 652 #include <stdint.h>
 653 #include <string.h>
 654 #define endianflip(A) ((((uint64_t)(A) & 0xff00000000000000LL) >> 56) | \
 655                        (((uint64_t)(A) & 0x00ff000000000000LL) >> 40) | \
 656                        (((uint64_t)(A) & 0x0000ff0000000000LL) >> 24) | \
 657                        (((uint64_t)(A) & 0x000000ff00000000LL) >> 8)  | \
 658                        (((uint64_t)(A) & 0x00000000ff000000LL) << 8)  | \
 659                        (((uint64_t)(A) & 0x0000000000ff0000LL) << 24) | \
 660                        (((uint64_t)(A) & 0x000000000000ff00LL) << 40) | \
 661                        (((uint64_t)(A) & 0x00000000000000ffLL) << 56))
 662       ]]]],
 663       [[[[
 664         uint64_t i0;
 665         uint64_t i1;
 666         uint8_t c[8];
 667         double d;
 668
 669         d = 8.642135e130;
 670         memcpy ((void *) &i0, (void *) &d, 8);
 671
 672         i1 = endianflip (i0);
 673         memcpy ((void *) c, (void *) &i1, 8);
 674
 675         if ((c[0] == 0x2f) && (c[1] == 0x25)
 676                         && (c[2] == 0xc0) && (c[3] == 0xc7)
 677                         && (c[4] == 0x43) && (c[5] == 0x2b)
 678                         && (c[6] == 0x1f) && (c[7] == 0x5b))
 679                 return (0);
 680         else
 681                 return (1);
 682       ]]]]),
 683       [fp_layout_need_endianflip="yes"],
 684       [fp_layout_need_endianflip="no"]
 685     )
 686   )
 687   if test "x$fp_layout_need_endianflip" = "xyes"; then
 688     fp_layout_type="endianflip"
 689   fi
 690 fi
 691 if test "x$fp_layout_type" = "xunknown"; then
 692   AC_CACHE_CHECK([if intswap converts to x86 representation],
 693     [fp_layout_need_intswap],
 694     AC_RUN_IFELSE(
 695       AC_LANG_PROGRAM(
 696       [[[[
 697 #include <stdlib.h>
 698 #include <stdio.h>
 699 #include <stdint.h>
 700 #include <string.h>
 701 #define intswap(A)    ((((uint64_t)(A) & 0xffffffff00000000LL) >> 32) | \
 702                        (((uint64_t)(A) & 0x00000000ffffffffLL) << 32))
 703       ]]]],
 704       [[[[
 705         uint64_t i0;
 706         uint64_t i1;
 707         uint8_t c[8];
 708         double d;
 709
 710         d = 8.642135e130;
 711         memcpy ((void *) &i0, (void *) &d, 8);
 712
 713         i1 = intswap (i0);
 714         memcpy ((void *) c, (void *) &i1, 8);
 715
 716         if ((c[0] == 0x2f) && (c[1] == 0x25)
 717                         && (c[2] == 0xc0) && (c[3] == 0xc7)
 718                         && (c[4] == 0x43) && (c[5] == 0x2b)
 719                         && (c[6] == 0x1f) && (c[7] == 0x5b))
 720                 return (0);
 721         else
 722                 return (1);
 723       ]]]]),
 724       [fp_layout_need_intswap="yes"],
 725       [fp_layout_need_intswap="no"]
 726     )
 727   )
 728   if test "x$fp_layout_need_intswap" = "xyes"; then
 729     fp_layout_type="intswap"
 730   fi
 731 fi
 732
 733 if test "x$fp_layout_type" = "xnothing"; then
 734   AC_DEFINE(FP_LAYOUT_NEED_NOTHING, 1,
 735   [Define if doubles are stored in x86 representation.])
 736 else if test "x$fp_layout_type" = "xendianflip"; then
 737   AC_DEFINE(FP_LAYOUT_NEED_ENDIANFLIP, 1,
 738   [Define if endianflip is needed to convert to x86 representation.])
 739 else if test "x$fp_layout_type" = "xintswap"; then
 740   AC_DEFINE(FP_LAYOUT_NEED_INTSWAP, 1,
 741   [Define if intswap is needed to convert to x86 representation.])
 742 else
 743   AC_MSG_ERROR([Didn't find out how doubles are stored in memory. Sorry.])
 744 fi; fi; fi
 745
 746 have_getfsstat="no"
 747 AC_CHECK_FUNCS(getfsstat, [have_getfsstat="yes"])
 748 have_getvfsstat="no"
 749 AC_CHECK_FUNCS(getvfsstat, [have_getvfsstat="yes"])
 750 have_listmntent="no"
 751 AC_CHECK_FUNCS(listmntent, [have_listmntent="yes"])
 752
 753 have_getmntent="no"
 754 AC_CHECK_FUNCS(getmntent, [have_getmntent="c"])
 755 if test "x$have_getmntent" = "xno"; then
 756         AC_CHECK_LIB(sun, getmntent, [have_getmntent="sun"])
 757 fi
 758 if test "x$have_getmntent" = "xno"; then
 759         AC_CHECK_LIB(seq, getmntent, [have_getmntent="seq"])
 760 fi
 761 if test "x$have_getmntent" = "xno"; then
 762         AC_CHECK_LIB(gen, getmntent, [have_getmntent="gen"])
 763 fi
 764
 765 if test "x$have_getmntent" = "xc"; then
 766         AC_CACHE_CHECK([whether getmntent takes one argument],
 767                 [have_one_getmntent],
 768                 AC_COMPILE_IFELSE(
 769                         AC_LANG_PROGRAM([[AC_INCLUDES_DEFAULT
 770 #include <mntent.h>
 771 #include "$srcdir/src/utils_mount.h"]],
 772                                 [[
 773                                  FILE *fh;
 774                                  struct mntent *me;
 775                                  fh = setmntent ("/etc/mtab", "r");
 776                                  me = getmntent (fh);
 777                                 ]]
 778                         ),
 779                         [have_one_getmntent="yes"],
 780                         [have_one_getmntent="no"]
 781                 )
 782         )
 783         AC_CACHE_CHECK([whether getmntent takes two arguments],
 784                 [have_two_getmntent],
 785                 AC_COMPILE_IFELSE(
 786                         AC_LANG_PROGRAM([[AC_INCLUDES_DEFAULT
 787 #include <sys/mnttab.h>
 788 #include "$srcdir/src/utils_mount.h"]],
 789                                 [[
 790                                  FILE *fh;
 791                                  struct mnttab mt;
 792                                  int status;
 793                                  fh = fopen ("/etc/mnttab", "r");
 794                                  status = getmntent (fh, &mt);
 795                                 ]]
 796                         ),
 797                         [have_two_getmntent="yes"],
 798                         [have_two_getmntent="no"]
 799                 )
 800         )
 801 fi
 802
 803 # Check for different versions of `getmntent' here..
 804
 805 if test "x$have_getmntent" = "xc"; then
 806         if test "x$have_one_getmntent" = "xyes"; then
 807                 AC_DEFINE(HAVE_ONE_GETMNTENT, 1,
 808                           [Define if the function getmntent exists and takes one argument.])
 809         fi
 810         if test "x$have_two_getmntent" = "xyes"; then
 811                 AC_DEFINE(HAVE_TWO_GETMNTENT, 1,
 812                           [Define if the function getmntent exists and takes two arguments.])
 813         fi
 814 fi
 815 if test "x$have_getmntent" = "xsun"; then
 816         AC_DEFINE(HAVE_SUN_GETMNTENT, 1,
 817                   [Define if the function getmntent exists. It's the version from libsun.])
 818 fi
 819 if test "x$have_getmntent" = "xseq"; then
 820         AC_DEFINE(HAVE_SEQ_GETMNTENT, 1,
 821                   [Define if the function getmntent exists. It's the version from libseq.])
 822 fi
 823 if test "x$have_getmntent" = "xgen"; then
 824         AC_DEFINE(HAVE_GEN_GETMNTENT, 1,
 825                   [Define if the function getmntent exists. It's the version from libgen.])
 826 fi
 827
 828 # Check for structures
 829 AC_CHECK_MEMBERS([struct if_data.ifi_ibytes, struct if_data.ifi_opackets, struct if_data.ifi_ierrors],
 830         [AC_DEFINE(HAVE_STRUCT_IF_DATA, 1, [Define if struct if_data exists and is usable.])],
 831         [],
 832         [
 833         #include <sys/types.h>
 834         #include <sys/socket.h>
 835         #include <net/if.h>
 836         ])
 837 AC_CHECK_MEMBERS([struct net_device_stats.rx_bytes, struct net_device_stats.tx_packets, struct net_device_stats.rx_errors],
 838         [AC_DEFINE(HAVE_STRUCT_NET_DEVICE_STATS, 1, [Define if struct net_device_stats exists and is usable.])],
 839         [],
 840         [
 841         #include <sys/types.h>
 842         #include <sys/socket.h>
 843         #include <linux/if.h>
 844         #include <linux/netdevice.h>
 845         ])
 846
 847 AC_CHECK_MEMBERS([struct udphdr.uh_dport, struct udphdr.uh_sport], [], [],
 848 [#if HAVE_STDINT_H
 849 # include <stdint.h>
 850 #endif
 851 #if HAVE_SYS_TYPES_H
 852 # include <sys/types.h>
 853 #endif
 854 #if HAVE_NETINET_IN_SYSTM_H
 855 # include <netinet/in_systm.h>
 856 #endif
 857 #if HAVE_NETINET_IN_H
 858 # include <netinet/in.h>
 859 #endif
 860 #if HAVE_NETINET_IP_H
 861 # include <netinet/ip.h>
 862 #endif
 863 #if HAVE_NETINET_UDP_H
 864 # include <netinet/udp.h>
 865 #endif
 866 ])
 867 AC_CHECK_MEMBERS([struct udphdr.dest, struct udphdr.source], [], [],
 868 [#if HAVE_STDINT_H
 869 # include <stdint.h>
 870 #endif
 871 #if HAVE_SYS_TYPES_H
 872 # include <sys/types.h>
 873 #endif
 874 #if HAVE_NETINET_IN_SYSTM_H
 875 # include <netinet/in_systm.h>
 876 #endif
 877 #if HAVE_NETINET_IN_H
 878 # include <netinet/in.h>
 879 #endif
 880 #if HAVE_NETINET_IP_H
 881 # include <netinet/ip.h>
 882 #endif
 883 #if HAVE_NETINET_UDP_H
 884 # include <netinet/udp.h>
 885 #endif
 886 ])
 887
 888 AC_CHECK_MEMBERS([kstat_io_t.nwritten, kstat_io_t.writes, kstat_io_t.nwrites, kstat_io_t.wtime],
 889         [],
 890         [],
 891         [
 892 #if HAVE_KSTAT_H
 893 # include <kstat.h>
 894 #endif
 895         ])
 896
 897 #
 898 # Checks for libraries begin here
 899 #
 900 with_libresolv="yes"
 901 AC_CHECK_LIB(resolv, res_search,
 902 [
 903         AC_DEFINE(HAVE_LIBRESOLV, 1, [Define to 1 if you have the 'resolv' library (-lresolv).])
 904 ],
 905 [with_libresolv="no"])
 906 AM_CONDITIONAL(BUILD_WITH_LIBRESOLV, test "x$with_libresolv" = "xyes")
 907
 908 dnl Check for HAL (hardware abstraction library)
 909 with_libhal="yes"
 910 AC_CHECK_LIB(hal,libhal_device_property_exists,
 911              [AC_DEFINE(HAVE_LIBHAL, 1, [Define to 1 if you have 'hal' library])],
 912              [with_libhal="no"])
 913 if test "x$with_libhal" = "xyes"; then
 914         if test "x$PKG_CONFIG" != "x"; then
 915                 BUILD_WITH_LIBHAL_CFLAGS="`pkg-config --cflags hal`"
 916                 BUILD_WITH_LIBHAL_LIBS="`pkg-config --libs hal`"
 917                 AC_SUBST(BUILD_WITH_LIBHAL_CFLAGS)
 918                 AC_SUBST(BUILD_WITH_LIBHAL_LIBS)
 919         fi
 920 fi
 921
 922 m4_divert_once([HELP_WITH], [
 923 collectd additional packages:])
 924
 925 # AC_ARG_WITH (package, help-string, [action-if-given], [action-if-not-given])
 926 librrd_cflags=""
 927 librrd_ldflags=""
 928 librrd_threadsafe="yes"
 929 AC_ARG_WITH(rrdtool, [AS_HELP_STRING([--with-rrdtool@<:@=PREFIX@:>@], [Path to rrdtool.])],
 930 [       if test "x$withval" != "xno" && test "x$withval" != "xyes"
 931         then
 932                 librrd_cflags="-I$withval/include"
 933                 librrd_ldflags="-L$withval/lib"
 934                 with_rrdtool="yes"
 935         else
 936                 with_rrdtool="$withval"
 937         fi
 938 ], [with_rrdtool="yes"])
 939 if test "x$with_rrdtool" = "xyes"
 940 then
 941         SAVE_CPPFLAGS="$CPPFLAGS"
 942         SAVE_LDFLAGS="$LDFLAGS"
 943
 944         CPPFLAGS="$CPPFLAGS $librrd_cflags"
 945         LDFLAGS="$LDFLAGS $librrd_ldflags"
 946
 947         AC_CHECK_HEADERS(rrd.h,, [with_rrdtool="no (rrd.h not found)"])
 948
 949         CPPFLAGS="$SAVE_CPPFLAGS"
 950         LDFLAGS="$SAVE_LDFLAGS"
 951 fi
 952 if test "x$with_rrdtool" = "xyes"
 953 then
 954         SAVE_CPPFLAGS="$CPPFLAGS"
 955         SAVE_LDFLAGS="$LDFLAGS"
 956
 957         CPPFLAGS="$CPPFLAGS $librrd_cflags"
 958         LDFLAGS="$LDFLAGS $librrd_ldflags"
 959
 960         AC_CHECK_LIB(rrd_th, rrd_update_r,
 961         [with_rrdtool="yes"
 962          librrd_ldflags="$librrd_ldflags -lrrd_th -lm"
 963         ],
 964         [librrd_threadsafe="no"
 965          AC_CHECK_LIB(rrd, rrd_update,
 966          [with_rrdtool="yes"
 967           librrd_ldflags="$librrd_ldflags -lrrd -lm"
 968          ],
 969          [with_rrdtool="no (symbol 'rrd_update' not found)"],
 970          [-lm])
 971         ],
 972         [-lm])
 973
 974         CPPFLAGS="$SAVE_CPPFLAGS"
 975         LDFLAGS="$SAVE_LDFLAGS"
 976 fi
 977 if test "x$with_rrdtool" = "xyes"
 978 then
 979         BUILD_WITH_LIBRRD_CFLAGS="$librrd_cflags"
 980         BUILD_WITH_LIBRRD_LDFLAGS="$librrd_ldflags"
 981         AC_SUBST(BUILD_WITH_LIBRRD_CFLAGS)
 982         AC_SUBST(BUILD_WITH_LIBRRD_LDFLAGS)
 983 fi
 984 if test "x$librrd_threadsafe" = "xyes"
 985 then
 986         AC_DEFINE(HAVE_THREADSAFE_LIBRRD, 1, [Define to 1 if you have the threadsafe rrd library (-lrrd_th).])
 987 fi
 988
 989 AC_ARG_WITH(libpthread, [AS_HELP_STRING([--with-libpthread=@<:@=PREFIX@:>@], [Path to libpthread.])],
 990 [       if test "x$withval" != "xno" \
 991                 && test "x$withval" != "xyes"
 992         then
 993                 LDFLAGS="$LDFLAGS -L$withval/lib"
 994                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 995                 with_libpthread="yes"
 996         else
 997                 if test "x$withval" = "xno"
 998                 then
 999                         with_libpthread="no (disabled)"
1000                 fi
1001         fi
1002 ], [with_libpthread="yes"])
1003 if test "x$with_libpthread" = "xyes"
1004 then
1005         AC_CHECK_LIB(pthread, pthread_create, [with_libpthread="yes"], [with_libpthread="no (libpthread not found)"], [])
1006 fi
1007 if test "x$with_libpthread" = "xyes"
1008 then
1009         AC_CHECK_HEADERS(pthread.h,, [with_libpthread="no (pthread.h not found)"])
1010 fi
1011 if test "x$with_libpthread" = "xyes"
1012 then
1013         collect_pthread=1
1014 else
1015         collect_pthread=0
1016 fi
1017 AC_DEFINE_UNQUOTED(HAVE_LIBPTHREAD, [$collect_pthread],
1018         [Wether or not to use pthread (POSIX threads) library])
1019 AM_CONDITIONAL(BUILD_WITH_LIBPTHREAD, test "x$with_libpthread" = "xyes")
1020
1021 if test "x$ac_system" = "xSolaris"
1022 then
1023         with_kstat="yes"
1024         with_devinfo="yes"
1025 else
1026         with_kstat="no (Solaris only)"
1027         with_devinfo="no (Solaris only)"
1028 fi
1029
1030 if test "x$with_kstat" = "xyes"
1031 then
1032         AC_CHECK_LIB(kstat, kstat_open, [with_kstat="yes"], [with_kstat="no (libkstat not found)"], [])
1033 fi
1034 if test "x$with_kstat" = "xyes"
1035 then
1036         AC_CHECK_LIB(devinfo, di_init, [with_devinfo="yes"], [with_devinfo="no (not found)"], [])
1037         AC_CHECK_HEADERS(kstat.h,, [with_kstat="no (kstat.h not found)"])
1038 fi
1039 if test "x$with_kstat" = "xyes"
1040 then
1041         AC_DEFINE(HAVE_LIBKSTAT, 1,
1042                   [Define to 1 if you have the 'kstat' library (-lkstat)])
1043 fi
1044 AM_CONDITIONAL(BUILD_WITH_LIBKSTAT, test "x$with_kstat" = "xyes")
1045 AM_CONDITIONAL(BUILD_WITH_LIBDEVINFO, test "x$with_devinfo" = "xyes")
1046
1047 ### BEGIN of check for libcurl ###
1048 with_curl_config="curl-config"
1049 with_curl_cflags=""
1050 with_curl_libs=""
1051 AC_ARG_WITH(libcurl, [AS_HELP_STRING([--with-libcurl@<:@=PREFIX@:>@], [Path to libcurl.])],
1052 [
1053         if test "x$withval" = "xno"
1054         then
1055                 with_libcurl="no"
1056         else if test "x$withval" = "xyes"
1057         then
1058                 with_libcurl="yes"
1059         else
1060                 if test -f "$withval" && test -x "$withval"
1061                 then
1062                         with_curl_config="$withval"
1063                         with_libcurl="yes"
1064                 else if test -x "$withval/bin/curl-config"
1065                 then
1066                         with_curl_config="$withval/bin/curl-config"
1067                         with_libcurl="yes"
1068                 fi; fi
1069                 with_libcurl="yes"
1070         fi; fi
1071 ],
1072 [
1073         with_libcurl="yes"
1074 ])
1075 if test "x$with_libcurl" = "xyes"
1076 then
1077         with_curl_cflags=`$with_curl_config --cflags 2>/dev/null`
1078         curl_config_status=$?
1079
1080         if test $curl_config_status -ne 0
1081         then
1082                 with_libcurl="no ($with_curl_config failed)"
1083         else
1084                 SAVE_CPPFLAGS="$CPPFLAGS"
1085                 CPPFLAGS="$CPPFLAGS $with_curl_cflags"
1086
1087                 AC_CHECK_HEADERS(curl/curl.h, [], [with_libcurl="no (curl/curl.h not found)"], [])
1088
1089                 CPPFLAGS="$SAVE_CPPFLAGS"
1090         fi
1091 fi
1092 if test "x$with_libcurl" = "xyes"
1093 then
1094         with_curl_libs=`$with_curl_config --libs 2>/dev/null`
1095         curl_config_status=$?
1096
1097         if test $curl_config_status -ne 0
1098         then
1099                 with_libcurl="no ($with_curl_config failed)"
1100         else
1101                 AC_CHECK_LIB(curl, curl_easy_init,
1102                  [with_libcurl="yes"],
1103                  [with_libcurl="no (symbol 'curl_easy_init' not found)"],
1104                  [$with_curl_libs])
1105         fi
1106 fi
1107 if test "x$with_libcurl" = "xyes"
1108 then
1109         BUILD_WITH_LIBCURL_CFLAGS="$with_curl_cflags"
1110         BUILD_WITH_LIBCURL_LIBS="$with_curl_libs"
1111         AC_SUBST(BUILD_WITH_LIBCURL_CFLAGS)
1112         AC_SUBST(BUILD_WITH_LIBCURL_LIBS)
1113 fi
1114 AM_CONDITIONAL(BUILD_WITH_LIBCURL, test "x$with_libcurl" = "xyes")
1115 ### END of check for libcurl ###
1116
1117 with_libiokit="no"
1118 AC_CHECK_LIB(IOKit, IOServiceGetMatchingServices,
1119 [
1120         with_libiokit="yes"
1121 ],
1122 [
1123         with_libiokit="no"
1124 ])
1125 AM_CONDITIONAL(BUILD_WITH_LIBIOKIT, test "x$with_libiokit" = "xyes")
1126
1127 with_libstatgrab_cflags=""
1128 with_libstatgrab_ldflags=""
1129 AC_ARG_WITH(libstatgrab, [AS_HELP_STRING([--with-libstatgrab@<:@=PREFIX@:>@], [Path to libstatgrab.])],
1130 [
1131         if test "x$withval" != "xno" \
1132                 && test "x$withval" != "xyes"
1133         then
1134                 with_libstatgrab_cflags="-I$withval/include"
1135                 with_libstatgrab_ldflags="-L$withval/lib"
1136                 with_libstatgrab="yes"
1137         else
1138                 with_libstatgrab="$withval"
1139         fi
1140 ],
1141 [
1142         if test "x$ac_system" = "xunknown"
1143         then
1144                 with_libstatgrab="yes"
1145         else
1146                 with_libstatgrab="no"
1147         fi
1148 ])
1149 with_libstatgrab_pkg_config="yes"
1150 if test "x$with_libstatgrab" = "xyes" \
1151   && test "x$PKG_CONFIG" != "x"
1152 then
1153   AC_MSG_CHECKING([pkg-config for libstatgrab])
1154   temp_result="found"
1155   $PKG_CONFIG --exists libstatgrab 2>/dev/null
1156   if test "$?" != "0"
1157   then
1158     with_libstatgrab_pkg_config="no"
1159     temp_result="not found"
1160   fi
1161   AC_MSG_RESULT([$temp_result])
1162 else
1163   AC_MSG_NOTICE([pkg-config not available, trying to guess flags for the statgrab library.])
1164   with_libstatgrab_pkg_config="no"
1165   with_libstatgrab_ldflags="$with_libstatgrab_ldflags -lstatgrab"
1166 fi
1167
1168 if test "x$with_libstatgrab" = "xyes" \
1169   && test "x$with_libstatgrab_pkg_config" = "xyes" \
1170   && test "x$with_libstatgrab_cflags" = "x"
1171 then
1172   AC_MSG_CHECKING([for libstatgrab CFLAGS])
1173   temp_result="`$PKG_CONFIG --cflags libstatgrab`"
1174   if test "$?" = "0"
1175   then
1176     with_libstatgrab_cflags="$temp_result"
1177   else
1178     with_libstatgrab="no ($PKG_CONFIG --cflags libstatgrab failed)"
1179     temp_result="$PKG_CONFIG --cflags libstatgrab failed"
1180   fi
1181   AC_MSG_RESULT([$temp_result])
1182 fi
1183
1184 if test "x$with_libstatgrab" = "xyes" \
1185   && test "x$with_libstatgrab_pkg_config" = "xyes" \
1186   && test "x$with_libstatgrab_ldflags" = "x"
1187 then
1188   AC_MSG_CHECKING([for libstatgrab LDFLAGS])
1189   temp_result="`$PKG_CONFIG --libs libstatgrab`"
1190   if test "$?" = "0"
1191   then
1192     with_libstatgrab_ldflags="$temp_result"
1193   else
1194     with_libstatgrab="no ($PKG_CONFIG --libs libstatgrab failed)"
1195     temp_result="$PKG_CONFIG --libs libstatgrab failed"
1196   fi
1197   AC_MSG_RESULT([$temp_result])
1198 fi
1199
1200 if test "x$with_libstatgrab" = "xyes"
1201 then
1202   SAVE_CPPFLAGS="$CPPFLAGS"
1203   CPPFLAGS="$CPPFLAGS $with_libstatgrab_cflags"
1204
1205   AC_CHECK_HEADERS(statgrab.h,
1206                    [with_libstatgrab="yes"],
1207                    [with_libstatgrab="no (statgrab.h not found)"])
1208
1209   CPPFLAGS="$SAVE_CPPFLAGS"
1210 fi
1211
1212 if test "x$with_libstatgrab" = "xyes"
1213 then
1214   SAVE_CFLAGS="$CFLAGS"
1215   SAVE_LDFLAGS="$LDFLAGS"
1216
1217   CFLAGS="$CFLAGS $with_libstatgrab_cflags"
1218   LDFLAGS="$LDFLAGS $with_libstatgrab_ldflags"
1219
1220   AC_CHECK_LIB(statgrab, sg_init,
1221                [with_libstatgrab="yes"],
1222                [with_libstatgrab="no (symbol sg_init not found)"])
1223
1224   CFLAGS="$SAVE_CFLAGS"
1225   LDFLAGS="$SAVE_LDFLAGS"
1226 fi
1227
1228 AM_CONDITIONAL(BUILD_WITH_LIBSTATGRAB, test "x$with_libstatgrab" = "xyes")
1229 if test "x$with_libstatgrab" = "xyes"
1230 then
1231   AC_DEFINE(HAVE_LIBSTATGRAB, 1, [Define to 1 if you have the 'statgrab' library (-lstatgrab)])
1232   BUILD_WITH_LIBSTATGRAB_CFLAGS="$with_libstatgrab_cflags"
1233   BUILD_WITH_LIBSTATGRAB_LDFLAGS="$with_libstatgrab_ldflags"
1234   AC_SUBST(BUILD_WITH_LIBSTATGRAB_CFLAGS)
1235   AC_SUBST(BUILD_WITH_LIBSTATGRAB_LDFLAGS)
1236 fi
1237
1238 AC_CHECK_LIB(kvm, kvm_getprocs, [with_kvm_getprocs="yes"], [with_kvm_getprocs="no"])
1239 if test "x$with_kvm_getprocs" = "xyes"
1240 then
1241         AC_DEFINE(HAVE_LIBKVM_GETPROCS, 1,
1242                   [Define to 1 if you have the 'kvm' library with the 'kvm_getprocs' symbol (-lkvm)])
1243 fi
1244 AM_CONDITIONAL(BUILD_WITH_LIBKVM_GETPROCS, test "x$with_kvm_getprocs" = "xyes")
1245
1246 AC_CHECK_LIB(kvm, kvm_getswapinfo, [with_kvm_getswapinfo="yes"], [with_kvm_getswapinfo="no"])
1247 if test "x$with_kvm_getswapinfo" = "xyes"
1248 then
1249         AC_DEFINE(HAVE_LIBKVM_GETSWAPINFO, 1,
1250                   [Define to 1 if you have the 'kvm' library with the 'kvm_getswapinfo' symbol (-lkvm)])
1251 fi
1252 AM_CONDITIONAL(BUILD_WITH_LIBKVM_GETSWAPINFO, test "x$with_kvm_getswapinfo" = "xyes")
1253
1254 with_sensors_cflags=""
1255 with_sensors_ldflags=""
1256 AC_ARG_WITH(lm-sensors, [AS_HELP_STRING([--with-lm-sensors@<:@=PREFIX@:>@], [Path to lm_sensors.])],
1257 [
1258         if test "x$withval" = "xno"
1259         then
1260                 with_lm_sensors="no"
1261         else
1262                 with_lm_sensors="yes"
1263                 if test "x$withval" != "xyes"
1264                 then
1265                         with_sensors_cflags="-I$withval/include"
1266                         with_sensors_ldflags="-L$withval/lib"
1267                         with_lm_sensors="yes"
1268                 fi
1269         fi
1270 ],
1271 [
1272         if test "x$ac_system" = "xLinux"
1273         then
1274                 with_lm_sensors="yes"
1275         else
1276                 with_lm_sensors="no (Linux only library)"
1277         fi
1278 ])
1279 if test "x$with_lm_sensors" = "xyes"
1280 then
1281         SAVE_CPPFLAGS="$CPPFLAGS"
1282         CPPFLAGS="$CPPFLAGS $with_sensors_cflags"
1283
1284 #       AC_CHECK_HEADERS(sensors/sensors.h,
1285 #       [
1286 #               AC_DEFINE(HAVE_SENSORS_SENSORS_H, 1, [Define to 1 if you have the <sensors/sensors.h> header file.])
1287 #       ],
1288 #       [with_lm_sensors="no (sensors/sensors.h not found)"])
1289         AC_CHECK_HEADERS(sensors/sensors.h, [], [with_lm_sensors="no (sensors/sensors.h not found)"])
1290
1291         CPPFLAGS="$SAVE_CPPFLAGS"
1292 fi
1293 if test "x$with_lm_sensors" = "xyes"
1294 then
1295         SAVE_CPPFLAGS="$CPPFLAGS"
1296         SAVE_LDFLAGS="$LDFLAGS"
1297         CPPFLAGS="$CPPFLAGS $with_sensors_cflags"
1298         LDFLAGS="$LDFLAGS $with_sensors_ldflags"
1299
1300         AC_CHECK_LIB(sensors, sensors_init,
1301         [
1302                 AC_DEFINE(HAVE_LIBSENSORS, 1, [Define to 1 if you have the sensors library (-lsensors).])
1303         ],
1304         [with_lm_sensors="no (libsensors not found)"])
1305
1306         CPPFLAGS="$SAVE_CPPFLAGS"
1307         LDFLAGS="$SAVE_LDFLAGS"
1308 fi
1309 if test "x$with_lm_sensors" = "xyes"
1310 then
1311         BUILD_WITH_LIBSENSORS_CFLAGS="$with_sensors_cflags"
1312         BUILD_WITH_LIBSENSORS_LDFLAGS="$with_sensors_ldflags"
1313         AC_SUBST(BUILD_WITH_LIBSENSORS_CFLAGS)
1314         AC_SUBST(BUILD_WITH_LIBSENSORS_LDFLAGS)
1315 fi
1316 AM_CONDITIONAL(BUILD_WITH_LM_SENSORS, test "x$with_lm_sensors" = "xyes")
1317
1318 with_mysql_config="mysql_config"
1319 with_mysql_cflags=""
1320 with_mysql_libs=""
1321 AC_ARG_WITH(libmysql, [AS_HELP_STRING([--with-libmysql@<:@=PREFIX@:>@], [Path to libmysql.])],
1322 [
1323         if test "x$withval" = "xno"
1324         then
1325                 with_libmysql="no"
1326         else if test "x$withval" = "xyes"
1327         then
1328                 with_libmysql="yes"
1329         else
1330                 if test -f "$withval" && test -x "$withval";
1331                 then
1332                         with_mysql_config="$withval"
1333                 else if test -x "$withval/bin/mysql_config"
1334                 then
1335                         with_mysql_config="$withval/bin/mysql_config"
1336                 fi; fi
1337                 with_libmysql="yes"
1338         fi; fi
1339 ],
1340 [
1341         with_libmysql="yes"
1342 ])
1343 if test "x$with_libmysql" = "xyes"
1344 then
1345         with_mysql_cflags=`$with_mysql_config --cflags 2>/dev/null`
1346         mysql_config_status=$?
1347
1348         if test $mysql_config_status -ne 0
1349         then
1350                 with_libmysql="no"
1351         else
1352                 SAVE_CPPFLAGS="$CPPFLAGS"
1353                 CPPFLAGS="$CPPFLAGS $with_mysql_cflags"
1354
1355                 AC_CHECK_HEADERS(mysql/mysql.h, [], [with_libmysql="no (mysql/mysql.h not found)"], [])
1356
1357                 CPPFLAGS="$SAVE_CPPFLAGS"
1358         fi
1359 fi
1360 if test "x$with_libmysql" = "xyes"
1361 then
1362         with_mysql_libs=`$with_mysql_config --libs 2>/dev/null`
1363         mysql_config_status=$?
1364
1365         if test $mysql_config_status -ne 0
1366         then
1367                 with_libmysql="no"
1368         else
1369                 AC_CHECK_LIB(mysqlclient, mysql_init,
1370                  [with_libmysql="yes"],
1371                  [with_libmysql="no (symbol 'mysql_init' not found)"],
1372                  [$with_mysql_libs])
1373         fi
1374 fi
1375 if test "x$with_libmysql" = "xyes"
1376 then
1377         BUILD_WITH_LIBMYSQL_CFLAGS="$with_mysql_cflags"
1378         BUILD_WITH_LIBMYSQL_LIBS="$with_mysql_libs"
1379         AC_SUBST(BUILD_WITH_LIBMYSQL_CFLAGS)
1380         AC_SUBST(BUILD_WITH_LIBMYSQL_LIBS)
1381 fi
1382 AM_CONDITIONAL(BUILD_WITH_LIBMYSQL, test "x$with_libmysql" = "xyes")
1383
1384 with_own_liboconfig="no"
1385 liboconfig_LDFLAGS="$LDFLAGS"
1386 liboconfig_CPPFLAGS="$CPPFLAGS"
1387 AC_ARG_WITH(liboconfig, [AS_HELP_STRING([--with-liboconfig@<:@=PREFIX@:>@], [Path to liboconfig.])],
1388 [
1389         if test "x$withval" != "xno" && test "x$withval" != "xyes"
1390         then
1391                 if test -d "$withval/lib"
1392                 then
1393                         liboconfig_LDFLAGS="$LDFLAGS -L$withval/lib"
1394                 fi
1395                 if test -d "$withval/include"
1396                 then
1397                         liboconfig_CPPFLAGS="$CPPFLAGS -I$withval/include"
1398                 fi
1399         fi
1400         if test "x$withval" = "xno"
1401         then
1402                 AC_MSG_ERROR("liboconfig is required")
1403         fi
1404 ],
1405 [
1406         with_liboconfig="yes"
1407 ])
1408
1409 save_LDFLAGS="$LDFLAGS"
1410 save_CPPFLAGS="$CPPFLAGS"
1411 LDFLAGS="$liboconfig_LDFLAGS"
1412 CPPFLAGS="$liboconfig_CPPFLAGS"
1413 AC_CHECK_LIB(oconfig, oconfig_parse_fh,
1414 [
1415         with_liboconfig="yes"
1416         with_own_liboconfig="no"
1417 ],
1418 [
1419         with_liboconfig="yes"
1420         with_own_liboconfig="yes"
1421         LDFLAGS="$save_LDFLAGS"
1422         CPPFLAGS="$save_CPPFLAGS"
1423 ])
1424
1425 AM_CONDITIONAL(BUILD_WITH_OWN_LIBOCONFIG, test "x$with_own_liboconfig" = "xyes")
1426 if test "x$with_own_liboconfig" = "xyes"
1427 then
1428         with_liboconfig="yes (shipped version)"
1429 fi
1430
1431 #with_liboping="yes"
1432 with_own_liboping="no"
1433 liboping_LDFLAGS="$LDFLAGS"
1434 liboping_CPPFLAGS="$CPPFLAGS"
1435 AC_ARG_WITH(liboping, [AS_HELP_STRING([--with-liboping@<:@=PREFIX@:>@], [Path to liboping.])],
1436 [
1437         if test "x$withval" != "xno" && test "x$withval" != "xyes"
1438         then
1439                 if test -d "$withval/lib"
1440                 then
1441                         liboping_LDFLAGS="$LDFLAGS -L$withval/lib"
1442                 fi
1443                 if test -d "$withval/include"
1444                 then
1445                         liboping_CPPFLAGS="$CPPFLAGS -I$withval/include"
1446                 fi
1447         fi
1448         if test "x$withval" = "xno"
1449         then
1450                 with_liboping="no"
1451                 with_own_liboping="no"
1452         else if test "x$withval" = "xyes"
1453         then
1454                 with_liboping="yes"
1455         fi; fi
1456 ],
1457 [
1458         with_liboping="yes"
1459 ])
1460
1461 if test "x$with_liboping" = "xyes"
1462 then
1463         save_LDFLAGS="$LDFLAGS"
1464         save_CPPFLAGS="$CPPFLAGS"
1465         LDFLAGS="$liboping_LDFLAGS"
1466         CPPFLAGS="$liboping_CPPFLAGS"
1467         AC_CHECK_LIB(oping, ping_construct,
1468         [
1469                 with_liboping="yes"
1470                 with_own_liboping="no"
1471         ],
1472         [
1473                 with_liboping="yes"
1474                 with_own_liboping="yes"
1475                 LDFLAGS="$save_LDFLAGS"
1476                 CPPFLAGS="$save_CPPFLAGS"
1477         ])
1478 fi
1479 AM_CONDITIONAL(BUILD_WITH_LIBOPING, test "x$with_liboping" = "xyes")
1480 AM_CONDITIONAL(BUILD_WITH_OWN_LIBOPING, test "x$with_own_liboping" = "xyes")
1481
1482 with_libowcapi_cppflags=""
1483 with_libowcapi_libs="-lowcapi"
1484 AC_ARG_WITH(libowcapi, [AS_HELP_STRING([--with-libowcapi@<:@=PREFIX@:>@], [Path to libowcapi.])],
1485 [
1486         if test "x$withval" != "xno" && test "x$withval" != "xyes"
1487         then
1488                 with_libowcapi_cppflags="-I$withval/include"
1489                 with_libowcapi_libs="-L$withval/lib -lowcapi"
1490                 with_libowcapi="yes"
1491         else
1492                 with_libowcapi="$withval"
1493         fi
1494 ],
1495 [
1496         with_libowcapi="yes"
1497 ])
1498 if test "x$with_libowcapi" = "xyes"
1499 then
1500         SAVE_CPPFLAGS="$CPPFLAGS"
1501         CPPFLAGS="$with_libowcapi_cppflags"
1502
1503         AC_CHECK_HEADERS(owcapi.h, [with_libowcapi="yes"], [with_libowcapi="no (owcapi.h not found)"])
1504
1505         CPPFLAGS="$SAVE_CPPFLAGS"
1506 fi
1507 if test "x$with_libowcapi" = "xyes"
1508 then
1509         SAVE_LDFLAGS="$LDFLAGS"
1510         SAVE_CPPFLAGS="$CPPFLAGS"
1511         LDFLAGS="$with_libowcapi_libs"
1512         CPPFLAGS="$with_libowcapi_cppflags"
1513
1514         AC_CHECK_LIB(owcapi, OW_get, [with_libowcapi="yes"], [with_libowcapi="no (libowcapi not found)"])
1515
1516         LDFLAGS="$SAVE_LDFLAGS"
1517         CPPFLAGS="$SAVE_CPPFLAGS"
1518 fi
1519 if test "x$with_libowcapi" = "xyes"
1520 then
1521         BUILD_WITH_LIBOWCAPI_CPPFLAGS="$with_libowcapi_cppflags"
1522         BUILD_WITH_LIBOWCAPI_LIBS="$with_libowcapi_libs"
1523         AC_SUBST(BUILD_WITH_LIBOWCAPI_CPPFLAGS)
1524         AC_SUBST(BUILD_WITH_LIBOWCAPI_LIBS)
1525 fi
1526
1527
1528 AC_ARG_WITH(libpcap, [AS_HELP_STRING([--with-libpcap@<:@=PREFIX@:>@], [Path to libpcap.])],
1529 [
1530         if test "x$withval" != "xno" && test "x$withval" != "xyes"
1531         then
1532                 LDFLAGS="$LDFLAGS -L$withval/lib"
1533                 CPPFLAGS="$CPPFLAGS -I$withval/include"
1534                 with_libpcap="yes"
1535         else
1536                 with_libpcap="$withval"
1537         fi
1538 ],
1539 [
1540         with_libpcap="yes"
1541 ])
1542 if test "x$with_libpcap" = "xyes"
1543 then
1544         AC_CHECK_LIB(pcap, pcap_open_live,
1545         [
1546                 AC_DEFINE(HAVE_LIBPCAP, 1, [Define to 1 if you have the pcap library (-lpcap).])
1547         ], [with_libpcap="no (libpcap not found)"])
1548 fi
1549 if test "x$with_libpcap" = "xyes"
1550 then
1551         AC_CHECK_HEADERS(pcap.h,
1552         [
1553                 AC_DEFINE(HAVE_PCAP_H, 1, [Define to 1 if you have the <pcap.h> header file.])
1554         ], [with_libpcap="no (pcap.h not found)"])
1555 fi
1556 if test "x$with_libpcap" = "xyes"
1557 then
1558         collect_libpcap=1
1559 else
1560         collect_libpcap=0
1561 fi
1562 AC_DEFINE_UNQUOTED(COLLECT_LIBPCAP, [$collect_libpcap],
1563         [Wether or not to use the pcap library])
1564 AM_CONDITIONAL(BUILD_WITH_LIBPCAP, test "x$with_libpcap" = "xyes")
1565
1566 AC_ARG_WITH(libesmtp, [AS_HELP_STRING([--with-libesmtp@<:@=PREFIX@:>@], [Path to libesmtp.])],
1567 [
1568         if test "x$withval" != "xno" && test "x$withval" != "xyes"
1569         then
1570                 LDFLAGS="$LDFLAGS -L$withval/lib"
1571                 CPPFLAGS="$CPPFLAGS -I$withval/include -D_THREAD_SAFE"
1572                 with_libesmtp="yes"
1573         else
1574                 with_libesmtp="$withval"
1575         fi
1576 ],
1577 [
1578         with_libesmtp="yes"
1579 ])
1580 if test "x$with_libesmtp" = "xyes"
1581 then
1582         AC_CHECK_LIB(esmtp, smtp_create_session,
1583         [
1584                 AC_DEFINE(HAVE_LIBESMTP, 1, [Define to 1 if you have the esmtp library (-lesmtp).])
1585         ], [with_libesmtp="no (libesmtp not found)"])
1586 fi
1587 if test "x$with_libesmtp" = "xyes"
1588 then
1589         AC_CHECK_HEADERS(libesmtp.h,
1590         [
1591                 AC_DEFINE(HAVE_LIBESMTP_H, 1, [Define to 1 if you have the <libesmtp.h> header file.])
1592         ], [with_libesmtp="no (libesmtp.h not found)"])
1593 fi
1594 if test "x$with_libesmtp" = "xyes"
1595 then
1596         collect_libesmtp=1
1597 else
1598         collect_libesmtp=0
1599 fi
1600 AC_DEFINE_UNQUOTED(COLLECT_LIBESMTP, [$collect_libesmtp],
1601         [Wether or not to use the esmtp library])
1602 AM_CONDITIONAL(BUILD_WITH_LIBESMTP, test "x$with_libesmtp" = "xyes")
1603
1604 perl_interpreter="perl"
1605 AC_ARG_WITH(libperl, [AS_HELP_STRING([--with-libperl@<:@=PREFIX@:>@], [Path to libperl.])],
1606 [
1607         if test "x$withval" != "xno" && test "x$withval" != "xyes"
1608         then
1609                 LDFLAGS="$LDFLAGS -L$withval/lib"
1610                 CPPFLAGS="$CPPFLAGS -I$withval/include"
1611                 perl_interpreter="$withval/bin/perl"
1612                 with_libperl="yes"
1613         else
1614                 with_libperl="$withval"
1615         fi
1616 ],
1617 [
1618         with_libperl="yes"
1619 ])
1620
1621 AC_MSG_CHECKING([for perl])
1622 perl_interpreter=`which "$perl_interpreter" 2> /dev/null`
1623 if test -x "$perl_interpreter"
1624 then
1625         AC_MSG_RESULT([yes])
1626 else
1627         perl_interpreter=""
1628         AC_MSG_RESULT([no])
1629 fi
1630
1631 AC_SUBST(PERL, "$perl_interpreter")
1632
1633 if test "x$with_libperl" = "xyes" \
1634         && test -n "$perl_interpreter"
1635 then
1636   SAVE_CFLAGS=$CFLAGS
1637   SAVE_LDFLAGS=$LDFLAGS
1638   PERL_CFLAGS=`$perl_interpreter -MExtUtils::Embed -e ccopts`
1639   PERL_LDFLAGS=`$perl_interpreter -MExtUtils::Embed -e ldopts`
1640   CFLAGS="$CFLAGS $PERL_CFLAGS"
1641   LDFLAGS="$LDFLAGS $PERL_LDFLAGS"
1642
1643   AC_CACHE_CHECK([for libperl],
1644     [have_libperl],
1645     AC_LINK_IFELSE(
1646       AC_LANG_PROGRAM(
1647       [[
1648 #include <EXTERN.h>
1649 #include <perl.h>
1650 #include <XSUB.h>
1651       ]],
1652       [[
1653        PerlInterpreter *perl = NULL;
1654        Perl_load_module (perl, PERL_LOADMOD_NOIMPORT,
1655                          newSVpv ("Collectd::Plugin::FooBar", 24),
1656                          Nullsv);
1657       ]]),
1658       [have_libperl="yes"],
1659       [have_libperl="no"]
1660     )
1661   )
1662
1663   if test "x$have_libperl" = "xyes"
1664   then
1665           AC_DEFINE(HAVE_LIBPERL, 1, [Define if libperl is present and usable.])
1666           AC_SUBST(PERL_CFLAGS)
1667           AC_SUBST(PERL_LDFLAGS)
1668   else
1669           with_libperl="no"
1670   fi
1671
1672   CFLAGS=$SAVE_CFLAGS
1673   LDFLAGS=$SAVE_LDFLAGS
1674 else if test -z "$perl_interpreter"; then
1675   with_libperl="no (no perl interpreter found)"
1676   have_libperl="no"
1677 fi; fi
1678 AM_CONDITIONAL(BUILD_WITH_LIBPERL, test "x$with_libperl" = "xyes")
1679
1680 if test "x$with_libperl" = "xyes"
1681 then
1682         SAVE_CFLAGS=$CFLAGS
1683         SAVE_LDFLAGS=$LDFLAGS
1684         CFLAGS="$CFLAGS $PERL_CFLAGS"
1685         LDFLAGS="$LDFLAGS $PERL_LDFLAGS"
1686
1687         AC_CACHE_CHECK([if perl supports ithreads],
1688                 [have_perl_ithreads],
1689                 AC_LINK_IFELSE(
1690                         AC_LANG_PROGRAM(
1691                         [[
1692 #include <EXTERN.h>
1693 #include <perl.h>
1694 #include <XSUB.h>
1695
1696 #if !defined(USE_ITHREADS)
1697 # error "Perl does not support ithreads!"
1698 #endif /* !defined(USE_ITHREADS) */
1699                         ]],
1700                         [[ ]]),
1701                         [have_perl_ithreads="yes"],
1702                         [have_perl_ithreads="no"]
1703                 )
1704         )
1705
1706         if test "x$have_perl_ithreads" = "xyes"
1707         then
1708                 AC_DEFINE(HAVE_PERL_ITHREADS, 1, [Define if Perl supports ithreads.])
1709         fi
1710
1711         CFLAGS=$SAVE_CFLAGS
1712         LDFLAGS=$SAVE_LDFLAGS
1713 fi
1714
1715 with_own_libiptc="no"
1716 AC_ARG_WITH(libiptc, [AS_HELP_STRING([--with-libiptc@<:@=PREFIX@:>@], [Path to libiptc.])],
1717 [
1718         if test "x$withval" != "xno" && test "x$withval" != "xyes"
1719         then
1720                 LDFLAGS="$LDFLAGS -L$withval/lib"
1721                 CPPFLAGS="$CPPFLAGS -I$withval/include"
1722                 with_libiptc="yes"
1723         else
1724                 with_libiptc="$withval"
1725         fi
1726 ],
1727 [
1728         if test "x$ac_system" = "xLinux"
1729         then
1730                 with_libiptc="yes"
1731         else
1732                 with_libiptc="no (Linux only)"
1733         fi
1734 ])
1735 if test "x$with_libiptc" = "xyes"
1736 then
1737         AC_CHECK_LIB(iptc, iptc_init,
1738         [
1739                 AC_DEFINE(HAVE_LIBIPTC, 1, [Define to 1 if you have the iptc library (-liptc).])
1740         ],
1741         [
1742                 with_libiptc="yes"
1743                 with_own_libiptc="yes"
1744         ])
1745 fi
1746 if test "x$with_libiptc" = "xyes" -a "x$with_own_libiptc" != "xyes"
1747 then
1748         AC_CHECK_HEADERS(libiptc/libiptc.h,
1749         [
1750                 AC_DEFINE(HAVE_LIBIPTC_LIBIPTC_H, 1, [Define to 1 if you have the <libiptc/libiptc.h> header file.])
1751         ],
1752         [
1753                 with_libiptc="yes"
1754                 with_own_libiptc="yes"
1755         ])
1756 fi
1757 if test "x$with_libiptc" = "xyes"
1758 then
1759         SAVE_CFLAGS=$CFLAGS
1760         CFLAGS="$CFLAGS $KERNEL_CFLAGS"
1761
1762         AC_CHECK_HEADERS(linux/netfilter_ipv4/ip_tables.h linux/netfilter_ipv6/ip6_tables.h, [],
1763         [
1764                 with_libiptc="no (Linux iptables headers not found - check KERNEL_DIR)"
1765                 with_own_libiptc="no"
1766         ],
1767         [
1768 #include "$srcdir/src/libiptc/ipt_kernel_headers.h"
1769         ])
1770
1771         CFLAGS=$SAVE_CFLAGS
1772 fi
1773 AM_CONDITIONAL(BUILD_WITH_LIBIPTC, test "x$with_libiptc" = "xyes")
1774 AM_CONDITIONAL(BUILD_WITH_OWN_LIBIPTC, test "x$with_own_libiptc" = "xyes")
1775 if test "x$with_own_libiptc" = "xyes"
1776 then
1777         AC_DEFINE(OWN_LIBIPTC, 1, [Define to 1 if we use the shipped iptc library.])
1778 fi
1779
1780 with_snmp_config="net-snmp-config"
1781 with_snmp_cflags=""
1782 with_snmp_libs=""
1783 AC_ARG_WITH(libnetsnmp, [AS_HELP_STRING([--with-libnetsnmp@<:@=PREFIX@:>@], [Path to the Net-SNMPD library.])],
1784 [
1785         if test "x$withval" = "xno"
1786         then
1787                 with_libnetsnmp="no"
1788         else if test "x$withval" = "xyes"
1789         then
1790                 with_libnetsnmp="yes"
1791         else
1792                 if test -x "$withval"
1793                 then
1794                         with_snmp_config="$withval"
1795                         with_libnetsnmp="yes"
1796                 else
1797                         with_snmp_config="$withval/bin/net-snmp-config"
1798                         with_libnetsnmp="yes"
1799                 fi
1800         fi; fi
1801 ],
1802 [with_libnetsnmp="yes"])
1803 if test "x$with_libnetsnmp" = "xyes"
1804 then
1805         with_snmp_cflags=`$with_snmp_config --cflags 2>/dev/null`
1806         snmp_config_status=$?
1807
1808         if test $snmp_config_status -ne 0
1809         then
1810                 with_libnetsnmp="no ($with_snmp_config failed)"
1811         else
1812                 SAVE_CPPFLAGS="$CPPFLAGS"
1813                 CPPFLAGS="$CPPFLAGS $with_snmp_cflags"
1814
1815                 AC_CHECK_HEADERS(net-snmp/net-snmp-config.h, [], [with_libnetsnmp="no (net-snmp/net-snmp-config.h not found)"])
1816
1817                 CPPFLAGS="$SAVE_CPPFLAGS"
1818         fi
1819 fi
1820 if test "x$with_libnetsnmp" = "xyes"
1821 then
1822         with_snmp_libs=`$with_snmp_config --libs 2>/dev/null`
1823         snmp_config_status=$?
1824
1825         if test $snmp_config_status -ne 0
1826         then
1827                 with_libnetsnmp="no ($with_snmp_config failed)"
1828         else
1829                 AC_CHECK_LIB(netsnmp, init_snmp,
1830                 [with_libnetsnmp="yes"],
1831                 [with_libnetsnmp="no (libnetsnmp not found)"],
1832                 [$with_snmp_libs])
1833         fi
1834 fi
1835 if test "x$with_libnetsnmp" = "xyes"
1836 then
1837         BUILD_WITH_LIBSNMP_CFLAGS="$with_snmp_cflags"
1838         BUILD_WITH_LIBSNMP_LIBS="$with_snmp_libs"
1839         AC_SUBST(BUILD_WITH_LIBSNMP_CFLAGS)
1840         AC_SUBST(BUILD_WITH_LIBSNMP_LIBS)
1841 fi
1842 AM_CONDITIONAL(BUILD_WITH_LIBNETSNMP, test "x$with_libnetsnmp" = "xyes")
1843
1844 PKG_CHECK_MODULES([LIBNOTIFY], [libnotify],
1845                 [with_libnotify="yes"],
1846                 [with_libnotify="no ($LIBNOTIFY_PKG_ERRORS)"])
1847
1848 with_libupsclient="no (pkg-config isn't available)"
1849 with_libupsclient_cflags=""
1850 with_libupsclient_libs=""
1851 if test "x$PKG_CONFIG" != "x"
1852 then
1853         pkg-config --exists 'libupsclient' 2>/dev/null
1854         if test "$?" = "0"
1855         then
1856                 with_libupsclient="yes"
1857         else
1858                 with_libupsclient="no (pkg-config doesn't know library)"
1859         fi
1860 fi
1861 if test "x$with_libupsclient" = "xyes"
1862 then
1863         with_libupsclient_cflags="`pkg-config --cflags 'libupsclient'`"
1864         if test $? -ne 0
1865         then
1866                 with_libupsclient="no"
1867         fi
1868         with_libupsclient_libs="`pkg-config --libs 'libupsclient'`"
1869         if test $? -ne 0
1870         then
1871                 with_libupsclient="no"
1872         fi
1873 fi
1874 if test "x$with_libupsclient" = "xyes"
1875 then
1876         SAVE_CPPFLAGS="$CPPFLAGS"
1877         CPPFLAGS="$CPPFLAGS $with_libupsclient_cflags"
1878
1879         AC_CHECK_HEADERS(upsclient.h, [], [with_libupsclient="no (upsclient.h not found)"])
1880
1881         CPPFLAGS="$SAVE_CPPFLAGS"
1882 fi
1883 if test "x$with_libupsclient" = "xyes"
1884 then
1885         SAVE_CPPFLAGS="$CPPFLAGS"
1886         SAVE_LDFLAGS="$LDFLAGS"
1887
1888         CPPFLAGS="$CPPFLAGS $with_libupsclient_cflags"
1889         LDFLAGS="$LDFLAGS $with_libupsclient_libs"
1890
1891         AC_CHECK_LIB(upsclient, upscli_connect,
1892                      [with_libupsclient="yes"],
1893                      [with_libupsclient="no (symbol upscli_connect not found)"])
1894
1895         CPPFLAGS="$SAVE_CPPFLAGS"
1896         LDFLAGS="$SAVE_LDFLAGS"
1897 fi
1898 if test "x$with_libupsclient" = "xyes"
1899 then
1900         SAVE_CPPFLAGS="$CPPFLAGS"
1901         CPPFLAGS="$CPPFLAGS $with_libupsclient_cflags"
1902
1903         AC_CHECK_TYPES([UPSCONN_t, UPSCONN], [], [],
1904 [#include <stdlib.h>
1905 #include <stdio.h>
1906 #include <upsclient.h>])
1907
1908         CPPFLAGS="$SAVE_CPPFLAGS"
1909 fi
1910 if test "x$with_libupsclient" = "xyes"
1911 then
1912         BUILD_WITH_LIBUPSCLIENT_CFLAGS="$with_libupsclient_cflags"
1913         BUILD_WITH_LIBUPSCLIENT_LIBS="$with_libupsclient_libs"
1914         AC_SUBST(BUILD_WITH_LIBUPSCLIENT_CFLAGS)
1915         AC_SUBST(BUILD_WITH_LIBUPSCLIENT_LIBS)
1916 fi
1917
1918 ### BEGIN of check for libxmms ###
1919 with_xmms_config="xmms-config"
1920 with_xmms_cflags=""
1921 with_xmms_libs=""
1922 AC_ARG_WITH(libxmms, [AS_HELP_STRING([--with-libxmms@<:@=PREFIX@:>@], [Path to libxmms.])],
1923 [
1924         if test "x$withval" != "xno" \
1925                 && test "x$withval" != "xyes"
1926         then
1927                 if test -f "$withval" && test -x "$withval";
1928                 then
1929                         with_xmms_config="$withval"
1930                 else if test -x "$withval/bin/xmms-config"
1931                 then
1932                         with_xmms_config="$withval/bin/xmms-config"
1933                 fi; fi
1934                 with_libxmms="yes"
1935         else if test "x$withval" = "xno"
1936         then
1937                 with_libxmms="no"
1938         else
1939                 with_libxmms="yes"
1940         fi; fi
1941 ],
1942 [
1943         with_libxmms="yes"
1944 ])
1945 if test "x$with_libxmms" = "xyes"
1946 then
1947         with_xmms_cflags=`$with_xmms_config --cflags 2>/dev/null`
1948         xmms_config_status=$?
1949
1950         if test $xmms_config_status -ne 0
1951         then
1952                 with_libxmms="no"
1953         fi
1954 fi
1955 if test "x$with_libxmms" = "xyes"
1956 then
1957         with_xmms_libs=`$with_xmms_config --libs 2>/dev/null`
1958         xmms_config_status=$?
1959
1960         if test $xmms_config_status -ne 0
1961         then
1962                 with_libxmms="no"
1963         fi
1964 fi
1965 if test "x$with_libxmms" = "xyes"
1966 then
1967         AC_CHECK_LIB(xmms, xmms_remote_get_info,
1968         [
1969                 BUILD_WITH_LIBXMMS_CFLAGS="$with_xmms_cflags"
1970                 BUILD_WITH_LIBXMMS_LIBS="$with_xmms_libs"
1971                 AC_SUBST(BUILD_WITH_LIBXMMS_CFLAGS)
1972                 AC_SUBST(BUILD_WITH_LIBXMMS_LIBS)
1973         ],
1974         [
1975                 with_libxmms="no"
1976         ],
1977         [$with_xmms_libs])
1978 fi
1979 with_libxmms_numeric=0
1980 if test "x$with_libxmms" = "xyes"
1981 then
1982         with_libxmms_numeric=1
1983 fi
1984 AC_DEFINE_UNQUOTED(HAVE_LIBXMMS, [$with_libxmms_numeric], [Define to 1 if you have the 'xmms' library (-lxmms).])
1985 AM_CONDITIONAL(BUILD_WITH_LIBXMMS, test "x$with_libxmms" = "xyes")
1986 ### END of check for libxmms ###
1987
1988 with_libnetlink_cflags=""
1989 with_libnetlink_libs="-lnetlink"
1990 AC_ARG_WITH(libnetlink, [AS_HELP_STRING([--with-libnetlink@<:@=PREFIX@:>@], [Path to libnetlink.])],
1991 [
1992  echo "libnetlink: withval = $withval"
1993  if test "x$withval" = "xyes"
1994  then
1995          with_libnetlink="yes"
1996  else if test "x$withval" = "xno"
1997  then
1998          with_libnetlink="no"
1999  else
2000          if test -d "$withval/include"
2001          then
2002                  with_libnetlink_cflags="-I$withval/include"
2003                  with_libnetlink_libs="-L$withval/lib -lnetlink"
2004                  with_libnetlink="yes"
2005          else
2006                  AC_MSG_ERROR("no such directory: $withval/include")
2007          fi
2008  fi; fi
2009 ],
2010 [
2011  if test "x$ac_system" = "xLinux"
2012  then
2013          with_libnetlink="yes"
2014  else
2015          with_libnetlink="no (Linux only library)"
2016  fi
2017 ])
2018 if test "x$with_libnetlink" = "xyes"
2019 then
2020         SAVE_CFLAGS=$CFLAGS
2021         CFLAGS="$CFLAGS $with_libnetlink_cflags"
2022
2023         with_libnetlink="no (libnetlink.h not found)"
2024
2025         AC_CHECK_HEADERS(libnetlink.h iproute/libnetlink.h linux/libnetlink.h,
2026         [
2027          with_libnetlink="yes"
2028          break
2029         ], [],
2030 [#include <stdio.h>
2031 #include <sys/types.h>
2032 #include <asm/types.h>
2033 #include <sys/socket.h>
2034 #include <linux/netlink.h>
2035 #include <linux/rtnetlink.h>])
2036         AC_CHECK_HEADERS(linux/gen_stats.h linux/pkt_sched.h, [], [],
2037 [#include <stdio.h>
2038 #include <sys/types.h>
2039 #include <asm/types.h>
2040 #include <sys/socket.h>])
2041
2042         AC_COMPILE_IFELSE(
2043 [#include <stdio.h>
2044 #include <sys/types.h>
2045 #include <asm/types.h>
2046 #include <sys/socket.h>
2047 #include <linux/netlink.h>
2048 #include <linux/rtnetlink.h>
2049
2050 int main (void)
2051 {
2052         int retval = TCA_STATS2;
2053         return (retval);
2054 }],
2055         [AC_DEFINE([HAVE_TCA_STATS2], 1, [True if the enum-member TCA_STATS2 exists])]
2056         []);
2057
2058         AC_COMPILE_IFELSE(
2059 [#include <stdio.h>
2060 #include <sys/types.h>
2061 #include <asm/types.h>
2062 #include <sys/socket.h>
2063 #include <linux/netlink.h>
2064 #include <linux/rtnetlink.h>
2065
2066 int main (void)
2067 {
2068         int retval = TCA_STATS;
2069         return (retval);
2070 }],
2071         [AC_DEFINE([HAVE_TCA_STATS], 1, [True if the enum-member TCA_STATS exists])]
2072         []);
2073
2074         CFLAGS="$SAVE_CFLAGS"
2075 fi
2076 if test "x$with_libnetlink" = "xyes"
2077 then
2078         AC_CHECK_LIB(netlink, rtnl_open,
2079                      [with_libnetlink="yes"],
2080                      [with_libnetlink="no (symbol 'rtnl_open' not found)"],
2081                      [$with_libnetlink_libs])
2082 fi
2083 if test "x$with_libnetlink" = "xyes"
2084 then
2085         BUILD_WITH_LIBNETLINK_CFLAGS="$with_libnetlink_cflags"
2086         BUILD_WITH_LIBNETLINK_LIBS="$with_libnetlink_libs"
2087         AC_SUBST(BUILD_WITH_LIBNETLINK_CFLAGS)
2088         AC_SUBST(BUILD_WITH_LIBNETLINK_LIBS)
2089 fi
2090 AM_CONDITIONAL(BUILD_WITH_LIBNETLINK, test "x$with_libnetlink" = "xyes")
2091
2092 with_libopenipmipthread="yes"
2093 with_libopenipmipthread_cflags=""
2094 with_libopenipmipthread_libs=""
2095
2096 AC_MSG_CHECKING([for pkg-config])
2097 temp_result="no"
2098 if test "x$PKG_CONFIG" = "x"
2099 then
2100         with_libopenipmipthread="no"
2101         temp_result="no"
2102 else
2103         temp_result="$PKG_CONFIG"
2104 fi
2105 AC_MSG_RESULT([$temp_result])
2106
2107 if test "x$with_libopenipmipthread" = "xyes"
2108 then
2109         AC_MSG_CHECKING([for libOpenIPMIpthread])
2110         $PKG_CONFIG --exists OpenIPMIpthread 2>/dev/null
2111         if test "$?" != "0"
2112         then
2113                 with_libopenipmipthread="no ($PKG_CONFIG doesn't know OpenIPMIpthread)"
2114         fi
2115         AC_MSG_RESULT([$with_libopenipmipthread])
2116 fi
2117
2118 if test "x$with_libopenipmipthread" = "xyes"
2119 then
2120         AC_MSG_CHECKING([for libOpenIPMIpthread CFLAGS])
2121         temp_result="`$PKG_CONFIG --cflags OpenIPMIpthread`"
2122         if test "$?" = "0"
2123         then
2124                 with_libopenipmipthread_cflags="$temp_result"
2125         else
2126                 with_libopenipmipthread="no ($PKG_CONFIG --cflags OpenIPMIpthread failed)"
2127                 temp_result="$PKG_CONFIG --cflags OpenIPMIpthread failed"
2128         fi
2129         AC_MSG_RESULT([$temp_result])
2130 fi
2131
2132 if test "x$with_libopenipmipthread" = "xyes"
2133 then
2134         AC_MSG_CHECKING([for libOpenIPMIpthread LDFLAGS])
2135         temp_result="`$PKG_CONFIG --libs OpenIPMIpthread`"
2136         if test "$?" = "0"
2137         then
2138                 with_libopenipmipthread_ldflags="$temp_result"
2139         else
2140                 with_libopenipmipthread="no ($PKG_CONFIG --libs OpenIPMIpthread failed)"
2141                 temp_result="$PKG_CONFIG --libs OpenIPMIpthread failed"
2142         fi
2143         AC_MSG_RESULT([$temp_result])
2144 fi
2145
2146 if test "x$with_libopenipmipthread" = "xyes"
2147 then
2148         SAVE_CPPFLAGS="$CPPFLAGS"
2149         CPPFLAGS="$CPPFLAGS $with_libopenipmipthread_cflags"
2150
2151         AC_CHECK_HEADERS(OpenIPMI/ipmi_smi.h,
2152                          [with_libopenipmipthread="yes"],
2153                          [with_libopenipmipthread="no (OpenIPMI/ipmi_smi.h not found)"],
2154 [#include <OpenIPMI/ipmiif.h>
2155 #include <OpenIPMI/ipmi_err.h>
2156 #include <OpenIPMI/ipmi_posix.h>
2157 #include <OpenIPMI/ipmi_conn.h>
2158 ])
2159
2160         CPPFLAGS="$SAVE_CPPFLAGS"
2161 fi
2162
2163 if test "x$with_libopenipmipthread" = "xyes"
2164 then
2165         BUILD_WITH_OPENIPMI_CFLAGS="$with_libopenipmipthread_cflags"
2166         BUILD_WITH_OPENIPMI_LIBS="$with_libopenipmipthread_ldflags"
2167         AC_SUBST(BUILD_WITH_OPENIPMI_CFLAGS)
2168         AC_SUBST(BUILD_WITH_OPENIPMI_LIBS)
2169 fi
2170
2171 dnl Check for libpq.
2172 with_pg_config="pg_config"
2173 with_libpq_includedir=""
2174 with_libpq_libdir=""
2175 with_libpq_cppflags=""
2176 with_libpq_ldflags=""
2177 AC_ARG_WITH(libpq, [AS_HELP_STRING([--with-libpq@<:@=PREFIX@:>@],
2178         [Path to libpq.])],
2179 [
2180         if test "x$withval" = "xno"
2181         then
2182                 with_libpq="no"
2183         else if test "x$withval" = "xyes"
2184         then
2185                 with_libpq="yes"
2186         else
2187                 if test -f "$withval" && test -x "$withval";
2188                 then
2189                         with_pg_config="$withval"
2190                 else if test -x "$withval/bin/pg_config"
2191                 then
2192                         with_pg_config="$withval/bin/pg_config"
2193                 fi; fi
2194                 with_libpq="yes"
2195         fi; fi
2196 ],
2197 [
2198         with_libpq="yes"
2199 ])
2200 if test "x$with_libpq" = "xyes"
2201 then
2202         with_libpq_includedir=`$with_pg_config --includedir 2> /dev/null`
2203         pg_config_status=$?
2204
2205         if test $pg_config_status -eq 0
2206         then
2207                 if test -n "$with_libpq_includedir"; then
2208                         for dir in $with_libpq_includedir; do
2209                                 with_libpq_cppflags="$with_libpq_cppflags -I$dir"
2210                         done
2211                 fi
2212         else
2213                 AC_MSG_WARN([$with_pg_config returned with status $pg_config_status])
2214         fi
2215
2216         SAVE_CPPFLAGS="$CPPFLAGS"
2217         CPPFLAGS="$CPPFLAGS $with_libpq_cppflags"
2218
2219         AC_CHECK_HEADERS(libpq-fe.h, [],
2220                 [with_libpq="no (libpq-fe.h not found)"], [])
2221
2222         CPPFLAGS="$SAVE_CPPFLAGS"
2223 fi
2224 if test "x$with_libpq" = "xyes"
2225 then
2226         with_libpq_libdir=`$with_pg_config --libdir 2> /dev/null`
2227         pg_config_status=$?
2228
2229         if test $pg_config_status -eq 0
2230         then
2231                 if test -n "$with_libpq_libdir"; then
2232                         for dir in $with_libpq_libdir; do
2233                                 with_libpq_ldflags="$with_libpq_ldflags -L$dir"
2234                         done
2235                 fi
2236         else
2237                 AC_MSG_WARN([$with_pg_config returned with status $pg_config_status])
2238         fi
2239
2240         SAVE_LDFLAGS="$LDFLAGS"
2241         LDFLAGS="$LDFLAGS $with_libpq_ldflags"
2242
2243         AC_CHECK_LIB(pq, PQconnectdb,
2244                 [with_libpq="yes"],
2245                 [with_libpq="no (symbol 'PQconnectdb' not found)"])
2246
2247         LDFLAGS="$SAVE_LDFLAGS"
2248 fi
2249 if test "x$with_libpq" = "xyes"
2250 then
2251         BUILD_WITH_LIBPQ_CPPFLAGS="$with_libpq_cppflags"
2252         BUILD_WITH_LIBPQ_LDFLAGS="$with_libpq_ldflags"
2253         AC_SUBST(BUILD_WITH_LIBPQ_CPPFLAGS)
2254         AC_SUBST(BUILD_WITH_LIBPQ_LDFLAGS)
2255 fi
2256 AM_CONDITIONAL(BUILD_WITH_LIBPQ, test "x$with_libpq" = "xyes")
2257
2258 dnl Check for libvirt and libxml2 libraries.
2259 with_libxml2="no (pkg-config isn't available)"
2260 with_libxml2_cflags=""
2261 with_libxml2_ldflags=""
2262 with_libvirt="no (pkg-config isn't available)"
2263 with_libvirt_cflags=""
2264 with_libvirt_ldflags=""
2265 if test "x$PKG_CONFIG" != "x"
2266 then
2267         pkg-config --exists 'libxml-2.0' 2>/dev/null
2268         if test "$?" = "0"
2269         then
2270                 with_libxml2="yes"
2271         else
2272                 with_libxml2="no (pkg-config doesn't know library)"
2273         fi
2274
2275         pkg-config --exists libvirt 2>/dev/null
2276         if test "$?" = "0"
2277         then
2278                 with_libvirt="yes"
2279         else
2280                 with_libvirt="no (pkg-config doesn't know library)"
2281         fi
2282 fi
2283 if test "x$with_libxml2" = "xyes"
2284 then
2285         with_libxml2_cflags="`pkg-config --cflags libxml-2.0`"
2286         if test $? -ne 0
2287         then
2288                 with_libxml2="no"
2289         fi
2290         with_libxml2_ldflags="`pkg-config --libs libxml-2.0`"
2291         if test $? -ne 0
2292         then
2293                 with_libxml2="no"
2294         fi
2295 fi
2296 if test "x$with_libxml2" = "xyes"
2297 then
2298         SAVE_CPPFLAGS="$CPPFLAGS"
2299         CPPFLAGS="$CPPFLAGS $with_libxml2_cflags"
2300
2301         AC_CHECK_HEADERS(libxml/parser.h, [],
2302                       [with_libxml2="no (libxml/parser.h not found)"])
2303
2304         CPPFLAGS="$SAVE_CPPFLAGS"
2305 fi
2306 if test "x$with_libxml2" = "xyes"
2307 then
2308         SAVE_CFLAGS="$CFLAGS"
2309         SAVE_LDFLAGS="$LDFLAGS"
2310
2311         CFLAGS="$CFLAGS $with_libxml2_cflags"
2312         LDFLAGS="$LDFLAGS $with_libxml2_ldflags"
2313
2314         AC_CHECK_LIB(xml2, xmlXPathEval,
2315                      [with_libxml2="yes"],
2316                      [with_libxml2="no (symbol xmlXPathEval not found)"])
2317
2318         CFLAGS="$SAVE_CFLAGS"
2319         LDFLAGS="$SAVE_LDFLAGS"
2320 fi
2321 dnl Add the right compiler flags and libraries.
2322 if test "x$with_libxml2" = "xyes"; then
2323         BUILD_WITH_LIBXML2_CFLAGS="$with_libxml2_cflags"
2324         BUILD_WITH_LIBXML2_LIBS="$with_libxml2_ldflags"
2325         AC_SUBST(BUILD_WITH_LIBXML2_CFLAGS)
2326         AC_SUBST(BUILD_WITH_LIBXML2_LIBS)
2327 fi
2328 if test "x$with_libvirt" = "xyes"
2329 then
2330         with_libvirt_cflags="`pkg-config --cflags libvirt`"
2331         if test $? -ne 0
2332         then
2333                 with_libvirt="no"
2334         fi
2335         with_libvirt_ldflags="`pkg-config --libs libvirt`"
2336         if test $? -ne 0
2337         then
2338                 with_libvirt="no"
2339         fi
2340 fi
2341 if test "x$with_libvirt" = "xyes"
2342 then
2343         SAVE_CPPFLAGS="$CPPFLAGS"
2344         CPPFLAGS="$CPPFLAGS $with_libvirt_cflags"
2345
2346         AC_CHECK_HEADERS(libvirt/libvirt.h, [],
2347                       [with_libvirt="no (libvirt/libvirt.h not found)"])
2348
2349         CPPFLAGS="$SAVE_CPPFLAGS"
2350 fi
2351 if test "x$with_libvirt" = "xyes"
2352 then
2353         SAVE_CFLAGS="$CFLAGS"
2354         SAVE_LDFLAGS="$LDFLAGS"
2355
2356         CFLAGS="$CFLAGS $with_libvirt_cflags"
2357         LDFLAGS="$LDFLAGS $with_libvirt_ldflags"
2358
2359         AC_CHECK_LIB(virt, virDomainBlockStats,
2360                      [with_libvirt="yes"],
2361                      [with_libvirt="no (symbol virDomainBlockStats not found)"])
2362
2363         CFLAGS="$SAVE_CFLAGS"
2364         LDFLAGS="$SAVE_LDFLAGS"
2365 fi
2366 dnl Add the right compiler flags and libraries.
2367 if test "x$with_libvirt" = "xyes"; then
2368         BUILD_WITH_LIBVIRT_CFLAGS="$with_libvirt_cflags"
2369         BUILD_WITH_LIBVIRT_LIBS="$with_libvirt_ldflags"
2370         AC_SUBST(BUILD_WITH_LIBVIRT_CFLAGS)
2371         AC_SUBST(BUILD_WITH_LIBVIRT_LIBS)
2372 fi
2373
2374 dnl End of check for libvirt and libxml2 libraries.
2375
2376 # Check for enabled/disabled features
2377 #
2378
2379 # AC_COLLECTD(name, enable/disable, info-text, feature/module)
2380 # ------------------------------------------------------------
2381 dnl
2382 m4_define([my_toupper], [m4_translit([$1], m4_defn([m4_cr_letters]), m4_defn([m4_cr_LETTERS]))])
2383 dnl
2384 AC_DEFUN(
2385         [AC_COLLECTD],
2386         [
2387         m4_if([$1], [], [AC_FATAL([AC_COLLECTD([$1], [$2], [$3], [$4]): 1st argument must not be empty])])dnl
2388         m4_if(
2389                 [$2],
2390                 [enable],
2391                 [dnl
2392                 m4_define([EnDis],[disabled])dnl
2393                 m4_define([YesNo],[no])dnl
2394                 ],dnl
2395                 [m4_if(
2396                         [$2],
2397                         [disable],
2398                         [dnl
2399                         m4_define([EnDis],[enabled])dnl
2400                         m4_define([YesNo],[yes])dnl
2401                         ],
2402                         [dnl
2403                         AC_FATAL([AC_COLLECTD([$1], [$2], [$3], [$4]): 2nd argument must be either enable or disable])dnl
2404                         ]dnl
2405                 )]dnl
2406         )dnl
2407         m4_if([$3], [feature], [],
2408                 [m4_if(
2409                         [$3], [module], [],
2410                         [dnl
2411                         AC_FATAL([AC_COLLECTD([$1], [$2], [$3], [$4]): 3rd argument must be either feature or disable])dnl
2412                         ]dnl
2413                 )]dnl
2414         )dnl
2415         AC_ARG_ENABLE(
2416                 [$1],
2417                 AS_HELP_STRING([--$2-$1], [$2 $4 (EnDis by def)]),
2418                 [],
2419                 enable_$1='[YesNo]'dnl
2420         )# AC_ARG_ENABLE
2421 if test "x$enable_$1" = "xno"
2422 then
2423         collectd_$1=0
2424 else
2425         if test "x$enable_$1" = "xyes"
2426         then
2427                 collectd_$1=1
2428         else
2429                 AC_MSG_NOTICE([please specify either --enable-$1 or --disable-$1; enabling $1.])
2430                 collectd_$1=1
2431                 enable_$1='yes'
2432         fi
2433 fi
2434         AC_DEFINE_UNQUOTED([COLLECT_]my_toupper([$1]), [$collectd_$1], [wether or not to enable $3 $4])
2435         AM_CONDITIONAL([BUILD_]my_toupper([$3])[_]my_toupper([$1]), [test "x$enable_$1" = "xyes"])dnl
2436         ]dnl
2437 )# AC_COLLECTD(name, enable/disable, info-text, feature/module)
2438
2439 # AC_PLUGIN(name, default, info)
2440 # ------------------------------------------------------------
2441 dnl
2442 AC_DEFUN(
2443   [AC_PLUGIN],
2444   [
2445     enable_plugin="no"
2446     AC_ARG_ENABLE([$1], AC_HELP_STRING([--enable-$1], [$3]),
2447     [
2448      if test "x$enableval" = "xyes"
2449      then
2450              enable_plugin="yes"
2451      else
2452              enable_plugin="no"
2453      fi
2454     ],
2455     [
2456      if test "x$2" = "xyes"
2457      then
2458              enable_plugin="yes"
2459      else
2460              enable_plugin="no"
2461      fi
2462     ])
2463     if test "x$enable_plugin" = "xyes"
2464     then
2465             AC_DEFINE([HAVE_PLUGIN_]my_toupper([$1]), 1, [Define to 1 if the $1 plugin is enabled.])
2466     fi
2467     AM_CONDITIONAL([BUILD_PLUGIN_]my_toupper([$1]), test "x$enable_plugin" = "xyes")
2468     enable_$1="$enable_plugin"
2469   ]
2470 )# AC_PLUGIN(name, default, info)
2471
2472 m4_divert_once([HELP_ENABLE], [
2473 collectd features:])
2474 # FIXME: Remove these calls to `AC_COLLECTD' and then remove that macro.
2475 AC_COLLECTD([debug],     [enable],  [feature], [debugging])
2476 AC_COLLECTD([daemon],    [disable], [feature], [daemon mode])
2477 AC_COLLECTD([getifaddrs],[enable],  [feature], [getifaddrs under Linux])
2478
2479 plugin_ascent="no"
2480 plugin_battery="no"
2481 plugin_cpu="no"
2482 plugin_cpufreq="no"
2483 plugin_df="no"
2484 plugin_disk="no"
2485 plugin_entropy="no"
2486 plugin_interface="no"
2487 plugin_ipmi="no"
2488 plugin_ipvs="no"
2489 plugin_irq="no"
2490 plugin_libvirt="no"
2491 plugin_load="no"
2492 plugin_memory="no"
2493 plugin_multimeter="no"
2494 plugin_nfs="no"
2495 plugin_perl="no"
2496 plugin_processes="no"
2497 plugin_serial="no"
2498 plugin_swap="no"
2499 plugin_tape="no"
2500 plugin_tcpconns="no"
2501 plugin_thermal="no"
2502 plugin_users="no"
2503 plugin_vmem="no"
2504 plugin_vserver="no"
2505 plugin_wireless="no"
2506
2507 # Linux
2508 if test "x$ac_system" = "xLinux"
2509 then
2510         plugin_battery="yes"
2511         plugin_cpu="yes"
2512         plugin_cpufreq="yes"
2513         plugin_disk="yes"
2514         plugin_entropy="yes"
2515         plugin_interface="yes"
2516         plugin_irq="yes"
2517         plugin_load="yes"
2518         plugin_memory="yes"
2519         plugin_nfs="yes"
2520         plugin_processes="yes"
2521         plugin_serial="yes"
2522         plugin_swap="yes"
2523         plugin_tcpconns="yes"
2524         plugin_thermal="yes"
2525         plugin_vmem="yes"
2526         plugin_vserver="yes"
2527         plugin_wireless="yes"
2528
2529         if test "x$have_net_ip_vs_h" = "xyes" -o "x$have_ip_vs_h" = "xyes"
2530         then
2531                 plugin_ipvs="yes"
2532         fi
2533 fi
2534
2535 if test "x$ac_system" = "xOpenBSD"
2536 then
2537         plugin_tcpconns="yes"
2538 fi
2539
2540 # Mac OS X devices
2541 if test "x$with_libiokit" = "xyes"
2542 then
2543         plugin_battery="yes"
2544         plugin_disk="yes"
2545 fi
2546
2547 # Solaris
2548 if test "x$with_devinfo$with_kstat" = "xyesyes"
2549 then
2550         plugin_cpu="yes"
2551         plugin_disk="yes"
2552         plugin_interface="yes"
2553         plugin_memory="yes"
2554         plugin_swap="yes"
2555         plugin_tape="yes"
2556 fi
2557
2558 # libstatgrab
2559 if test "x$with_libstatgrab" = "xyes"
2560 then
2561         plugin_cpu="yes"
2562         plugin_disk="yes"
2563         plugin_interface="yes"
2564         plugin_load="yes"
2565         plugin_memory="yes"
2566         plugin_swap="yes"
2567         plugin_users="yes"
2568 fi
2569
2570 if test "x$with_libcurl" = "xyes" && test "x$with_libxml2" = "xyes"
2571 then
2572         plugin_ascent="yes"
2573 fi
2574
2575 if test "x$with_libopenipmipthread" = "xyes"
2576 then
2577         plugin_ipmi="yes"
2578 fi
2579
2580 if test "x$have_processor_info" = "xyes"
2581 then
2582         plugin_cpu="yes"
2583 fi
2584 if test "x$have_sysctlbyname" = "xyes"
2585 then
2586         plugin_cpu="yes"
2587         plugin_memory="yes"
2588         plugin_tcpconns="yes"
2589 fi
2590
2591 if test "x$have_statfs" = "xyes"
2592 then
2593         plugin_df="yes"
2594 fi
2595 if test "x$have_statvfs" = "xyes"
2596 then
2597         plugin_df="yes"
2598 fi
2599
2600 if test "x$have_getifaddrs" = "xyes"
2601 then
2602         plugin_interface="yes"
2603 fi
2604
2605 if test "x$with_libxml2" = "xyes" && test "x$with_libvirt" = "xyes"
2606 then
2607         plugin_libvirt="yes"
2608 fi
2609
2610 if test "x$have_getloadavg" = "xyes"
2611 then
2612         plugin_load="yes"
2613 fi
2614
2615 if test "x$have_libperl$have_perl_ithreads" = "xyesyes"
2616 then
2617         plugin_perl="yes"
2618 fi
2619
2620 # Mac OS X memory interface
2621 if test "x$have_host_statistics" = "xyes"
2622 then
2623         plugin_memory="yes"
2624 fi
2625
2626 if test "x$have_termios_h" = "xyes"
2627 then
2628         plugin_multimeter="yes"
2629 fi
2630
2631 if test "x$have_thread_info" = "xyes"
2632 then
2633         plugin_processes="yes"
2634 fi
2635
2636 if test "x$with_libkvm" = "xyes"
2637 then
2638         plugin_processes="yes"
2639         plugin_swap="yes"
2640 fi
2641
2642 if test "x$have_getutent" = "xyes"
2643 then
2644         plugin_users="yes"
2645 fi
2646 if test "x$have_getutxent" = "xyes"
2647 then
2648         plugin_users="yes"
2649 fi
2650
2651 # FIXME: sysctl for swap plugin
2652
2653 m4_divert_once([HELP_ENABLE], [
2654 collectd plugins:])
2655
2656 AC_PLUGIN([apache],      [$with_libcurl],      [Apache httpd statistics])
2657 AC_PLUGIN([apcups],      [yes],                [Statistics of UPSes by APC])
2658 AC_PLUGIN([apple_sensors], [$with_libiokit],   [Apple's hardware sensors])
2659 AC_PLUGIN([ascent],      [$plugin_ascent],     [AscentEmu player statistics])
2660 AC_PLUGIN([battery],     [$plugin_battery],    [Battery statistics])
2661 AC_PLUGIN([cpu],         [$plugin_cpu],        [CPU usage statistics])
2662 AC_PLUGIN([cpufreq],     [$plugin_cpufreq],    [CPU frequency statistics])
2663 AC_PLUGIN([csv],         [yes],                [CSV output plugin])
2664 AC_PLUGIN([notify_desktop], [$with_libnotify], [Desktop notifications])
2665 AC_PLUGIN([df],          [$plugin_df],         [Filesystem usage statistics])
2666 AC_PLUGIN([disk],        [$plugin_disk],       [Disk usage statistics])
2667 AC_PLUGIN([dns],         [$with_libpcap],      [DNS traffic analysis])
2668 AC_PLUGIN([email],       [yes],                [EMail statistics])
2669 AC_PLUGIN([entropy],     [$plugin_entropy],    [Entropy statistics])
2670 AC_PLUGIN([exec],        [yes],                [Execution of external programs])
2671 AC_PLUGIN([hddtemp],     [yes],                [Query hddtempd])
2672 AC_PLUGIN([interface],   [$plugin_interface],  [Interface traffic statistics])
2673 AC_PLUGIN([iptables],    [$with_libiptc],      [IPTables rule counters])
2674 AC_PLUGIN([ipmi],        [$plugin_ipmi],       [IPMI sensor statistics])
2675 AC_PLUGIN([ipvs],        [$plugin_ipvs],       [IPVS connection statistics])
2676 AC_PLUGIN([irq],         [$plugin_irq],        [IRQ statistics])
2677 AC_PLUGIN([libvirt],     [$plugin_libvirt],    [Virtual machine statistics])
2678 AC_PLUGIN([load],        [$plugin_load],       [System load])
2679 AC_PLUGIN([logfile],     [yes],                [File logging plugin])
2680 AC_PLUGIN([mbmon],       [yes],                [Query mbmond])
2681 AC_PLUGIN([memcached],   [yes],                [memcached statistics])
2682 AC_PLUGIN([memory],      [$plugin_memory],     [Memory usage])
2683 AC_PLUGIN([multimeter],  [$plugin_multimeter], [Read multimeter values])
2684 AC_PLUGIN([mysql],       [$with_libmysql],     [MySQL statistics])
2685 AC_PLUGIN([netlink],     [$with_libnetlink],   [Enhanced Linux network statistics])
2686 AC_PLUGIN([network],     [yes],                [Network communication plugin])
2687 AC_PLUGIN([nfs],         [$plugin_nfs],        [NFS statistics])
2688 AC_PLUGIN([nginx],       [$with_libcurl],      [nginx statistics])
2689 AC_PLUGIN([notify_email], [$with_libesmtp],    [Email notifier])
2690 AC_PLUGIN([ntpd],        [yes],                [NTPd statistics])
2691 AC_PLUGIN([nut],         [$with_libupsclient], [Network UPS tools statistics])
2692 AC_PLUGIN([onewire],     [$with_libowcapi],    [OneWire sensor statistics])
2693 AC_PLUGIN([perl],        [$plugin_perl],       [Embed a Perl interpreter])
2694 AC_PLUGIN([ping],        [$with_liboping],     [Network latency statistics])
2695 AC_PLUGIN([postgresql],  [$with_libpq],        [PostgreSQL database statistics])
2696 AC_PLUGIN([powerdns],    [yes],                [PowerDNS statistics])
2697 AC_PLUGIN([processes],   [$plugin_processes],  [Process statistics])
2698 AC_PLUGIN([qmail],       [yes],                [QMail queue statistics])
2699 AC_PLUGIN([rrdtool],     [$with_rrdtool],      [RRDTool output plugin])
2700 AC_PLUGIN([sensors],     [$with_lm_sensors],   [lm_sensors statistics])
2701 AC_PLUGIN([serial],      [$plugin_serial],     [serial port traffic])
2702 AC_PLUGIN([snmp],        [$with_libnetsnmp],   [SNMP querying plugin])
2703 AC_PLUGIN([swap],        [$plugin_swap],       [Swap usage statistics])
2704 AC_PLUGIN([syslog],      [$have_syslog],       [Syslog logging plugin])
2705 AC_PLUGIN([tail],        [yes],                [Parsing of logfiles])
2706 AC_PLUGIN([tape],        [$plugin_tape],       [Tape drive statistics])
2707 AC_PLUGIN([tcpconns],    [$plugin_tcpconns],   [TCP connection statistics])
2708 AC_PLUGIN([teamspeak2],  [yes],                [TeamSpeak2 server statistics])
2709 AC_PLUGIN([thermal],     [$plugin_thermal],    [Linux ACPI thermal zone statistics])
2710 AC_PLUGIN([unixsock],    [yes],                [Unixsock communication plugin])
2711 AC_PLUGIN([users],       [$plugin_users],      [User statistics])
2712 AC_PLUGIN([uuid],        [yes],                [UUID as hostname plugin])
2713 AC_PLUGIN([vmem],        [$plugin_vmem],       [Virtual memory statistics])
2714 AC_PLUGIN([vserver],     [$plugin_vserver],    [Linux VServer statistics])
2715 AC_PLUGIN([wireless],    [$plugin_wireless],   [Wireless statistics])
2716 AC_PLUGIN([xmms],        [$with_libxmms],      [XMMS statistics])
2717
2718 dnl ip_vs.h
2719 if test "x$ac_system" = "xLinux" \
2720         && test "x$have_net_ip_vs_h$have_ip_vs_h" = "xnono"
2721 then
2722         enable_ipvs="$enable_ipvs (ip_vs.h not found)"
2723 fi
2724
2725 dnl Perl bindings
2726 AC_ARG_WITH(perl-bindings, [AS_HELP_STRING([--with-perl-bindings@<:@=OPTIONS@:>@], [Options passed to "perl Makefile.PL".])],
2727 [
2728         if test "x$withval" != "xno" && test "x$withval" != "xyes"
2729         then
2730                 PERL_BINDINGS_OPTIONS="$withval"
2731                 with_perl_bindings="yes"
2732         else
2733                 PERL_BINDINGS_OPTIONS=""
2734                 with_perl_bindings="$withval"
2735         fi
2736 ],
2737 [
2738         PERL_BINDINGS_OPTIONS=""
2739         if test -n "$perl_interpreter"
2740         then
2741                 with_perl_bindings="yes"
2742         else
2743                 with_perl_bindings="no (no perl interpreter found)"
2744         fi
2745 ])
2746 if test "x$with_perl_bindings" = "xyes"
2747 then
2748         PERL_BINDINGS="perl"
2749 else
2750         PERL_BINDINGS=""
2751 fi
2752 AC_SUBST(PERL_BINDINGS)
2753 AC_SUBST(PERL_BINDINGS_OPTIONS)
2754
2755 AC_OUTPUT(Makefile src/Makefile src/collectd.conf src/libiptc/Makefile src/liboconfig/Makefile src/liboping/Makefile bindings/Makefile)
2756
2757 if test "x$with_rrdtool" = "xyes" \
2758         && test "x$librrd_threadsafe" != "xyes"
2759 then
2760         with_rrdtool="yes (warning: librrd is not thread-safe)"
2761 fi
2762
2763 if test "x$with_liboping" = "xyes" \
2764         && test "x$with_own_liboping" = "xyes"
2765 then
2766         with_liboping="yes (shipped version)"
2767 fi
2768
2769 if test "x$with_libiptc" = "xyes" -a "x$with_own_libiptc" = "xyes"
2770 then
2771         with_libiptc="yes (shipped version)"
2772 fi
2773
2774 if test "x$with_libperl" = "xyes"
2775 then
2776         with_libperl="yes (version `$perl_interpreter -MConfig -e 'print $Config{version};'`)"
2777 else
2778         enable_perl="no (needs libperl)"
2779 fi
2780
2781 if test "x$with_perl_bindings" = "xyes" \
2782         && test "x$PERL_BINDINGS_OPTIONS" != "x"
2783 then
2784         with_perl_bindings="yes ($PERL_BINDINGS_OPTIONS)"
2785 fi
2786
2787 cat <<EOF;
2788
2789 Configuration:
2790   Libraries:
2791     libcurl . . . . . . . $with_libcurl
2792     libesmtp  . . . . . . $with_libesmtp
2793     libiokit  . . . . . . $with_libiokit
2794     libiptc . . . . . . . $with_libiptc
2795     libkstat  . . . . . . $with_kstat
2796     libkvm  . . . . . . . $with_libkvm
2797     libmysql  . . . . . . $with_libmysql
2798     libnetlink  . . . . . $with_libnetlink
2799     libnetsnmp  . . . . . $with_libnetsnmp
2800     libnotify . . . . . . $with_libnotify
2801     liboconfig  . . . . . $with_liboconfig
2802     libopenipmi . . . . . $with_libopenipmipthread
2803     liboping  . . . . . . $with_liboping
2804     libpcap . . . . . . . $with_libpcap
2805     libperl . . . . . . . $with_libperl
2806     libpthread  . . . . . $with_libpthread
2807     libpq . . . . . . . . $with_libpq
2808     librrd  . . . . . . . $with_rrdtool
2809     libsensors  . . . . . $with_lm_sensors
2810     libstatgrab . . . . . $with_libstatgrab
2811     libupsclient  . . . . $with_libupsclient
2812     libvirt . . . . . . . $with_libvirt
2813     libxml2 . . . . . . . $with_libxml2
2814     libxmms . . . . . . . $with_libxmms
2815
2816   Features:
2817     daemon mode . . . . . $enable_daemon
2818     debug . . . . . . . . $enable_debug
2819
2820   Bindings:
2821     perl  . . . . . . . . $with_perl_bindings
2822
2823   Modules:
2824     apache  . . . . . . . $enable_apache
2825     apcups  . . . . . . . $enable_apcups
2826     apple_sensors . . . . $enable_apple_sensors
2827     ascent  . . . . . . . $enable_ascent
2828     battery . . . . . . . $enable_battery
2829     cpu . . . . . . . . . $enable_cpu
2830     cpufreq . . . . . . . $enable_cpufreq
2831     csv . . . . . . . . . $enable_csv
2832     df  . . . . . . . . . $enable_df
2833     disk  . . . . . . . . $enable_disk
2834     dns . . . . . . . . . $enable_dns
2835     email . . . . . . . . $enable_email
2836     entropy . . . . . . . $enable_entropy
2837     exec  . . . . . . . . $enable_exec
2838     hddtemp . . . . . . . $enable_hddtemp
2839     interface . . . . . . $enable_interface
2840     iptables  . . . . . . $enable_iptables
2841     ipmi  . . . . . . . . $enable_ipmi
2842     ipvs  . . . . . . . . $enable_ipvs
2843     irq . . . . . . . . . $enable_irq
2844     libvirt . . . . . . . $enable_libvirt
2845     load  . . . . . . . . $enable_load
2846     logfile . . . . . . . $enable_logfile
2847     mbmon . . . . . . . . $enable_mbmon
2848     memcached . . . . . . $enable_memcached
2849     memory  . . . . . . . $enable_memory
2850     multimeter  . . . . . $enable_multimeter
2851     mysql . . . . . . . . $enable_mysql
2852     netlink . . . . . . . $enable_netlink
2853     network . . . . . . . $enable_network
2854     nfs . . . . . . . . . $enable_nfs
2855     nginx . . . . . . . . $enable_nginx
2856     notify_desktop  . . . $enable_notify_desktop
2857     notify_email  . . . . $enable_notify_email
2858     ntpd  . . . . . . . . $enable_ntpd
2859     nut . . . . . . . . . $enable_nut
2860     onewire . . . . . . . $enable_onewire
2861     perl  . . . . . . . . $enable_perl
2862     ping  . . . . . . . . $enable_ping
2863     postgresql  . . . . . $enable_postgresql
2864     powerdns  . . . . . . $enable_powerdns
2865     processes . . . . . . $enable_processes
2866     qmail . . . . . . . . $enable_qmail
2867     rrdtool . . . . . . . $enable_rrdtool
2868     sensors . . . . . . . $enable_sensors
2869     serial  . . . . . . . $enable_serial
2870     snmp  . . . . . . . . $enable_snmp
2871     swap  . . . . . . . . $enable_swap
2872     syslog  . . . . . . . $enable_syslog
2873     tail  . . . . . . . . $enable_tail
2874     tape  . . . . . . . . $enable_tape
2875     tcpconns  . . . . . . $enable_tcpconns
2876     teamspeak2  . . . . . $enable_teamspeak2
2877     thermal . . . . . . . $enable_thermal
2878     unixsock  . . . . . . $enable_unixsock
2879     users . . . . . . . . $enable_users
2880     uuid  . . . . . . . . $enable_uuid
2881     vmem  . . . . . . . . $enable_vmem
2882     vserver . . . . . . . $enable_vserver
2883     wireless  . . . . . . $enable_wireless
2884     xmms  . . . . . . . . $enable_xmms
2885
2886 EOF