configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(collectd, 3.11.0)
   3 AC_CONFIG_SRCDIR(src/collectd.c)
   4 AC_CONFIG_HEADERS(src/config.h)
   5 AM_INIT_AUTOMAKE(dist-bzip2)
   6 AC_LANG(C)
   7
   8 AC_PREFIX_DEFAULT("/opt/collectd")
   9
  10 #
  11 # Checks for programs.
  12 #
  13 AC_PROG_CC
  14 AC_PROG_CPP
  15 AC_PROG_INSTALL
  16 AC_PROG_LN_S
  17 AC_PROG_MAKE_SET
  18 AM_CONDITIONAL(COMPILER_IS_GCC, test "x$GCC" = "xyes")
  19
  20 dnl configure libtool
  21 AC_DISABLE_STATIC
  22 AC_LIBLTDL_CONVENIENCE
  23 AC_SUBST(LTDLINCL)
  24 AC_SUBST(LIBLTDL)
  25 AC_LIBTOOL_DLOPEN
  26 AC_PROG_LIBTOOL
  27 #AC_PROG_RANLIB
  28 AC_CONFIG_SUBDIRS(libltdl)
  29
  30 #
  31 # Checks for header files.
  32 #
  33 AC_HEADER_STDC
  34 AC_HEADER_SYS_WAIT
  35 AC_HEADER_DIRENT
  36 AC_CHECK_HEADERS(stdint.h)
  37 AC_CHECK_HEADERS(stdio.h)
  38 AC_CHECK_HEADERS(errno.h)
  39 AC_CHECK_HEADERS(math.h)
  40 AC_CHECK_HEADERS(syslog.h)
  41 AC_CHECK_HEADERS(fcntl.h)
  42 AC_CHECK_HEADERS(signal.h)
  43 AC_CHECK_HEADERS(assert.h)
  44 AC_CHECK_HEADERS(sys/types.h)
  45 AC_CHECK_HEADERS(sys/socket.h)
  46 AC_CHECK_HEADERS(sys/select.h)
  47 AC_CHECK_HEADERS(poll.h)
  48 AC_CHECK_HEADERS(netdb.h)
  49 AC_CHECK_HEADERS(arpa/inet.h)
  50 AC_CHECK_HEADERS(sys/resource.h)
  51 AC_CHECK_HEADERS(sys/param.h)
  52
  53 # For ping library
  54 AC_CHECK_HEADERS(netinet/in_systm.h, [], [],
  55 [#if HAVE_STDINT_H
  56 # include <stdint.h>
  57 #endif
  58 #if HAVE_SYS_TYPES_H
  59 # include <sys/types.h>
  60 #endif
  61 ])
  62 AC_CHECK_HEADERS(netinet/in.h, [], [],
  63 [#if HAVE_STDINT_H
  64 # include <stdint.h>
  65 #endif
  66 #if HAVE_SYS_TYPES_H
  67 # include <sys/types.h>
  68 #endif
  69 #if HAVE_NETINET_IN_SYSTM_H
  70 # include <netinet/in_systm.h>
  71 #endif
  72 ])
  73 AC_CHECK_HEADERS(netinet/ip.h, [], [],
  74 [#if HAVE_STDINT_H
  75 # include <stdint.h>
  76 #endif
  77 #if HAVE_SYS_TYPES_H
  78 # include <sys/types.h>
  79 #endif
  80 #if HAVE_NETINET_IN_SYSTM_H
  81 # include <netinet/in_systm.h>
  82 #endif
  83 #if HAVE_NETINET_IN_H
  84 # include <netinet/in.h>
  85 #endif
  86 ])
  87 AC_CHECK_HEADERS(netinet/ip_icmp.h, [], [],
  88 [#if HAVE_STDINT_H
  89 # include <stdint.h>
  90 #endif
  91 #if HAVE_SYS_TYPES_H
  92 # include <sys/types.h>
  93 #endif
  94 #if HAVE_NETINET_IN_SYSTM_H
  95 # include <netinet/in_systm.h>
  96 #endif
  97 #if HAVE_NETINET_IN_H
  98 # include <netinet/in.h>
  99 #endif
 100 #if HAVE_NETINET_IP_H
 101 # include <netinet/ip.h>
 102 #endif
 103 ])
 104 AC_CHECK_HEADERS(netinet/ip_var.h, [], [],
 105 [#if HAVE_STDINT_H
 106 # include <stdint.h>
 107 #endif
 108 #if HAVE_SYS_TYPES_H
 109 # include <sys/types.h>
 110 #endif
 111 #if HAVE_NETINET_IN_SYSTM_H
 112 # include <netinet/in_systm.h>
 113 #endif
 114 #if HAVE_NETINET_IN_H
 115 # include <netinet/in.h>
 116 #endif
 117 #if HAVE_NETINET_IP_H
 118 # include <netinet/ip.h>
 119 #endif
 120 ])
 121 AC_CHECK_HEADERS(netinet/ip6.h, [], [],
 122 [#if HAVE_STDINT_H
 123 # include <stdint.h>
 124 #endif
 125 #if HAVE_SYS_TYPES_H
 126 # include <sys/types.h>
 127 #endif
 128 #if HAVE_NETINET_IN_SYSTM_H
 129 # include <netinet/in_systm.h>
 130 #endif
 131 #if HAVE_NETINET_IN_H
 132 # include <netinet/in.h>
 133 #endif
 134 ])
 135 AC_CHECK_HEADERS(netinet/icmp6.h, [], [],
 136 [#if HAVE_STDINT_H
 137 # include <stdint.h>
 138 #endif
 139 #if HAVE_SYS_TYPES_H
 140 # include <sys/types.h>
 141 #endif
 142 #if HAVE_NETINET_IN_SYSTM_H
 143 # include <netinet/in_systm.h>
 144 #endif
 145 #if HAVE_NETINET_IN_H
 146 # include <netinet/in.h>
 147 #endif
 148 #if HAVE_NETINET_IP6_H
 149 # include <netinet/ip6.h>
 150 #endif
 151 ])
 152
 153 # For cpu modules
 154 AC_CHECK_HEADERS(sys/sysctl.h sys/dkstat.h)
 155 AC_CHECK_HEADERS(mach/mach_init.h)
 156 AC_CHECK_HEADERS(mach/host_priv.h)
 157 AC_CHECK_HEADERS(mach/mach_error.h)
 158 AC_CHECK_HEADERS(mach/mach_host.h)
 159 AC_CHECK_HEADERS(mach/mach_port.h)
 160 AC_CHECK_HEADERS(mach/mach_types.h)
 161 AC_CHECK_HEADERS(mach/message.h)
 162 AC_CHECK_HEADERS(mach/processor_set.h)
 163 AC_CHECK_HEADERS(mach/processor.h)
 164 AC_CHECK_HEADERS(mach/processor_info.h)
 165 AC_CHECK_HEADERS(mach/task.h)
 166 AC_CHECK_HEADERS(mach/thread_act.h)
 167 AC_CHECK_HEADERS(mach/vm_region.h)
 168 AC_CHECK_HEADERS(mach/vm_map.h)
 169 AC_CHECK_HEADERS(mach/vm_prot.h)
 170 AC_CHECK_HEADERS(mach/vm_statistics.h)
 171 AC_CHECK_HEADERS(mach/kern_return.h)
 172
 173 # For hddtemp module
 174 AC_CHECK_HEADERS(linux/major.h)
 175
 176 # For the apple_sensors module
 177 AC_CHECK_HEADERS(CoreFoundation/CoreFoundation.h)
 178 AC_CHECK_HEADERS(IOKit/IOKitLib.h)
 179 AC_CHECK_HEADERS(IOKit/IOTypes.h)
 180
 181 # For the battery plugin
 182 AC_CHECK_HEADERS(IOKit/ps/IOPowerSources.h, [], [],
 183 [
 184 #if HAVE_IOKIT_IOKITLIB_H
 185 #  include <IOKit/IOKitLib.h>
 186 #endif
 187 #if HAVE_IOKIT_IOTYPES_H
 188 #  include <IOKit/IOTypes.h>
 189 #endif
 190 ])
 191 AC_CHECK_HEADERS(IOKit/ps/IOPSKeys.h)
 192
 193 # For the `disk' plugin
 194 AC_CHECK_HEADERS(IOKit/IOBSD.h)
 195 AC_CHECK_HEADERS(IOKit/storage/IOBlockStorageDriver.h)
 196
 197 # For load module
 198 AC_CHECK_HEADERS(sys/loadavg.h)
 199
 200 # For the processes plugin
 201 AC_CHECK_HEADERS(linux/config.h)
 202
 203 # For the swap module
 204 AC_CHECK_HEADERS(sys/swap.h)
 205
 206 # For users module
 207 AC_CHECK_HEADERS(utmp.h)
 208 AC_CHECK_HEADERS(utmpx.h)
 209
 210 # For traffic plugin
 211 AC_CHECK_HEADERS(ifaddrs.h)
 212 AC_CHECK_HEADERS(net/if.h, [], [],
 213 [
 214 #if HAVE_SYS_TYPES_H
 215 #  include <sys/types.h>
 216 #endif
 217 #if HAVE_SYS_SOCKET_H
 218 #  include <sys/socket.h>
 219 #endif
 220 ])
 221 AC_CHECK_HEADERS(linux/if.h, [], [],
 222 [
 223 #if HAVE_SYS_TYPES_H
 224 #  include <sys/types.h>
 225 #endif
 226 #if HAVE_SYS_SOCKET_H
 227 #  include <sys/socket.h>
 228 #endif
 229 ])
 230 AC_CHECK_HEADERS(linux/netdevice.h, [], [],
 231 [
 232 #if HAVE_SYS_TYPES_H
 233 #  include <sys/types.h>
 234 #endif
 235 #if HAVE_SYS_SOCKET_H
 236 #  include <sys/socket.h>
 237 #endif
 238 #if HAVE_LINUX_IF_H
 239 # include <linux/if.h>
 240 #endif
 241 ])
 242
 243 # For apache plugin
 244 AC_CHECK_HEADERS(curl/curl.h)
 245
 246 # For quota module
 247 AC_CHECK_HEADERS(grp.h pwd.h sys/ucred.h)
 248 AC_CHECK_HEADERS(ctype.h)
 249 AC_CHECK_HEADERS(limits.h)
 250 AC_CHECK_HEADERS(sys/quota.h)
 251 AC_CHECK_HEADERS(xfs/xqm.h)
 252
 253 # For mount interface
 254 AC_CHECK_HEADERS(fs_info.h)
 255 AC_CHECK_HEADERS(fshelp.h)
 256 AC_CHECK_HEADERS(paths.h)
 257 AC_CHECK_HEADERS(mntent.h)
 258 AC_CHECK_HEADERS(mnttab.h)
 259 AC_CHECK_HEADERS(sys/fstyp.h)
 260 AC_CHECK_HEADERS(sys/fs_types.h)
 261 AC_CHECK_HEADERS(sys/mntent.h)
 262 AC_CHECK_HEADERS(sys/mnttab.h)
 263 AC_CHECK_HEADERS(sys/mount.h)
 264 AC_CHECK_HEADERS(sys/statfs.h)
 265 AC_CHECK_HEADERS(sys/statvfs.h)
 266 AC_CHECK_HEADERS(sys/vfs.h)
 267 AC_CHECK_HEADERS(sys/vfstab.h)
 268
 269 # For the swap plugin, FreeBSD
 270 AC_CHECK_HEADERS(kvm.h)
 271
 272 # For the email plugin
 273 AC_CHECK_HEADERS(linux/un.h, [], [],
 274 [
 275 #if HAVE_SYS_SOCKET_H
 276 #       include <sys/socket.h>
 277 #endif
 278 ])
 279 AC_CHECK_HEADERS(sys/un.h)
 280 AC_CHECK_HEADERS(grp.h)
 281
 282 # For debugging interface (variable number of arguments)
 283 AC_CHECK_HEADERS(stdarg.h)
 284
 285 # Regular expressions for the ignorelist.
 286 AC_CHECK_HEADERS(regex.h)
 287
 288 # For the dns plugin
 289 AC_CHECK_HEADERS(arpa/nameser.h arpa/nameser_compat.h)
 290
 291 AC_CHECK_HEADERS(net/if_arp.h)
 292 AC_CHECK_HEADERS(net/if_ppp.h)
 293 AC_CHECK_HEADERS(netinet/if_ether.h)
 294 AC_CHECK_HEADERS(netinet/tcp.h)
 295 AC_CHECK_HEADERS(netinet/udp.h)
 296
 297 dnl Checking for libraries
 298 AC_CHECK_LIB(m, ext)
 299
 300 #
 301 # Checks for typedefs, structures, and compiler characteristics.
 302 #
 303 AC_C_CONST
 304 AC_TYPE_PID_T
 305 AC_TYPE_SIZE_T
 306 AC_TYPE_UID_T
 307 AC_HEADER_TIME
 308
 309 #
 310 # Checks for library functions.
 311 #
 312 AC_PROG_GCC_TRADITIONAL
 313 AC_CHECK_FUNCS(gettimeofday select strdup strtol)
 314 AC_CHECK_FUNCS(getaddrinfo getnameinfo)
 315 AC_CHECK_FUNCS(strchr memcpy strstr strcmp strncmp strncpy strlen)
 316 AC_CHECK_FUNCS(strncasecmp strcasecmp)
 317 AC_CHECK_FUNCS(openlog syslog closelog)
 318
 319 socket_needs_socket="no"
 320 AC_CHECK_FUNCS(socket, [], AC_CHECK_LIB(socket, socket, [socket_needs_socket="yes"], AC_MSG_ERROR(cannot find socket)))
 321 AM_CONDITIONAL(BUILD_WITH_LIBSOCKET, test "x$socket_needs_socket" = "xyes")
 322
 323 nanosleep_needs_rt="no"
 324 AC_CHECK_FUNCS(nanosleep, [], AC_CHECK_LIB(rt, nanosleep, [nanosleep_needs_rt="yes"], AC_MSG_ERROR(cannot find nanosleep)))
 325 AM_CONDITIONAL(BUILD_WITH_LIBRT, test "x$nanosleep_needs_rt" = "xyes")
 326
 327 # Regular expressions for the ignorelist.
 328 AC_CHECK_FUNCS(regcomp regerror regexec regfree)
 329
 330 # For cpu module
 331 AC_CHECK_FUNCS(sysctlbyname, [have_sysctlbyname="yes"], [have_sysctlbyname="no"])
 332
 333 # For df module
 334 AC_CHECK_FUNCS(statfs statvfs)
 335
 336 # For load module
 337 AC_CHECK_FUNCS(getloadavg, [have_getloadavg="yes"], [have_getloadavg="no"])
 338
 339 # For the `processes' plugin
 340 AC_CHECK_FUNCS(thread_info)
 341
 342 # For users module
 343 AC_CHECK_FUNCS(getutent getutxent)
 344
 345 # For quota module
 346 AC_CHECK_FUNCS(quotactl)
 347 AC_CHECK_FUNCS(getgrgid getpwuid)
 348
 349 # For traffic module
 350 AC_CHECK_FUNCS(getifaddrs)
 351
 352 # For mount interface
 353 #AC_CHECK_FUNCS(getfsent getvfsent)
 354
 355 have_getfsstat="no"
 356 AC_CHECK_FUNCS(getfsstat, [have_getfsstat="yes"])
 357 have_getvfsstat="no"
 358 AC_CHECK_FUNCS(getvfsstat, [have_getvfsstat="yes"])
 359 have_listmntent="no"
 360 AC_CHECK_FUNCS(listmntent, [have_listmntent="yes"])
 361
 362 have_getmntent="no"
 363 AC_CHECK_FUNCS(getmntent, [have_getmntent="c"])
 364 if test "x$have_getmntent" = "xno"; then
 365         AC_CHECK_LIB(sun, getmntent, [have_getmntent="sun"])
 366 fi
 367 if test "x$have_getmntent" = "xno"; then
 368         AC_CHECK_LIB(seq, getmntent, [have_getmntent="seq"])
 369 fi
 370 if test "x$have_getmntent" = "xno"; then
 371         AC_CHECK_LIB(gen, getmntent, [have_getmntent="gen"])
 372 fi
 373
 374 if test "x$have_getmntent" = "xc"; then
 375         AC_CACHE_CHECK([whether getmntent takes one argument],
 376                 [have_one_getmntent],
 377                 AC_COMPILE_IFELSE(
 378                         AC_LANG_PROGRAM([[AC_INCLUDES_DEFAULT
 379 #include <mntent.h>
 380 #include "$srcdir/src/utils_mount.h"]],
 381                                 [[
 382                                  FILE *fh;
 383                                  struct mntent *me;
 384                                  fh = setmntent ("/etc/mtab", "r");
 385                                  me = getmntent (fh);
 386                                 ]]
 387                         ),
 388                         [have_one_getmntent="yes"],
 389                         [have_one_getmntent="no"]
 390                 )
 391         )
 392         AC_CACHE_CHECK([whether getmntent takes two arguments],
 393                 [have_two_getmntent],
 394                 AC_COMPILE_IFELSE(
 395                         AC_LANG_PROGRAM([[AC_INCLUDES_DEFAULT
 396 #include <sys/mnttab.h>
 397 #include "$srcdir/src/utils_mount.h"]],
 398                                 [[
 399                                  FILE *fh;
 400                                  struct mnttab mt;
 401                                  int status;
 402                                  fh = fopen ("/etc/mnttab", "r");
 403                                  status = getmntent (fh, &mt);
 404                                 ]]
 405                         ),
 406                         [have_two_getmntent="yes"],
 407                         [have_two_getmntent="no"]
 408                 )
 409         )
 410 fi
 411
 412 # Check for different versions of `getmntent' here..
 413
 414 if test "x$have_getmntent" = "xc"; then
 415         if test "x$have_one_getmntent" = "xyes"; then
 416                 AC_DEFINE(HAVE_ONE_GETMNTENT, 1,
 417                           [Define if the function getmntent exists and takes one argument.])
 418         fi
 419         if test "x$have_two_getmntent" = "xyes"; then
 420                 AC_DEFINE(HAVE_TWO_GETMNTENT, 1,
 421                           [Define if the function getmntent exists and takes two arguments.])
 422         fi
 423 fi
 424 if test "x$have_getmntent" = "xsun"; then
 425         AC_DEFINE(HAVE_SUN_GETMNTENT, 1,
 426                   [Define if the function getmntent exists. It's the version from libsun.])
 427 fi
 428 if test "x$have_getmntent" = "xseq"; then
 429         AC_DEFINE(HAVE_SEQ_GETMNTENT, 1,
 430                   [Define if the function getmntent exists. It's the version from libseq.])
 431 fi
 432 if test "x$have_getmntent" = "xgen"; then
 433         AC_DEFINE(HAVE_GEN_GETMNTENT, 1,
 434                   [Define if the function getmntent exists. It's the version from libgen.])
 435 fi
 436
 437 # Check for structures
 438 AC_CHECK_MEMBERS([struct if_data.ifi_ibytes, struct if_data.ifi_opackets, struct if_data.ifi_ierrors],
 439         [AC_DEFINE(HAVE_STRUCT_IF_DATA, 1, [Define if struct if_data exists and is usable.])],
 440         [],
 441         [
 442         #include <sys/types.h>
 443         #include <sys/socket.h>
 444         #include <net/if.h>
 445         ])
 446 AC_CHECK_MEMBERS([struct net_device_stats.rx_bytes, struct net_device_stats.tx_packets, struct net_device_stats.rx_errors],
 447         [AC_DEFINE(HAVE_STRUCT_NET_DEVICE_STATS, 1, [Define if struct net_device_stats exists and is usable.])],
 448         [],
 449         [
 450         #include <sys/types.h>
 451         #include <sys/socket.h>
 452         #include <linux/if.h>
 453         #include <linux/netdevice.h>
 454         ])
 455
 456 AC_MSG_CHECKING([for kernel type ($host_os)])
 457 case $host_os in
 458         *linux*)
 459         AC_DEFINE([KERNEL_LINUX], 1, [True if program is to be compiled for a Linux kernel])
 460         ac_system="Linux"
 461         ;;
 462         *solaris*)
 463         AC_DEFINE([KERNEL_SOLARIS], 1, [True if program is to be compiled for a Solaris kernel])
 464         ac_system="Solaris"
 465         ;;
 466         *)
 467         ac_system="unknown"
 468 esac
 469 AC_MSG_RESULT([$ac_system])
 470
 471 with_libresolv="yes"
 472 AC_CHECK_LIB(resolv, res_search,
 473 [
 474         AC_DEFINE(HAVE_LIBRESOLV, 1, [Define to 1 if you have the 'resolv' library (-lresolv).])
 475 ],
 476 [with_libresolv="no"])
 477 AM_CONDITIONAL(BUILD_WITH_LIBRESOLV, test "x$with_libresolv" = "xyes")
 478
 479
 480 m4_divert_once([HELP_WITH], [
 481 collectd additional packages:])
 482
 483 # AC_ARG_WITH (package, help-string, [action-if-given], [action-if-not-given])
 484 AC_ARG_WITH(rrdtool, [AS_HELP_STRING([--with-rrdtool@<:@=PREFIX@:>@], [Path to rrdtool.])],
 485 [       if test "x$withval" != "xno" && test "x$withval" != "xyes"
 486         then
 487                 LDFLAGS="$LDFLAGS -L$withval/lib"
 488                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 489                 with_rrdtool="yes"
 490         fi
 491 ], [with_rrdtool="yes"])
 492 if test "x$with_rrdtool" = "xyes"
 493 then
 494         AC_CHECK_LIB(rrd, rrd_update,
 495         [
 496                 AC_DEFINE(HAVE_LIBRRD, 1, [Define to 1 if you have the rrd library (-lrrd).])
 497         ],
 498         [with_rrdtool="no (librrd not found)"], [-lm])
 499 fi
 500 if test "x$with_rrdtool" = "xyes"
 501 then
 502         AC_CHECK_HEADERS(rrd.h,, [with_rrdtool="no (rrd.h not found)"])
 503 fi
 504 if test "x$with_rrdtool" = "xyes"
 505 then
 506         collect_rrdtool=1
 507 else
 508         collect_rrdtool=0
 509 fi
 510 AC_DEFINE_UNQUOTED(COLLECT_RRDTOOL, [$collect_rrdtool],
 511         [Wether or not to use rrdtool library])
 512 AM_CONDITIONAL(BUILD_WITH_RRDTOOL, test "x$with_rrdtool" = "xyes")
 513
 514 AC_ARG_WITH(libpthread, [AS_HELP_STRING([--with-libpthread=@<:@=PREFIX@:>@], [Path to libpthread.])],
 515 [       if test "x$withval" != "xno" -a "x$withval" != "xyes"
 516         then
 517                 LDFLAGS="$LDFLAGS -L$withval/lib"
 518                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 519                 with_libpthread="yes"
 520         else
 521                 if test "x$withval" = "xno"
 522                 then
 523                         with_libpthread="no (disabled)"
 524                 fi
 525         fi
 526 ], [with_libpthread="yes"])
 527 if test "x$with_libpthread" = "xyes"
 528 then
 529         AC_CHECK_LIB(pthread, pthread_create, [with_libpthread="yes"], [with_libpthread="no (libpthread not found)"], [])
 530 fi
 531 if test "x$with_libpthread" = "xyes"
 532 then
 533         AC_CHECK_HEADERS(pthread.h,, [with_libpthread="no (pthread.h not found)"])
 534 fi
 535 if test "x$with_libpthread" = "xyes"
 536 then
 537         collect_pthread=1
 538 else
 539         collect_pthread=0
 540 fi
 541 AC_DEFINE_UNQUOTED(HAVE_LIBPTHREAD, [$collect_pthread],
 542         [Wether or not to use pthread (POSIX threads) library])
 543 AM_CONDITIONAL(BUILD_WITH_LIBPTHREAD, test "x$with_libpthread" = "xyes")
 544
 545 if test "$ac_system" = "Solaris"
 546 then
 547         with_kstat="yes"
 548         with_devinfo="yes"
 549 else
 550         with_kstat="no (Solaris only)"
 551         with_devinfo="no (Solaris only)"
 552 fi
 553
 554 if test "x$with_kstat" = "xyes"
 555 then
 556         AC_CHECK_LIB(kstat, kstat_open,, [with_kstat="no (libkstat not found)"])
 557 fi
 558 if test "x$with_kstat" = "xyes"
 559 then
 560         AC_CHECK_LIB(devinfo, di_init,, [with_devinfo="no (not found)"])
 561         AC_CHECK_HEADERS(kstat.h,, [with_kstat="no (kstat.h not found)"])
 562 fi
 563 if test "x$with_kstat" = "xyes"
 564 then
 565         collect_kstat=1
 566 else
 567         collect_kstat=0
 568 fi
 569 AC_DEFINE_UNQUOTED(COLLECT_KSTAT, [$collect_kstat],
 570         [Wether or not to use kstat library (Solaris)])
 571 AM_CONDITIONAL(BUILD_WITH_LIBKSTAT, test "x$with_kstat" = "xyes")
 572 AM_CONDITIONAL(BUILD_WITH_LIBDEVINFO, test "x$with_devinfo" = "xyes")
 573
 574 ### BEGIN of check for libcurl ###
 575 with_curl_config="curl-config"
 576 with_curl_prefix=0
 577 with_curl_libs=""
 578 AC_ARG_WITH(libcurl, [AS_HELP_STRING([--with-libcurl@<:@=PREFIX@:>@], [Path to libcurl.])],
 579 [
 580         if test "x$withval" != "xno" -a "x$withval" != "xyes"
 581         then
 582                 if test -x "$withval/bin/curl-config"
 583                 then
 584                         with_curl_config="$withval/bin/curl-config"
 585                         with_curl_prefix=1
 586                 fi
 587         fi
 588         if test "x$withval" = "xno"
 589         then
 590                 with_libcurl="no"
 591         else
 592                 with_libcurl="yes"
 593         fi
 594 ],
 595 [
 596         with_libcurl="yes"
 597 ])
 598 if test "x$with_libcurl" = "xyes"
 599 then
 600         with_curl_libs=`$with_curl_config --libs 2>/dev/null`
 601         curl_config_status=$?
 602
 603         if test $curl_config_status -ne 0
 604         then
 605                 with_libcurl="no"
 606         else
 607                 AC_CHECK_LIB(curl, curl_easy_init,
 608                 [
 609                         BUILD_WITH_LIBCURL_LIBS="$with_curl_libs"
 610                         AC_SUBST(BUILD_WITH_LIBCURL_LIBS)
 611                 ],
 612                 [
 613                         with_libcurl="no"
 614                 ],
 615                 [$with_curl_libs])
 616         fi
 617 fi
 618 if test "x$with_libcurl" = "xyes" -a $with_curl_prefix -ne 0
 619 then
 620         with_curl_prefix=`$with_curl_config --libs 2>/dev/null`
 621         curl_config_status=$?
 622
 623         if test $curl_config_status -ne 0
 624         then
 625                 with_libcurl="no"
 626         else
 627                 if test -d "$with_curl_prefix/include"
 628                 then
 629                         CPPFLAGS="$CPPFLAGS -I$with_curl_prefix/include"
 630                 fi
 631         fi
 632 fi
 633
 634 with_libcurl_numeric=0
 635 if test "x$with_libcurl" = "xyes"
 636 then
 637         with_libcurl_numeric=1
 638 fi
 639 AC_DEFINE_UNQUOTED(HAVE_LIBCURL, [$with_libcurl_numeric], [Define to 1 if you have the 'curl' library (-lcurl).])
 640 AM_CONDITIONAL(BUILD_WITH_LIBCURL, test "x$with_libcurl" = "xyes")
 641 ### END of check for libcurl ###
 642
 643 with_libiokit="no"
 644 collectd_libiokit=0
 645 AC_CHECK_LIB(IOKit, IOServiceGetMatchingServices,
 646 [
 647         with_libiokit="yes"
 648         collectd_libiokit=1
 649 ],
 650 [
 651         with_libiokit="no"
 652         collectd_libiokit=0
 653 ])
 654 AC_DEFINE_UNQUOTED(COLLECT_LIBIOKIT, [$collect_libiokit], [Wether or not to use the IOKit library])
 655 AM_CONDITIONAL(BUILD_WITH_LIBIOKIT, test "x$with_libiokit" = "xyes")
 656
 657 with_libstatgrab="yes"
 658 with_libdevstat="no"
 659 AC_ARG_WITH(libstatgrab, [AS_HELP_STRING([--with-libstatgrab@<:@=PREFIX@:>@], [Path to libstatgrab.])],
 660 [
 661         if test "x$withval" != "xno" -a "x$withval" != "xyes"
 662         then
 663                 LDFLAGS="$LDFLAGS -L$withval/lib"
 664                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 665                 with_libstatgrab="yes"
 666         fi
 667 ],
 668 [
 669         if test "x$ac_system" == "xunknown"
 670         then
 671                 with_libstatgrab="yes"
 672         else
 673                 with_libstatgrab="no"
 674         fi
 675 ])
 676 if test "x$with_libstatgrab" = "xyes"
 677 then
 678         AC_CHECK_LIB(statgrab, sg_init, [with_libstatgrab="yes"], [with_libstatgrab="no (libstatgrab not found)"])
 679 fi
 680 if test "x$with_libstatgrab" = "xyes"
 681 then
 682         AC_CHECK_HEADERS(statgrab.h,,    [with_libstatgrab="no (statgrab.h not found)"])
 683 fi
 684 if test "x$with_libstatgrab" = "xyes"
 685 then
 686         AC_CHECK_LIB(devstat, getdevs, [with_libdevstat="yes"], [with_libdevstat="no"])
 687 fi
 688 if test "x$with_libstatgrab" = "xyes"
 689 then
 690         collect_libstatgrab=1
 691 else
 692         collect_libstatgrab=0
 693 fi
 694 AC_DEFINE_UNQUOTED(COLLECT_LIBSTATGRAB, [$collect_libstatgrab],
 695         [Wether or not to use statgrab library])
 696 AM_CONDITIONAL(BUILD_WITH_LIBSTATGRAB, test "x$with_libstatgrab" = "xyes")
 697 AM_CONDITIONAL(BUILD_WITH_LIBDEVSTAT,  test "x$with_libdevstat"  = "xyes")
 698
 699 AC_CHECK_LIB(kvm, kvm_getswapinfo, [with_libkvm="yes"], [with_libkvm="no"])
 700 if test "x$with_libkvm" = "xyes"
 701 then
 702         AC_DEFINE(HAVE_LIBKVM, 1, [Define to 1 if you have the 'kvm' library (-lkvm)])
 703 fi
 704 AM_CONDITIONAL(BUILD_WITH_LIBKVM, test "x$with_libkvm" = "xyes")
 705
 706 AC_ARG_WITH(lm-sensors, [AS_HELP_STRING([--with-lm-sensors@<:@=PREFIX@:>@], [Path to lm_sensors.])],
 707 [
 708         if test "x$withval" != "xno" && test "x$withval" != "xyes"
 709         then
 710                 LDFLAGS="$LDFLAGS -L$withval/lib"
 711                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 712                 with_lm_sensors="yes"
 713         fi
 714 ],
 715 [
 716         if test "x$ac_system" = "xLinux"
 717         then
 718                 with_lm_sensors="yes"
 719         else
 720                 with_lm_sensors="no"
 721         fi
 722 ])
 723 if test "x$with_lm_sensors" = "xyes"
 724 then
 725         AC_CHECK_LIB(sensors, sensors_init,
 726         [
 727                 AC_DEFINE(HAVE_LIBSENSORS, 1, [Define to 1 if you have the sensors library (-lsensors).])
 728         ],
 729         [with_lm_sensors="no (libsensors not found)"])
 730 fi
 731 if test "x$with_lm_sensors" = "xyes"
 732 then
 733         AC_CHECK_HEADERS(sensors/sensors.h,
 734         [
 735                 AC_DEFINE(HAVE_SENSORS_SENSORS_H, 1, [Define to 1 if you have the <sensors/sensors.h> header file.])
 736         ],
 737         [with_lm_sensors="no (sensors/sensors.h not found)"])
 738 fi
 739 if test "x$with_lm_sensors" = "xyes"
 740 then
 741         collect_lm_sensors=1
 742 else
 743         collect_lm_sensors=0
 744 fi
 745 AC_DEFINE_UNQUOTED(COLLECT_LM_SENSORS, [$collect_lm_sensors],
 746         [Wether or not to use sensors library])
 747 AM_CONDITIONAL(BUILD_WITH_LM_SENSORS, test "x$with_lm_sensors" = "xyes")
 748
 749 AC_ARG_WITH(libmysql, [AS_HELP_STRING([--with-libmysql@<:@=PREFIX@:>@], [Path to libmysql.])],
 750 [
 751         if test "x$withval" != "xno" && test "x$withval" != "xyes"
 752         then
 753                 LDFLAGS="$LDFLAGS -L$withval/lib"
 754                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 755                 with_libmysql="yes"
 756         fi
 757 ],
 758 [
 759         with_libmysql="yes"
 760 ])
 761 if test "x$with_libmysql" = "xyes"
 762 then
 763         AC_CHECK_LIB(mysqlclient, mysql_init,
 764         [
 765                 AC_DEFINE(HAVE_LIBMYSQLCLIENT, 1, [Define to 1 if you have the mysqlclient library (-lmysqlclient).])
 766         ], [with_libmysql="no (libmysql not found)"])
 767 fi
 768 if test "x$with_libmysql" = "xyes"
 769 then
 770         AC_CHECK_HEADERS(mysql/mysql.h,
 771         [
 772                 AC_DEFINE(HAVE_MYSQL_MYSQL_H, 1, [Define to 1 if you have the <mysql/mysql.h> header file.])
 773         ], [with_libmysql="no (mysql/mysql.h not found)"])
 774 fi
 775 if test "x$with_libmysql" = "xyes"
 776 then
 777         collect_libmysql=1
 778 else
 779         collect_libmysql=0
 780 fi
 781 AC_DEFINE_UNQUOTED(COLLECT_LIBMYSQL, [$collect_libmysql],
 782         [Wether or not to use mysql library])
 783 AM_CONDITIONAL(BUILD_WITH_LIBMYSQL, test "x$with_libmysql" = "xyes")
 784
 785 #with_liboping="yes"
 786 with_own_liboping="no"
 787 liboping_LDFLAGS="$LDFLAGS"
 788 liboping_CPPFLAGS="$CPPFLAGS"
 789 AC_ARG_WITH(liboping, [AS_HELP_STRING([--with-liboping@<:@=PREFIX@:>@], [Path to liboping.])],
 790 [
 791         if test "x$withval" != "xno" && test "x$withval" != "xyes"
 792         then
 793                 if test -d "$withval/lib"
 794                 then
 795                         liboping_LDFLAGS="$LDFLAGS -L$withval/lib"
 796                 fi
 797                 if test -d "$withval/include"
 798                 then
 799                         liboping_CPPFLAGS="$CPPFLAGS -I$withval/include"
 800                 fi
 801         fi
 802         if test "x$withval" = "xno"
 803         then
 804                 with_liboping="no"
 805                 with_own_liboping="no"
 806         fi
 807 ],
 808 [
 809         #753
 810         with_liboping="yes"
 811 ])
 812
 813 if test "x$with_liboping" = "xyes"
 814 then
 815         save_LDFLAGS="$LDFLAGS"
 816         save_CPPFLAGS="$CPPFLAGS"
 817         LDFLAGS="$liboping_LDFLAGS"
 818         CPPFLAGS="$liboping_CPPFLAGS"
 819         AC_CHECK_LIB(oping, ping_construct,
 820         [
 821                 with_liboping="yes"
 822                 with_own_liboping="no"
 823         ],
 824         [
 825                 with_liboping="yes"
 826                 with_own_liboping="yes"
 827                 LDFLAGS="$save_LDFLAGS"
 828                 CPPFLAGS="$save_CPPFLAGS"
 829         ])
 830 fi
 831 AM_CONDITIONAL(BUILD_WITH_LIBOPING, test "x$with_liboping" = "xyes")
 832 AM_CONDITIONAL(BUILD_WITH_OWN_LIBOPING, test "x$with_own_liboping" = "xyes")
 833 if test "x$with_liboping" = "xyes" -a "x$with_own_liboping" = "xyes"
 834 then
 835         with_liboping="yes (shipped version)"
 836 fi
 837
 838 AC_ARG_WITH(libpcap, [AS_HELP_STRING([--with-libpcap@<:@=PREFIX@:>@], [Path to libpcap.])],
 839 [
 840         if test "x$withval" != "xno" && test "x$withval" != "xyes"
 841         then
 842                 LDFLAGS="$LDFLAGS -L$withval/lib"
 843                 CPPFLAGS="$CPPFLAGS -I$withval/include"
 844                 with_libpcap="yes"
 845         fi
 846 ],
 847 [
 848         with_libpcap="yes"
 849 ])
 850 if test "x$with_libpcap" = "xyes"
 851 then
 852         AC_CHECK_LIB(pcap, pcap_open_live,
 853         [
 854                 AC_DEFINE(HAVE_LIBPCAP, 1, [Define to 1 if you have the pcap library (-lpcap).])
 855         ], [with_libpcap="no (libpcap not found)"])
 856 fi
 857 if test "x$with_libpcap" = "xyes"
 858 then
 859         AC_CHECK_HEADERS(pcap.h,
 860         [
 861                 AC_DEFINE(HAVE_PCAP_H, 1, [Define to 1 if you have the <pcap.h> header file.])
 862         ], [with_libpcap="no (pcap.h not found)"])
 863 fi
 864 if test "x$with_libpcap" = "xyes"
 865 then
 866         collect_libpcap=1
 867 else
 868         collect_libpcap=0
 869 fi
 870 AC_DEFINE_UNQUOTED(COLLECT_LIBPCAP, [$collect_libpcap],
 871         [Wether or not to use the pcap library])
 872 AM_CONDITIONAL(BUILD_WITH_LIBPCAP, test "x$with_libpcap" = "xyes")
 873
 874 # Define `step' and `hearbeat' values..
 875 declare -i collectd_step=10
 876 declare -i collectd_heartbeat=25
 877 AC_ARG_WITH(step, [AS_HELP_STRING([--with-step=SECONDS], [Interval in which plugins are queried.])],
 878 [
 879         if test "x$withval" != "xno" -a "x$withval" != "xyes"
 880         then
 881                 declare -i tmp_collectd_step="$withval"
 882                 if test $tmp_collectd_step -gt 0
 883                 then
 884                         collectd_step=$tmp_collectd_step
 885                         let "collectd_heartbeat=$collectd_step*2"
 886                 fi
 887         fi
 888 ], [])
 889 AC_ARG_WITH(heartbeat, [AS_HELP_STRING([--with-heartbeat=SECONDS], [Heartbeat of the DS in generated RRD files.])],
 890 [
 891         if test "x$withval" != "xno" -a "x$withval" != "xyes"
 892         then
 893                 declare -i tmp_collectd_heartbeat="$withval"
 894                 if test $tmp_collectd_heartbeat -gt 0
 895                 then
 896                         collectd_heartbeat=$tmp_collectd_heartbeat
 897                 fi
 898         fi
 899 ], [])
 900
 901 if test $collectd_step -ne 10
 902 then
 903         AC_DEFINE_UNQUOTED(COLLECTD_STEP, "$collectd_step", [Interval in which plugins are queried.])
 904 fi
 905 if test $collectd_heartbeat -ne 25
 906 then
 907         AC_DEFINE_UNQUOTED(COLLECTD_HEARTBEAT, "$collectd_heartbeat", [Interval in which plugins are queried.])
 908 fi
 909
 910 # Check for enabled/disabled features
 911 #
 912
 913 # AC_COLLECTD(name, enable/disable, info-text, feature/module)
 914 # ------------------------------------------------------------
 915 dnl
 916 m4_define([my_toupper], [m4_translit([$1], m4_defn([m4_cr_letters]), m4_defn([m4_cr_LETTERS]))])
 917 dnl
 918 AC_DEFUN(
 919         [AC_COLLECTD],
 920         [
 921         m4_if([$1], [], [AC_FATAL([AC_COLLECTD([$1], [$2], [$3], [$4]): 1st argument must not be empty])])dnl
 922         m4_if(
 923                 [$2],
 924                 [enable],
 925                 [dnl
 926                 m4_define([EnDis],[disabled])dnl
 927                 m4_define([YesNo],[no])dnl
 928                 ],dnl
 929                 [m4_if(
 930                         [$2],
 931                         [disable],
 932                         [dnl
 933                         m4_define([EnDis],[enabled])dnl
 934                         m4_define([YesNo],[yes])dnl
 935                         ],
 936                         [dnl
 937                         AC_FATAL([AC_COLLECTD([$1], [$2], [$3], [$4]): 2nd argument must be either enable or disable])dnl
 938                         ]dnl
 939                 )]dnl
 940         )dnl
 941         m4_if([$3], [feature], [],
 942                 [m4_if(
 943                         [$3], [module], [],
 944                         [dnl
 945                         AC_FATAL([AC_COLLECTD([$1], [$2], [$3], [$4]): 3rd argument must be either feature or disable])dnl
 946                         ]dnl
 947                 )]dnl
 948         )dnl
 949         AC_ARG_ENABLE(
 950                 [$1],
 951                 AS_HELP_STRING([--$2-$1], [$2 $4 (EnDis by def)]),
 952                 [],
 953                 enable_$1='[YesNo]'dnl
 954         )# AC_ARG_ENABLE
 955 if test "x$enable_$1" = "xno"
 956 then
 957         collectd_$1=0
 958 else
 959         if test "x$enable_$1" = "xyes"
 960         then
 961                 collectd_$1=1
 962         else
 963                 AC_MSG_NOTICE([please specify either --enable-$1 or --disable-$1; enabling $1.])
 964                 collectd_$1=1
 965                 enable_$1='yes'
 966         fi
 967 fi
 968         AC_DEFINE_UNQUOTED([COLLECT_]my_toupper([$1]), [$collectd_$1], [wether or not to enable $3 $4])
 969         AM_CONDITIONAL([BUILD_]my_toupper([$3])[_]my_toupper([$1]), [test "x$enable_$1" = "xyes"])dnl
 970         ]dnl
 971 )# AC_COLLECTD(name, enable/disable, info-text, feature/module)
 972
 973 m4_divert_once([HELP_ENABLE], [
 974 collectd features:])
 975 AC_COLLECTD([debug],     [enable],  [feature], [debugging])
 976 AC_COLLECTD([daemon],    [disable], [feature], [daemon mode])
 977 AC_COLLECTD([getifaddrs],[enable],  [feature], [getifaddrs under Linux])
 978
 979 m4_divert_once([HELP_ENABLE], [
 980 collectd modules:])
 981 AC_COLLECTD([apache],    [disable], [module], [Apache httpd statistics])
 982 AC_COLLECTD([apcups],    [disable], [module], [Statistics of UPSes by APC])
 983 AC_COLLECTD([apple_sensors], [disable], [module], [Apple's hardware sensors])
 984 AC_COLLECTD([battery],   [disable], [module], [battery statistics])
 985 AC_COLLECTD([cpu],       [disable], [module], [cpu usage statistics])
 986 AC_COLLECTD([cpufreq],   [disable], [module], [system cpu frequency statistics])
 987 AC_COLLECTD([disk],      [disable], [module], [disk/partition statistics])
 988 AC_COLLECTD([csv],       [disable], [module], [csv output plugin])
 989 AC_COLLECTD([df],        [disable], [module], [df statistics])
 990 AC_COLLECTD([dns],       [disable], [module], [dns statistics])
 991 AC_COLLECTD([email],     [disable], [module], [email statistics])
 992 AC_COLLECTD([entropy],   [disable], [module], [entropy statistics])
 993 AC_COLLECTD([hddtemp],   [disable], [module], [hdd temperature statistics])
 994 AC_COLLECTD([load],      [disable], [module], [system load statistics])
 995 AC_COLLECTD([mbmon],     [disable], [module], [motherboard monitor statistics])
 996 AC_COLLECTD([memory],    [disable], [module], [memory statistics])
 997 AC_COLLECTD([multimeter],[disable], [module], [multimeter statistics])
 998 AC_COLLECTD([mysql],     [disable], [module], [mysql statistics])
 999 AC_COLLECTD([network],   [disable], [module], [network functionality])
1000 AC_COLLECTD([nfs],       [disable], [module], [nfs statistics])
1001 AC_COLLECTD([ntpd],      [disable], [module], [nfs statistics])
1002 AC_COLLECTD([ping],      [disable], [module], [ping statistics])
1003 AC_COLLECTD([processes], [disable], [module], [processes statistics])
1004 AC_COLLECTD([sensors],   [disable], [module], [lm_sensors statistics])
1005 AC_COLLECTD([serial],    [disable], [module], [serial statistics])
1006 AC_COLLECTD([swap],      [disable], [module], [swap statistics])
1007 AC_COLLECTD([tape],      [disable], [module], [tape statistics])
1008 AC_COLLECTD([traffic],   [disable], [module], [system traffic statistics])
1009 AC_COLLECTD([unixsock],  [disable], [module], [UNIX socket plugin])
1010 AC_COLLECTD([users],     [disable], [module], [user count statistics])
1011 AC_COLLECTD([vserver],   [disable], [module], [vserver statistics])
1012 AC_COLLECTD([wireless],  [disable], [module], [wireless link statistics])
1013
1014 AC_OUTPUT(Makefile src/Makefile src/collectd.conf src/libconfig/Makefile src/liboping/Makefile)
1015
1016 cat <<EOF;
1017
1018 Configuration:
1019   Libraries:
1020     libcurl . . . . . . $with_libcurl
1021     libiokit  . . . . . $with_libiokit
1022     liboping  . . . . . $with_liboping
1023     librrd  . . . . . . $with_rrdtool
1024     lm_sensors  . . . . $with_lm_sensors
1025     libstatgrab . . . . $with_libstatgrab
1026     libkstat  . . . . . $with_kstat
1027     libmysql  . . . . . $with_libmysql
1028     libpcap . . . . . . $with_libpcap
1029     libpthread  . . . . $with_libpthread
1030
1031   Features:
1032     debug . . . . . . . $enable_debug
1033     daemon mode . . . . $enable_daemon
1034     step  . . . . . . . $collectd_step seconds
1035     heartbeat . . . . . $collectd_heartbeat seconds
1036
1037   Modules:
1038     apache  . . . . . . $enable_apache
1039     apcups  . . . . . . $enable_apcups
1040     apple_sensors . . . $enable_apple_sensors
1041     battery . . . . . . $enable_battery
1042     cpu . . . . . . . . $enable_cpu
1043     cpufreq . . . . . . $enable_cpufreq
1044     csv . . . . . . . . $enable_csv
1045     df  . . . . . . . . $enable_df
1046     disk  . . . . . . . $enable_disk
1047     dns . . . . . . . . $enable_dns
1048     email . . . . . . . $enable_email
1049     entropy . . . . . . $enable_entropy
1050     hddtemp . . . . . . $enable_hddtemp
1051     load  . . . . . . . $enable_load
1052     mbmon . . . . . . . $enable_mbmon
1053     memory  . . . . . . $enable_memory
1054     multimeter  . . . . $enable_multimeter
1055     mysql . . . . . . . $enable_mysql
1056     network . . . . . . $enable_network
1057     nfs . . . . . . . . $enable_nfs
1058     ntpd  . . . . . . . $enable_ntpd
1059     ping  . . . . . . . $enable_ping
1060     processes . . . . . $enable_processes
1061     sensors . . . . . . $enable_sensors
1062     serial  . . . . . . $enable_serial
1063     swap  . . . . . . . $enable_swap
1064     tape  . . . . . . . $enable_tape
1065     traffic . . . . . . $enable_traffic
1066     unixsock  . . . . . $enable_unixsock
1067     users . . . . . . . $enable_users
1068     vserver . . . . . . $enable_vserver
1069     wireless  . . . . . $enable_wireless
1070
1071 EOF