contrib/migrate-3-4.px

   1 #!/usr/bin/perl
   2
   3 use strict;
   4 use warnings;
   5
   6 use Getopt::Long ('GetOptions');
   7 use Data::Dumper ();
   8 use File::Basename ('dirname');
   9
  10 our $InDir = '/var/lib/collectd';
  11 our $OutDir = '/tmp/collectd-4';
  12 our $Hostname = 'localhost';
  13
  14 # Types:
  15 # +------------+----------------------+----+----+----+
  16 # ! Subdir     ! Type                 ! ti ! pi ! ex !
  17 # +------------+----------------------+----+----+----+
  18 # ! apache     ! apache_bytes         !    !    !    !
  19 # ! apache     ! apache_requests      !    !    !    !
  20 # ! apache     ! apache_scoreboard    ! x  !    !    !
  21 # ! battery    ! charge               !    ! x  !    !
  22 # ! apcups     ! charge_percent       !    !    !    !
  23 # !            ! cpu                  ! x  !    ! x  !
  24 # !            ! cpufreq              ! x  !    !    !
  25 # ! battery    ! current              !    ! x  !    !
  26 # ! ntpd       ! delay                ! x  !    !    !
  27 # !            ! df                   ! x  !    !    !
  28 # !            ! disk                 ! x  !    !    !
  29 # ! dns        ! dns_traffic          !    !    !    !
  30 # ! apple_se.. ! fanspeed             ! x  !    !    !
  31 # ! mbmon      ! fanspeed             ! x  !    !    !
  32 # ! apcups     ! frequency            ! x  !    !    !
  33 # ! ntpd       ! frequency_offset     ! x  !    !    !
  34 # !            ! hddtemp              ! x  !    !    !
  35 # ! interface  ! if_errors            !    ! x  !    !
  36 # ! interface  ! if_packets           !    ! x  !    !
  37 # !            ! lm_sensors           !    !    !    !
  38 # !            ! load                 !    !    !    !
  39 # ! apcups     ! load_percent         !    !    !    !
  40 # !            ! memory               !    !    !    !
  41 # !            ! multimeter           !    !    !    !
  42 # ! mysql      ! mysql_commands       ! x  !    !    !
  43 # ! mysql      ! mysql_handler        ! x  !    !    !
  44 # ! mysql      ! mysql_qcache         !    !    !    !
  45 # ! mysql      ! mysql_threads        !    !    !    !
  46 # !            ! nfs2_procedures      ! x  !    ! x  !
  47 # !            ! nfs3_procedures      ! x  !    ! x  !
  48 # ! dns        ! opcode               ! x  !    !    !
  49 # !            ! partition            ! x  !    !    !
  50 # !            ! ping                 ! x  !    !    !
  51 # !            ! processes            !    !    !    !
  52 # ! processes  ! ps_count             ! x  !    !    !
  53 # ! processes  ! ps_cputime           ! x  !    !    !
  54 # ! processes  ! ps_pagefaults        ! x  !    !    !
  55 # ! processes  ! ps_rss               ! x  !    !    !
  56 # ! dns        ! qtype                ! x  !    !    !
  57 # ! dns        ! rcode                ! x  !    !    !
  58 # ! (*)        ! sensors              ! x  !    !    !
  59 # !            ! serial               ! x  !    !    !
  60 # !            ! swap                 !    !    !    !
  61 # !            ! tape                 ! x  !    !    !
  62 # ! apple_se.. ! temperature          ! x  !    !    !
  63 # ! mbmon      ! temperature          ! x  !    !    !
  64 # ! ntpd       ! time_dispersion      ! x  !    !    !
  65 # ! ntpd       ! time_offset          ! x  !    !    !
  66 # ! apcups     ! timeleft             !    !    !    !
  67 # !            ! traffic              ! x  !    !    ! ->rx,tx
  68 # ! vserver    ! traffic              ! x  ! x  !    ! ->rx.tx
  69 # !            ! users                !    !    !    !
  70 # ! apucups    ! voltage              ! x  !    !    !
  71 # ! battery    ! voltage              !    ! x  !    !
  72 # ! mbmon      ! voltage              ! x  !    !    !
  73 # ! vserver    ! vs_memory            !    ! x  !    !
  74 # ! vserver    ! vs_processes         !    ! x  !    !
  75 # ! vserver    ! vs_threads           !    ! x  !    !
  76 # !            ! wireless             ! x  !    !    !
  77 # +------------+----------------------+----+----+----+
  78
  79 our %Subdirs =
  80 (
  81         apache => 0,
  82         apcups => 0,
  83         apple_sensors => 0,
  84         battery => 1,
  85         dns => 0,
  86         interface => 1,
  87         mbmon => 0,
  88         mysql => 0,
  89         ntpd => 0,
  90         processes => 0,
  91         sensors => 1,
  92         vserver => 1
  93 );
  94
  95 our %TypeTranslate =
  96 (
  97         cpu => sub { $_ = shift; $_->{'plugin_instance'} = $_->{'type_instance'}; $_->{'type_instance'} = undef; $_; },
  98         if_errors => sub { $_ = shift; $_->{'type_instance'} = $_->{'plugin_instance'}; $_->{'plugin_instance'} = undef; $_; },
  99         if_packets => sub { $_ = shift; $_->{'type_instance'} = $_->{'plugin_instance'}; $_->{'plugin_instance'} = undef; $_; },
 100         nfs2_procedures => sub { $_ = shift; @$_{qw(plugin plugin_instance type type_instance)} = ('nfs', 'v2' . $_->{'type_instance'}, 'nfs_procedure', undef); $_; },
 101         nfs3_procedures => sub { $_ = shift; @$_{qw(plugin plugin_instance type type_instance)} = ('nfs', 'v3' . $_->{'type_instance'}, 'nfs_procedure', undef); $_; },
 102         partition => sub { $_ = shift; $_->{'plugin'} = 'disk'; $_; },
 103         processes => sub { $_ = shift; $_->{'type'} = 'ps_state'; $_; },
 104         traffic => sub { $_ = shift; $_->{'plugin'} =~ s/^traffic$/interface/; @$_{qw(plugin_instance type)} = (undef, 'if_octets'); $_; }
 105 );
 106
 107 our %TypeSplit =
 108 (
 109         cpu => { from => [qw(user nice syst idle wait)], to => 'value', type_instance => [qw(user nice system idle wait)] },
 110         memory => { from => [qw(used free buffers cached)], to => 'value', type_instance => [qw(used free buffered cached)] },
 111         nfs3_procedures => { from => [qw(null getattr lookup access readlink
 112                 read write create mkdir symlink mknod remove rmdir rename link
 113                 readdir readdirplus fsstat fsinfo pathconf commit)], to => 'value' },
 114         nfs2_procedures => { from => [qw(create fsstat getattr link lookup
 115                 mkdir null read readdir readlink remove rename rmdir root
 116                 setattr symlink wrcache write)], to => 'value' },
 117         processes => { from => [qw(running sleeping zombies stopped paging blocked)], to => 'value' },
 118         swap => { from => [qw(cached free used resv)], to => 'value', type_instance => [qw(cached free used reserved)] }
 119 );
 120
 121 our %TypeRename =
 122 (
 123         traffic => { from => [qw(incoming outgoing)], to => [qw(rx tx)] }
 124 );
 125
 126 GetOptions ("indir|i=s" => \$InDir,
 127         "outdir|o=s" => \$OutDir,
 128         "hostname=s" => \$Hostname) or exit (1);
 129
 130 die "No such directory: $InDir" if (!-d $InDir);
 131 if (!-e $OutDir)
 132 {
 133         mkdir ($OutDir) or die ("mkdir ($OutDir): $!");
 134 }
 135 die "Not a directory: $OutDir" if (!-d $OutDir);
 136
 137 our @Files = ();
 138 our %OutDirs = ();
 139
 140 @Files = find_files ();
 141
 142 for (@Files)
 143 {
 144         my $orig_filename = $_;
 145         my $orig = parse_file ($orig_filename);
 146         my $dest = translate_file ($orig);
 147         my $dest_filename = get_filename ($dest);
 148
 149         my $dest_directory = dirname ($dest_filename);
 150         if (!exists ($OutDirs{$dest_directory}))
 151         {
 152                 print "[ -d '$OutDir/$dest_directory' ] || mkdir -p '$OutDir/$dest_directory'\n";
 153                 $OutDirs{$dest_directory} = 1;
 154         }
 155
 156         if (($orig->{'type'} eq 'disk') || ($orig->{'type'} eq 'partition'))
 157         {
 158                 special_disk ($orig_filename, $orig, $dest_filename, $dest);
 159         }
 160         elsif (exists ($TypeSplit{$orig->{'type'}}))
 161         {
 162                 my $src_dses = $TypeSplit{$orig->{'type'}}->{'from'};
 163                 my $dst_ds = $TypeSplit{$orig->{'type'}}->{'to'};
 164                 my $type_instances = exists ($TypeSplit{$orig->{'type'}}->{'type_instance'})
 165                         ? $TypeSplit{$orig->{'type'}}->{'type_instance'}
 166                         : $TypeSplit{$orig->{'type'}}->{'from'};
 167
 168                 for (my $i = 0; $i < @$src_dses; $i++)
 169                 {
 170                         my $src_ds = $src_dses->[$i];
 171                         $dest->{'type_instance'} = $type_instances->[$i];
 172                         $dest_filename = get_filename ($dest);
 173                         print "./extractDS.px -i '$InDir/$orig_filename' -s '$src_ds' -o '$OutDir/$dest_filename' -d '$dst_ds'\n";
 174                 }
 175         }
 176         elsif (exists ($TypeRename{$orig->{'type'}}))
 177         {
 178                 my $src_dses = $TypeRename{$orig->{'type'}}->{'from'};
 179                 my $dst_dses = $TypeRename{$orig->{'type'}}->{'to'};
 180                 my @sed_prog = ();
 181
 182                 for (my $i = 0; $i < @$src_dses; $i++)
 183                 {
 184                         push (@sed_prog, 's/^' . $src_dses->[$i] . '$/' . $dst_dses->[$i] . '/g;');
 185                 }
 186
 187                 print "rrdtool dump '$InDir/$orig_filename' | sed -e '" . join (' ', @sed_prog) . "' | rrdtool restore - '$OutDir/$dest_filename'\n";
 188         }
 189         else
 190         {
 191                 print "cp '$InDir/$orig_filename' '$OutDir/$dest_filename'\n";
 192         }
 193 }
 194
 195 exit (0);
 196
 197 sub translate_file
 198 {
 199         my $orig = shift;
 200         my $dest = {};
 201         %$dest = %$orig;
 202
 203         if (defined ($TypeTranslate{$orig->{'type'}}))
 204         {
 205                 $TypeTranslate{$orig->{'type'}}->($dest);
 206         }
 207
 208         return ($dest);
 209 } # translate_file
 210
 211 sub get_filename
 212 {
 213         my $args = shift;
 214         my $filename = $args->{'host'}
 215         . '/' . $args->{'plugin'} . (defined ($args->{'plugin_instance'}) ? '-'.$args->{'plugin_instance'} : '')
 216         . '/' . $args->{'type'} . (defined ($args->{'type_instance'}) ? '-'.$args->{'type_instance'} : '') . '.rrd';
 217
 218         return ($filename);
 219 }
 220
 221 sub parse_file
 222 {
 223         my $fullname = shift;
 224         my @parts = split ('/', $fullname);
 225
 226         my $filename;
 227
 228         my $host;
 229         my $plugin;
 230         my $plugin_instance;
 231         my $type;
 232         my $type_instance;
 233
 234         $filename = pop (@parts);
 235
 236         if ($filename =~ m/^([^-]+)(?:-(.*))?\.rrd$/)
 237         {
 238                 $type = $1;
 239                 $type_instance = $2;
 240         }
 241         else
 242         {
 243                 return;
 244         }
 245
 246         if (@parts)
 247         {
 248                 my $dirname = pop (@parts);
 249                 my $regex_str = join ('|', keys (%Subdirs));
 250                 if ($dirname =~ m/^($regex_str)(?:-(.*))?$/)
 251                 {
 252                         $plugin = $1;
 253                         $plugin_instance = $2;
 254                 }
 255                 else
 256                 {
 257                         push (@parts, $dirname);
 258                 }
 259         }
 260         if (!$plugin)
 261         {
 262                 $plugin = $type;
 263         }
 264
 265         if (@parts)
 266         {
 267                 $host = pop (@parts);
 268         }
 269         else
 270         {
 271                 $host = $Hostname;
 272         }
 273
 274         return
 275         ({
 276                 host => $host,
 277                 plugin => $plugin,
 278                 plugin_instance => $plugin_instance,
 279                 type => $type,
 280                 type_instance => $type_instance
 281         });
 282 } # parse_file
 283
 284 sub find_files
 285 {
 286         my $reldir = @_ ? shift : '';
 287         my $absdir = $InDir . ($reldir ? "/$reldir" : '');
 288
 289         my $dh;
 290
 291         my @files = ();
 292         my @dirs = ();
 293
 294         opendir ($dh, $absdir) or die ("opendir ($absdir): $!");
 295         while (my $file = readdir ($dh))
 296         {
 297                 next if ($file =~ m/^\./);
 298                 next if (-l "$absdir/$file");
 299                 if (-d "$absdir/$file")
 300                 {
 301                         push (@dirs, ($reldir ? "$reldir/" : '') . $file);
 302                 }
 303                 elsif ($file =~ m/\.rrd$/)
 304                 {
 305                         push (@files, ($reldir ? "$reldir/" : '') . $file);
 306                 }
 307         }
 308         closedir ($dh);
 309
 310         for (my $i = 0; $i < @dirs; $i++)
 311         {
 312                 push (@files, find_files ($dirs[$i]));
 313         }
 314
 315         return (@files);
 316 } # find_files
 317
 318 {my $cache;
 319 sub _special_disk_instance
 320 {
 321         my $orig_instance = shift;
 322
 323         if (!defined ($cache))
 324         {
 325                 my $fh;
 326                 open ($fh, "< /proc/diskstats") or die ("open (/proc/diststats): $!");
 327
 328                 $cache = {};
 329                 while (my $line = <$fh>)
 330                 {
 331                         chomp ($line);
 332                         my @fields = split (' ', $line);
 333                         $cache->{$fields[0] . '-' . $fields[1]} = $fields[2];
 334                 }
 335                 close ($fh);
 336         }
 337
 338         return (defined ($cache->{$orig_instance})
 339                 ? $cache->{$orig_instance}
 340                 : $orig_instance);
 341 }}
 342
 343 sub special_disk
 344 {
 345         my $orig_filename = shift;
 346         my $orig = shift;
 347         my $dest_filename = shift;
 348         my $dest = shift;
 349
 350         $dest->{'type_instance'} = undef;
 351         $dest->{'plugin_instance'} = _special_disk_instance ($orig->{'type_instance'});
 352         if ($dest->{'plugin_instance'} eq $orig->{'type_instance'})
 353         {
 354                 print qq(echo "You may need to rename these files" >&2\n);
 355         }
 356
 357         $dest->{'type'} = 'disk_merged';
 358         $dest_filename = get_filename ($dest);
 359         print "./extractDS.px -i '$InDir/$orig_filename' -s 'rmerged' -s 'wmerged' -o '$OutDir/$dest_filename' -d 'read' -d 'write'\n";
 360
 361         $dest->{'type'} = 'disk_octets';
 362         $dest_filename = get_filename ($dest);
 363         print "./extractDS.px -i '$InDir/$orig_filename' -s 'rbytes' -s 'wbytes' -o '$OutDir/$dest_filename' -d 'read' -d 'write'\n";
 364
 365         $dest->{'type'} = 'disk_ops';
 366         $dest_filename = get_filename ($dest);
 367         print "./extractDS.px -i '$InDir/$orig_filename' -s 'rcount' -s 'wcount' -o '$OutDir/$dest_filename' -d 'read' -d 'write'\n";
 368
 369         $dest->{'type'} = 'disk_time';
 370         $dest_filename = get_filename ($dest);
 371         print "./extractDS.px -i '$InDir/$orig_filename' -s 'rtime' -s 'wtime' -o '$OutDir/$dest_filename' -d 'read' -d 'write'\n";
 372 }