src/collectd-perl.pod

   1 =head1 NAME
   2
   3 collectd-perl - Documentation of collectd's C<perl plugin>
   4
   5 =head1 SYNOPSIS
   6
   7   <LoadPlugin perl>
   8     Globals true
   9   </LoadPlugin>
  10   # ...
  11   <Plugin perl>
  12     IncludeDir "/path/to/perl/plugins"
  13     BaseName "Collectd::Plugins"
  14     EnableDebugger ""
  15     LoadPlugin "FooBar"
  16
  17     <Plugin FooBar>
  18       Foo "Bar"
  19     </Plugin>
  20   </Plugin>
  21
  22 =head1 DESCRIPTION
  23
  24 The C<perl plugin> embeds a Perl-interpreter into collectd and provides an
  25 interface to collectd's plugin system. This makes it possible to write plugins
  26 for collectd in Perl. This is a lot more efficient than executing a
  27 Perl-script every time you want to read a value with the C<exec plugin> (see
  28 L<collectd-exec(5)>) and provides a lot more functionality, too.
  29
  30 When loading the C<perl plugin>, the B<Globals> option should be enabled.
  31 Else, the perl plugin will fail to load any Perl modules implemented in C,
  32 which includes, amongst many others, the B<threads> module used by the plugin
  33 itself. See the documentation of the B<Globals> option in L<collectd.conf(5)>
  34 for details.
  35
  36 =head1 CONFIGURATION
  37
  38 =over 4
  39
  40 =item B<LoadPlugin> I<Plugin>
  41
  42 Loads the Perl plugin I<Plugin>. This does basically the same as B<use> would
  43 do in a Perl program. As a side effect, the first occurrence of this option
  44 causes the Perl-interpreter to be initialized.
  45
  46 =item B<BaseName> I<Name>
  47
  48 Prepends I<Name>B<::> to all plugin names loaded after this option. This is
  49 provided for convenience to keep plugin names short. All Perl-based plugins
  50 provided with the I<collectd> distributions reside in the C<Collectd::Plugins>
  51 namespace.
  52
  53 =item E<lt>B<Plugin> I<Name>E<gt> block
  54
  55 This block may be used to pass on configuration settings to a Perl plugin. The
  56 configuration is converted into a config-item data type which is passed to the
  57 registered configuration callback. See below for details about the config-item
  58 data type and how to register callbacks.
  59
  60 The I<name> identifies the callback. It is used literally and independent of
  61 the B<BaseName> setting.
  62
  63 =item B<EnableDebugger> I<Package>[=I<option>,...]
  64
  65 Run collectd under the control of the Perl source debugger. If I<Package> is
  66 not the empty string, control is passed to the debugging, profiling, or
  67 tracing module installed as Devel::I<Package>. A comma-separated list of
  68 options may be specified after the "=" character. Please note that you may not
  69 leave out the I<Package> option even if you specify B<"">. This is the same as
  70 using the B<-d:Package> command line option.
  71
  72 See L<perldebug> for detailed documentation about debugging Perl.
  73
  74 This option does not prevent collectd from daemonizing, so you should start
  75 collectd with the B<-f> command line option. Else you will not be able to use
  76 the command line driven interface of the debugger.
  77
  78 =item B<IncludeDir> I<Dir>
  79
  80 Adds I<Dir> to the B<@INC> array. This is the same as using the B<-IDir>
  81 command line option or B<use lib Dir> in the source code. Please note that it
  82 only has effect on plugins loaded after this option.
  83
  84 =back
  85
  86 =head1 WRITING YOUR OWN PLUGINS
  87
  88 Writing your own plugins is quite simple. collectd manages plugins by means of
  89 B<dispatch functions> which call the appropriate B<callback functions>
  90 registered by the plugins. Any plugin basically consists of the implementation
  91 of these callback functions and initializing code which registers the
  92 functions with collectd. See the section "EXAMPLES" below for a really basic
  93 example. The following types of B<callback functions> are known to collectd
  94 (all of them are optional):
  95
  96 =over 4
  97
  98 =item configuration functions
  99
 100 This type of functions is called during configuration if an appropriate
 101 B<Plugin> block has been encountered. It is called once for each B<Plugin>
 102 block which matches the name of the callback as provided with the
 103 B<plugin_register> method - see below.
 104
 105 =item init functions
 106
 107 This type of functions is called once after loading the module and before any
 108 calls to the read and write functions. It should be used to initialize the
 109 internal state of the plugin (e.E<nbsp>g. open sockets, ...). If the return
 110 value evaluates to B<false>, the plugin will be disabled.
 111
 112 =item read functions
 113
 114 This type of function is used to collect the actual data. It is called once
 115 per interval (see the B<Interval> configuration option of collectd). Usually
 116 it will call B<plugin_dispatch_values> to dispatch the values to collectd
 117 which will pass them on to all registered B<write functions>. If the return
 118 value evaluates to B<false> the plugin will be skipped for an increasing
 119 amount of time until it returns B<true> again.
 120
 121 =item write functions
 122
 123 This type of function is used to write the dispatched values. It is called
 124 once for each call to B<plugin_dispatch_values>.
 125
 126 =item flush functions
 127
 128 This type of function is used to flush internal caches of plugins. It is
 129 usually triggered by the user only. Any plugin which caches data before
 130 writing it to disk should provide this kind of callback function.
 131
 132 =item log functions
 133
 134 This type of function is used to pass messages of plugins or the daemon itself
 135 to the user.
 136
 137 =item notification function
 138
 139 This type of function is used to act upon notifications. In general, a
 140 notification is a status message that may be associated with a data instance.
 141 Usually, a notification is generated by the daemon if a configured threshold
 142 has been exceeded (see the section "THRESHOLD CONFIGURATION" in
 143 L<collectd.conf(5)> for more details), but any plugin may dispatch
 144 notifications as well.
 145
 146 =item shutdown functions
 147
 148 This type of function is called once before the daemon shuts down. It should
 149 be used to clean up the plugin (e.g. close sockets, ...).
 150
 151 =back
 152
 153 Any function (except log functions) may set the B<$@> variable to describe
 154 errors in more detail. The message will be passed on to the user using
 155 collectd's logging mechanism.
 156
 157 See the documentation of the B<plugin_register> method in the section
 158 "METHODS" below for the number and types of arguments passed to each
 159 B<callback function>. This section also explains how to register B<callback
 160 functions> with collectd.
 161
 162 To enable a plugin, copy it to a place where Perl can find it (i.E<nbsp>e. a
 163 directory listed in the B<@INC> array) just as any other Perl plugin and add
 164 an appropriate B<LoadPlugin> option to the configuration file. After
 165 restarting collectd you're done.
 166
 167 =head1 DATA TYPES
 168
 169 The following complex types are used to pass values between the Perl plugin
 170 and collectd:
 171
 172 =over 4
 173
 174 =item Config-Item
 175
 176 A config-item is one structure which keeps the information provided in the
 177 configuration file. The array of children keeps one entry for each
 178 configuration option. Each such entry is another config-item structure, which
 179 may nest further if nested blocks are used.
 180
 181   {
 182     key      => key,
 183     values   => [ val1, val2, ... ],
 184     children => [ { ... }, { ... }, ... ]
 185   }
 186
 187 =item Data-Set
 188
 189 A data-set is a list of one or more data-sources. Each data-source defines a
 190 name, type, min- and max-value and the data-set wraps them up into one
 191 structure. The general layout looks like this:
 192
 193   [{
 194     name => 'data_source_name',
 195     type => DS_TYPE_COUNTER || DS_TYPE_GAUGE || DS_TYPE_DERIVE || DS_TYPE_ABSOLUTE,
 196     min  => value || undef,
 197     max  => value || undef
 198   }, ...]
 199
 200 =item Value-List
 201
 202 A value-list is one structure which features an array of values and fields to
 203 identify the values, i.E<nbsp>e. time and host, plugin name and
 204 plugin-instance as well as a type and type-instance. Since the "type" is not
 205 included in the value-list but is passed as an extra argument, the general
 206 layout looks like this:
 207
 208   {
 209     values => [123, 0.5],
 210     time   => time (),
 211     interval => plugin_get_interval (),
 212     host   => $hostname_g,
 213     plugin => 'myplugin',
 214     type   => 'myplugin',
 215     plugin_instance => '',
 216     type_instance   => ''
 217   }
 218
 219 =item Notification
 220
 221 A notification is one structure defining the severity, time and message of the
 222 status message as well as an identification of a data instance. Also, it
 223 includes an optional list of user-defined meta information represented as
 224 (name, value) pairs:
 225
 226   {
 227     severity => NOTIF_FAILURE || NOTIF_WARNING || NOTIF_OKAY,
 228     time     => time (),
 229     message  => 'status message',
 230     host     => $hostname_g,
 231     plugin   => 'myplugin',
 232     type     => 'mytype',
 233     plugin_instance => '',
 234     type_instance   => '',
 235     meta     => [ { name => <name>, value => <value> }, ... ]
 236   }
 237
 238 =item Match-Proc
 239
 240 A match-proc is one structure storing the callbacks of a "match" of the filter
 241 chain infrastructure. The general layout looks like this:
 242
 243   {
 244     create  => 'my_create',
 245     destroy => 'my_destroy',
 246     match   => 'my_match'
 247   }
 248
 249 =item Target-Proc
 250
 251 A target-proc is one structure storing the callbacks of a "target" of the
 252 filter chain infrastructure. The general layout looks like this:
 253
 254   {
 255     create  => 'my_create',
 256     destroy => 'my_destroy',
 257     invoke  => 'my_invoke'
 258   }
 259
 260 =back
 261
 262 =head1 METHODS
 263
 264 The following functions provide the C-interface to Perl-modules. They are
 265 exported by the ":plugin" export tag (see the section "EXPORTS" below).
 266
 267 =over 4
 268
 269 =item B<plugin_register> (I<type>, I<name>, I<data>)
 270
 271 Registers a callback-function or data-set.
 272
 273 I<type> can be one of:
 274
 275 =over 4
 276
 277 =item TYPE_CONFIG
 278
 279 =item TYPE_INIT
 280
 281 =item TYPE_READ
 282
 283 =item TYPE_WRITE
 284
 285 =item TYPE_FLUSH
 286
 287 =item TYPE_LOG
 288
 289 =item TYPE_NOTIF
 290
 291 =item TYPE_SHUTDOWN
 292
 293 =item TYPE_DATASET
 294
 295 =back
 296
 297 I<name> is the name of the callback-function or the type of the data-set,
 298 depending on the value of I<type>. (Please note that the type of the data-set
 299 is the value passed as I<name> here and has nothing to do with the I<type>
 300 argument which simply tells B<plugin_register> what is being registered.)
 301
 302 The last argument, I<data>, is either a function name or an array-reference.
 303 If I<type> is B<TYPE_DATASET>, then the I<data> argument must be an
 304 array-reference which points to an array of hashes. Each hash describes one
 305 data-set. For the exact layout see B<Data-Set> above. Please note that
 306 there is a large number of predefined data-sets available in the B<types.db>
 307 file which are automatically registered with collectd - see L<types.db(5)> for
 308 a description of the format of this file.
 309
 310 B<Note>: Using B<plugin_register> to register a data-set is deprecated. Add
 311 the new type to a custom L<types.db(5)> file instead. This functionality might
 312 be removed in a future version of collectd.
 313
 314 If the I<type> argument is any of the other types (B<TYPE_INIT>, B<TYPE_READ>,
 315 ...) then I<data> is expected to be a function name. If the name is not
 316 prefixed with the plugin's package name collectd will add it automatically.
 317 The interface slightly differs from the C interface (which expects a function
 318 pointer instead) because Perl does not support to share references to
 319 subroutines between threads.
 320
 321 These functions are called in the various stages of the daemon (see the
 322 section "WRITING YOUR OWN PLUGINS" above) and are passed the following
 323 arguments:
 324
 325 =over 4
 326
 327 =item TYPE_CONFIG
 328
 329 The only argument passed is I<config-item>. See above for the layout of this
 330 data type.
 331
 332 =item TYPE_INIT
 333
 334 =item TYPE_READ
 335
 336 =item TYPE_SHUTDOWN
 337
 338 No arguments are passed.
 339
 340 =item TYPE_WRITE
 341
 342 The arguments passed are I<type>, I<data-set>, and I<value-list>. I<type> is a
 343 string. For the layout of I<data-set> and I<value-list> see above.
 344
 345 =item TYPE_FLUSH
 346
 347 The arguments passed are I<timeout> and I<identifier>. I<timeout> indicates
 348 that only data older than I<timeout> seconds is to be flushed. I<identifier>
 349 specifies which values are to be flushed.
 350
 351 =item TYPE_LOG
 352
 353 The arguments are I<log-level> and I<message>. The log level is small for
 354 important messages and high for less important messages. The least important
 355 level is B<LOG_DEBUG>, the most important level is B<LOG_ERR>. In between there
 356 are (from least to most important): B<LOG_INFO>, B<LOG_NOTICE>, and
 357 B<LOG_WARNING>. I<message> is simply a string B<without> a newline at the end.
 358
 359 =item TYPE_NOTIF
 360
 361 The only argument passed is I<notification>. See above for the layout of this
 362 data type.
 363
 364 =back
 365
 366 =item B<plugin_unregister> (I<type>, I<plugin>)
 367
 368 Removes a callback or data-set from collectd's internal list of
 369 functionsE<nbsp>/ datasets.
 370
 371 =item B<plugin_dispatch_values> (I<value-list>)
 372
 373 Submits a I<value-list> to the daemon. If the data-set identified by
 374 I<value-list>->{I<type>}
 375 is found (and the number of values matches the number of data-sources) then the
 376 type, data-set and value-list is passed to all write-callbacks that are
 377 registered with the daemon.
 378
 379 =item B<plugin_write> ([B<plugins> => I<...>][, B<datasets> => I<...>],
 380 B<valuelists> => I<...>)
 381
 382 Calls the write function of the given I<plugins> with the provided I<data
 383 sets> and I<value lists>. In contrast to B<plugin_dispatch_values>, it does
 384 not update collectd's internal cache and bypasses the filter mechanism (see
 385 L<collectd.conf(5)> for details). If the B<plugins> argument has been omitted,
 386 the values will be dispatched to all registered write plugins. If the
 387 B<datasets> argument has been omitted, the required data sets are looked up
 388 according to the C<type> member in the appropriate value list. The value of
 389 all three arguments may either be a single scalar or a reference to an array.
 390 If the B<datasets> argument has been specified, the number of data sets has to
 391 equal the number of specified value lists.
 392
 393 =item B<plugin_flush> ([B<timeout> => I<timeout>][, B<plugins> => I<...>][,
 394 B<identifiers> => I<...>])
 395
 396 Flush one or more plugins. I<timeout> and the specified I<identifiers> are
 397 passed on to the registered flush-callbacks. If omitted, the timeout defaults
 398 to C<-1>. The identifier defaults to the undefined value. If the B<plugins>
 399 argument has been specified, only named plugins will be flushed. The value of
 400 the B<plugins> and B<identifiers> arguments may either be a string or a
 401 reference to an array of strings.
 402
 403 =item B<plugin_dispatch_notification> (I<notification>)
 404
 405 Submits a I<notification> to the daemon which will then pass it to all
 406 notification-callbacks that are registered.
 407
 408 =item B<plugin_log> (I<log-level>, I<message>)
 409
 410 Submits a I<message> of level I<log-level> to collectd's logging mechanism.
 411 The message is passed to all log-callbacks that are registered with collectd.
 412
 413 =item B<ERROR>, B<WARNING>, B<NOTICE>, B<INFO>, B<DEBUG> (I<message>)
 414
 415 Wrappers around B<plugin_log>, using B<LOG_ERR>, B<LOG_WARNING>,
 416 B<LOG_NOTICE>, B<LOG_INFO> and B<LOG_DEBUG> respectively as I<log-level>.
 417
 418 =item B<plugin_get_interval> ()
 419
 420 Returns the interval of the current plugin as a floating point number in
 421 seconds. This value depends on the interval configured within the
 422 C<LoadPlugin perl> block or the global interval (see L<collectd.conf(5)> for
 423 details).
 424
 425 =back
 426
 427 The following function provides the filter chain C-interface to Perl-modules.
 428 It is exported by the ":filter_chain" export tag (see the section "EXPORTS"
 429 below).
 430
 431 =over 4
 432
 433 =item B<fc_register> (I<type>, I<name>, I<proc>)
 434
 435 Registers filter chain callbacks with collectd.
 436
 437 I<type> may be any of:
 438
 439 =over 4
 440
 441 =item FC_MATCH
 442
 443 =item FC_TARGET
 444
 445 =back
 446
 447 I<name> is the name of the match or target. By this name, the callbacks are
 448 identified in the configuration file when specifying a B<Match> or B<Target>
 449 block (see L<collectd.conf(5)> for details).
 450
 451 I<proc> is a hash reference. The hash includes up to three callbacks: an
 452 optional constructor (B<create>) and destructor (B<destroy>) and a mandatory
 453 B<match> or B<invoke> callback. B<match> is called whenever processing an
 454 appropriate match, while B<invoke> is called whenever processing an
 455 appropriate target (see the section "FILTER CONFIGURATION" in
 456 L<collectd.conf(5)> for details). Just like any other callbacks, filter chain
 457 callbacks are identified by the function name rather than a function pointer
 458 because Perl does not support to share references to subroutines between
 459 threads. The following arguments are passed to the callbacks:
 460
 461 =over 4
 462
 463 =item create
 464
 465 The arguments passed are I<config-item> and I<user-data>. See above for the
 466 layout of the config-item data-type. I<user-data> is a reference to a scalar
 467 value that may be used to store any information specific to this particular
 468 instance. The daemon does not care about this information at all. It's for the
 469 plugin's use only.
 470
 471 =item destroy
 472
 473 The only argument passed is I<user-data> which is a reference to the user data
 474 initialized in the B<create> callback. This callback may be used to cleanup
 475 instance-specific information and settings.
 476
 477 =item match, invoke
 478
 479 The arguments passed are I<data-set>, I<value-list>, I<meta> and I<user-data>.
 480 See above for the layout of the data-set and value-list data-types. I<meta> is
 481 a pointer to an array of meta information, just like the B<meta> member of the
 482 notification data-type (see above). I<user-data> is a reference to the user
 483 data initialized in the B<create> callback.
 484
 485 =back
 486
 487 =back
 488
 489 =head1 GLOBAL VARIABLES
 490
 491 =over 4
 492
 493 =item B<$hostname_g>
 494
 495 As the name suggests this variable keeps the hostname of the system collectd
 496 is running on. The value might be influenced by the B<Hostname> or
 497 B<FQDNLookup> configuration options (see L<collectd.conf(5)> for details).
 498
 499 =item B<$interval_g>
 500
 501 This variable keeps the interval in seconds in which the read functions are
 502 queried (see the B<Interval> configuration option).
 503
 504 B<Note:> This variable should no longer be used in favor of
 505 C<plugin_get_interval()> (see above). This function takes any plugin-specific
 506 interval settings into account (see the C<Interval> option of C<LoadPlugin> in
 507 L<collectd.conf(5)> for details).
 508
 509 =back
 510
 511 Any changes to these variables will be globally visible in collectd.
 512
 513 =head1 EXPORTS
 514
 515 By default no symbols are exported. However, the following export tags are
 516 available (B<:all> will export all of them):
 517
 518 =over 4
 519
 520 =item B<:plugin>
 521
 522 =over 4
 523
 524 =item B<plugin_register> ()
 525
 526 =item B<plugin_unregister> ()
 527
 528 =item B<plugin_dispatch_values> ()
 529
 530 =item B<plugin_flush> ()
 531
 532 =item B<plugin_flush_one> ()
 533
 534 =item B<plugin_flush_all> ()
 535
 536 =item B<plugin_dispatch_notification> ()
 537
 538 =item B<plugin_log> ()
 539
 540 =back
 541
 542 =item B<:types>
 543
 544 =over 4
 545
 546 =item B<TYPE_CONFIG>
 547
 548 =item B<TYPE_INIT>
 549
 550 =item B<TYPE_READ>
 551
 552 =item B<TYPE_WRITE>
 553
 554 =item B<TYPE_FLUSH>
 555
 556 =item B<TYPE_SHUTDOWN>
 557
 558 =item B<TYPE_LOG>
 559
 560 =item B<TYPE_DATASET>
 561
 562 =back
 563
 564 =item B<:ds_types>
 565
 566 =over 4
 567
 568 =item B<DS_TYPE_COUNTER>
 569
 570 =item B<DS_TYPE_GAUGE>
 571
 572 =item B<DS_TYPE_DERIVE>
 573
 574 =item B<DS_TYPE_ABSOLUTE>
 575
 576 =back
 577
 578 =item B<:log>
 579
 580 =over 4
 581
 582 =item B<ERROR> ()
 583
 584 =item B<WARNING> ()
 585
 586 =item B<NOTICE> ()
 587
 588 =item B<INFO> ()
 589
 590 =item B<DEBUG> ()
 591
 592 =item B<LOG_ERR>
 593
 594 =item B<LOG_WARNING>
 595
 596 =item B<LOG_NOTICE>
 597
 598 =item B<LOG_INFO>
 599
 600 =item B<LOG_DEBUG>
 601
 602 =back
 603
 604 =item B<:filter_chain>
 605
 606 =over 4
 607
 608 =item B<fc_register>
 609
 610 =item B<FC_MATCH_NO_MATCH>
 611
 612 =item B<FC_MATCH_MATCHES>
 613
 614 =item B<FC_TARGET_CONTINUE>
 615
 616 =item B<FC_TARGET_STOP>
 617
 618 =item B<FC_TARGET_RETURN>
 619
 620 =back
 621
 622 =item B<:fc_types>
 623
 624 =over 4
 625
 626 =item B<FC_MATCH>
 627
 628 =item B<FC_TARGET>
 629
 630 =back
 631
 632 =item B<:notif>
 633
 634 =over 4
 635
 636 =item B<NOTIF_FAILURE>
 637
 638 =item B<NOTIF_WARNING>
 639
 640 =item B<NOTIF_OKAY>
 641
 642 =back
 643
 644 =item B<:globals>
 645
 646 =over 4
 647
 648 =item B<$hostname_g>
 649
 650 =item B<$interval_g>
 651
 652 =back
 653
 654 =back
 655
 656 =head1 EXAMPLES
 657
 658 Any Perl plugin will start similar to:
 659
 660   package Collectd::Plugins::FooBar;
 661
 662   use strict;
 663   use warnings;
 664
 665   use Collectd qw( :all );
 666
 667 A very simple read function might look like:
 668
 669   sub foobar_read
 670   {
 671     my $vl = { plugin => 'foobar', type => 'gauge' };
 672     $vl->{'values'} = [ rand(42) ];
 673     plugin_dispatch_values ($vl);
 674     return 1;
 675   }
 676
 677 A very simple write function might look like:
 678
 679   sub foobar_write
 680   {
 681     my ($type, $ds, $vl) = @_;
 682     for (my $i = 0; $i < scalar (@$ds); ++$i) {
 683       print "$vl->{'plugin'} ($vl->{'type'}): $vl->{'values'}->[$i]\n";
 684     }
 685     return 1;
 686   }
 687
 688 A very simple match callback might look like:
 689
 690   sub foobar_match
 691   {
 692     my ($ds, $vl, $meta, $user_data) = @_;
 693     if (matches($ds, $vl)) {
 694       return FC_MATCH_MATCHES;
 695     } else {
 696       return FC_MATCH_NO_MATCH;
 697     }
 698   }
 699
 700 To register those functions with collectd:
 701
 702   plugin_register (TYPE_READ, "foobar", "foobar_read");
 703   plugin_register (TYPE_WRITE, "foobar", "foobar_write");
 704
 705   fc_register (FC_MATCH, "foobar", "foobar_match");
 706
 707 See the section "DATA TYPES" above for a complete documentation of the data
 708 types used by the read, write and match functions.
 709
 710 =head1 NOTES
 711
 712 =over 4
 713
 714 =item
 715
 716 Please feel free to send in new plugins to collectd's mailing list at
 717 E<lt>collectdE<nbsp>atE<nbsp>verplant.orgE<gt> for review and, possibly,
 718 inclusion in the main distribution. In the latter case, we will take care of
 719 keeping the plugin up to date and adapting it to new versions of collectd.
 720
 721 Before submitting your plugin, please take a look at
 722 L<http://collectd.org/dev-info.shtml>.
 723
 724 =back
 725
 726 =head1 CAVEATS
 727
 728 =over 4
 729
 730 =item
 731
 732 collectd is heavily multi-threaded. Each collectd thread accessing the perl
 733 plugin will be mapped to a Perl interpreter thread (see L<threads(3perl)>).
 734 Any such thread will be created and destroyed transparently and on-the-fly.
 735
 736 Hence, any plugin has to be thread-safe if it provides several entry points
 737 from collectd (i.E<nbsp>e. if it registers more than one callback or if a
 738 registered callback may be called more than once in parallel). Please note
 739 that no data is shared between threads by default. You have to use the
 740 B<threads::shared> module to do so.
 741
 742 =item
 743
 744 Each function name registered with collectd has to be available before the
 745 first thread has been created (i.E<nbsp>e. basically at compile time). This
 746 basically means that hacks (yes, I really consider this to be a hack) like
 747 C<*foo = \&bar; plugin_register (TYPE_READ, "plugin", "foo");> most likely
 748 will not work. This is due to the fact that the symbol table is not shared
 749 across different threads.
 750
 751 =item
 752
 753 Each plugin is usually only loaded once and kept in memory for performance
 754 reasons. Therefore, END blocks are only executed once when collectd shuts
 755 down. You should not rely on END blocks anyway - use B<shutdown functions>
 756 instead.
 757
 758 =item
 759
 760 The perl plugin exports the internal API of collectd which is considered
 761 unstable and subject to change at any time. We try hard to not break backwards
 762 compatibility in the Perl API during the life cycle of one major release.
 763 However, this cannot be guaranteed at all times. Watch out for warnings
 764 dispatched by the perl plugin after upgrades.
 765
 766 =back
 767
 768 =head1 KNOWN BUGS
 769
 770 =over 4
 771
 772 =item
 773
 774 Currently, it is not possible to flush a single Perl plugin only. You can
 775 either flush all Perl plugins or none at all and you have to use C<perl> as
 776 plugin name when doing so.
 777
 778 =back
 779
 780 =head1 SEE ALSO
 781
 782 L<collectd(1)>,
 783 L<collectd.conf(5)>,
 784 L<collectd-exec(5)>,
 785 L<types.db(5)>,
 786 L<perl(1)>,
 787 L<threads(3perl)>,
 788 L<threads::shared(3perl)>,
 789 L<perldebug(1)>
 790
 791 =head1 AUTHOR
 792
 793 The C<perl plugin> has been written by Sebastian Harl
 794 E<lt>shE<nbsp>atE<nbsp>tokkee.orgE<gt>.
 795
 796 This manpage has been written by Florian Forster
 797 E<lt>octoE<nbsp>atE<nbsp>verplant.orgE<gt> and Sebastian Harl
 798 E<lt>shE<nbsp>atE<nbsp>tokkee.orgE<gt>.
 799
 800 =cut
 801