src/collectd-perl.pod

   1 =head1 NAME
   2
   3 collectd-perl - Documentation of collectd's C<perl plugin>
   4
   5 =head1 SYNOPSIS
   6
   7   LoadPlugin perl
   8   # ...
   9   <Plugin perl>
  10     IncludeDir "/path/to/perl/plugins"
  11     BaseName "Collectd::Plugins"
  12     EnableDebugger ""
  13     LoadPlugin "FooBar"
  14
  15     <Plugin FooBar>
  16       Foo "Bar"
  17     </Plugin>
  18   </Plugin>
  19
  20 =head1 DESCRIPTION
  21
  22 The C<perl plugin> embeds a Perl-interpreter into collectd and provides an
  23 interface to collectd's plugin system. This makes it possible to write plugins
  24 for collectd in Perl. This is a lot more efficient than executing a
  25 Perl-script every time you want to read a value with the C<exec plugin> (see
  26 L<collectd-exec(5)>) and provides a lot more functionality, too.
  27
  28 =head1 CONFIGURATION
  29
  30 =over 4
  31
  32 =item B<LoadPlugin> I<Plugin>
  33
  34 Loads the Perl plugin I<Plugin>. This does basically the same as B<use> would
  35 do in a Perl program. As a side effect, the first occurrence of this option
  36 causes the Perl-interpreter to be initialized.
  37
  38 =item B<BaseName> I<Name>
  39
  40 Prepends I<Name>B<::> to all plugin names loaded after this option. This is
  41 provided for convenience to keep plugin names short. All Perl-based plugins
  42 provided with the I<collectd> distributions reside in the C<Collectd::Plugins>
  43 namespace.
  44
  45 =item E<lt>B<Plugin> I<Name>E<gt> block
  46
  47 This block may be used to pass on configuration settings to a Perl plugin. The
  48 configuration is converted into a config-item data type which is passed to the
  49 registered configuration callback. See below for details about the config-item
  50 data type and how to register callbacks.
  51
  52 The I<name> identifies the callback. It is used literally and independent of
  53 the B<BaseName> setting.
  54
  55 =item B<EnableDebugger> I<Package>[=I<option>,...]
  56
  57 Run collectd under the control of the Perl source debugger. If I<Package> is
  58 not the empty string, control is passed to the debugging, profiling, or
  59 tracing module installed as Devel::I<Package>. A comma-separated list of
  60 options may be specified after the "=" character. Please note that you may not
  61 leave out the I<Package> option even if you specify B<"">. This is the same as
  62 using the B<-d:Package> command line option.
  63
  64 See L<perldebug> for detailed documentation about debugging Perl.
  65
  66 This option does not prevent collectd from daemonizing, so you should start
  67 collectd with the B<-f> command line option. Else you will not be able to use
  68 the command line driven interface of the debugger.
  69
  70 =item B<IncludeDir> I<Dir>
  71
  72 Adds I<Dir> to the B<@INC> array. This is the same as using the B<-IDir>
  73 command line option or B<use lib Dir> in the source code. Please note that it
  74 only has effect on plugins loaded after this option.
  75
  76 =back
  77
  78 =head1 WRITING YOUR OWN PLUGINS
  79
  80 Writing your own plugins is quite simple. collectd manages plugins by means of
  81 B<dispatch functions> which call the appropriate B<callback functions>
  82 registered by the plugins. Any plugin basically consists of the implementation
  83 of these callback functions and initializing code which registers the
  84 functions with collectd. See the section "EXAMPLES" below for a really basic
  85 example. The following types of B<callback functions> are known to collectd
  86 (all of them are optional):
  87
  88 =over 4
  89
  90 =item configuration functions
  91
  92 This type of functions is called during configuration if an appropriate
  93 B<Plugin> block has been encountered. It is called once for each B<Plugin>
  94 block which matches the name of the callback as provided with the
  95 B<plugin_register> method - see below.
  96
  97 =item init functions
  98
  99 This type of functions is called once after loading the module and before any
 100 calls to the read and write functions. It should be used to initialize the
 101 internal state of the plugin (e.E<nbsp>g. open sockets, ...). If the return
 102 value evaluates to B<false>, the plugin will be disabled.
 103
 104 =item read functions
 105
 106 This type of function is used to collect the actual data. It is called once
 107 per interval (see the B<Interval> configuration option of collectd). Usually
 108 it will call B<plugin_dispatch_values> to dispatch the values to collectd
 109 which will pass them on to all registered B<write functions>. If the return
 110 value evaluates to B<false> the plugin will be skipped for an increasing
 111 amount of time until it returns B<true> again.
 112
 113 =item write functions
 114
 115 This type of function is used to write the dispatched values. It is called
 116 once for each call to B<plugin_dispatch_values>.
 117
 118 =item flush functions
 119
 120 This type of function is used to flush internal caches of plugins. It is
 121 usually triggered by the user only. Any plugin which caches data before
 122 writing it to disk should provide this kind of callback function.
 123
 124 =item log functions
 125
 126 This type of function is used to pass messages of plugins or the daemon itself
 127 to the user.
 128
 129 =item notification function
 130
 131 This type of function is used to act upon notifications. In general, a
 132 notification is a status message that may be associated with a data instance.
 133 Usually, a notification is generated by the daemon if a configured threshold
 134 has been exceeded (see the section "THRESHOLD CONFIGURATION" in
 135 L<collectd.conf(5)> for more details), but any plugin may dispatch
 136 notifications as well.
 137
 138 =item shutdown functions
 139
 140 This type of function is called once before the daemon shuts down. It should
 141 be used to clean up the plugin (e.g. close sockets, ...).
 142
 143 =back
 144
 145 Any function (except log functions) may set the B<$@> variable to describe
 146 errors in more detail. The message will be passed on to the user using
 147 collectd's logging mechanism.
 148
 149 See the documentation of the B<plugin_register> method in the section
 150 "METHODS" below for the number and types of arguments passed to each
 151 B<callback function>. This section also explains how to register B<callback
 152 functions> with collectd.
 153
 154 To enable a plugin, copy it to a place where Perl can find it (i.E<nbsp>e. a
 155 directory listed in the B<@INC> array) just as any other Perl plugin and add
 156 an appropriate B<LoadPlugin> option to the configuration file. After
 157 restarting collectd you're done.
 158
 159 =head1 DATA TYPES
 160
 161 The following complex types are used to pass values between the Perl plugin
 162 and collectd:
 163
 164 =over 4
 165
 166 =item Config-Item
 167
 168 A config-item is one structure which keeps the information provided in the
 169 configuration file. The array of children keeps one entry for each
 170 configuration option. Each such entry is another config-item structure, which
 171 may nest further if nested blocks are used.
 172
 173   {
 174     key      => key,
 175     values   => [ val1, val2, ... ],
 176     children => [ { ... }, { ... }, ... ]
 177   }
 178
 179 =item Data-Set
 180
 181 A data-set is a list of one or more data-sources. Each data-source defines a
 182 name, type, min- and max-value and the data-set wraps them up into one
 183 structure. The general layout looks like this:
 184
 185   [{
 186     name => 'data_source_name',
 187     type => DS_TYPE_COUNTER || DS_TYPE_GAUGE || DS_TYPE_DERIVE || DS_TYPE_ABSOLUTE,
 188     min  => value || undef,
 189     max  => value || undef
 190   }, ...]
 191
 192 =item Value-List
 193
 194 A value-list is one structure which features an array of values and fields to
 195 identify the values, i.E<nbsp>e. time and host, plugin name and
 196 plugin-instance as well as a type and type-instance. Since the "type" is not
 197 included in the value-list but is passed as an extra argument, the general
 198 layout looks like this:
 199
 200   {
 201     values => [123, 0.5],
 202     time   => time (),
 203     interval => $interval_g,
 204     host   => $hostname_g,
 205     plugin => 'myplugin',
 206     type   => 'myplugin',
 207     plugin_instance => '',
 208     type_instance   => ''
 209   }
 210
 211 =item Notification
 212
 213 A notification is one structure defining the severity, time and message of the
 214 status message as well as an identification of a data instance. Also, it
 215 includes an optional list of user-defined meta information represented as
 216 (name, value) pairs:
 217
 218   {
 219     severity => NOTIF_FAILURE || NOTIF_WARNING || NOTIF_OKAY,
 220     time     => time (),
 221     message  => 'status message',
 222     host     => $hostname_g,
 223     plugin   => 'myplugin',
 224     type     => 'mytype',
 225     plugin_instance => '',
 226     type_instance   => '',
 227     meta     => [ { name => <name>, value => <value> }, ... ]
 228   }
 229
 230 =item Match-Proc
 231
 232 A match-proc is one structure storing the callbacks of a "match" of the filter
 233 chain infrastructure. The general layout looks like this:
 234
 235   {
 236     create  => 'my_create',
 237     destroy => 'my_destroy',
 238     match   => 'my_match'
 239   }
 240
 241 =item Target-Proc
 242
 243 A target-proc is one structure storing the callbacks of a "target" of the
 244 filter chain infrastructure. The general layout looks like this:
 245
 246   {
 247     create  => 'my_create',
 248     destroy => 'my_destroy',
 249     invoke  => 'my_invoke'
 250   }
 251
 252 =back
 253
 254 =head1 METHODS
 255
 256 The following functions provide the C-interface to Perl-modules. They are
 257 exported by the ":plugin" export tag (see the section "EXPORTS" below).
 258
 259 =over 4
 260
 261 =item B<plugin_register> (I<type>, I<name>, I<data>)
 262
 263 Registers a callback-function or data-set.
 264
 265 I<type> can be one of:
 266
 267 =over 4
 268
 269 =item TYPE_CONFIG
 270
 271 =item TYPE_INIT
 272
 273 =item TYPE_READ
 274
 275 =item TYPE_WRITE
 276
 277 =item TYPE_FLUSH
 278
 279 =item TYPE_LOG
 280
 281 =item TYPE_NOTIF
 282
 283 =item TYPE_SHUTDOWN
 284
 285 =item TYPE_DATASET
 286
 287 =back
 288
 289 I<name> is the name of the callback-function or the type of the data-set,
 290 depending on the value of I<type>. (Please note that the type of the data-set
 291 is the value passed as I<name> here and has nothing to do with the I<type>
 292 argument which simply tells B<plugin_register> what is being registered.)
 293
 294 The last argument, I<data>, is either a function name or an array-reference.
 295 If I<type> is B<TYPE_DATASET>, then the I<data> argument must be an
 296 array-reference which points to an array of hashes. Each hash describes one
 297 data-set. For the exact layout see B<Data-Set> above. Please note that
 298 there is a large number of predefined data-sets available in the B<types.db>
 299 file which are automatically registered with collectd - see L<types.db(5)> for
 300 a description of the format of this file.
 301
 302 B<Note>: Using B<plugin_register> to register a data-set is deprecated. Add
 303 the new type to a custom L<types.db(5)> file instead. This functionality might
 304 be removed in a future version of collectd.
 305
 306 If the I<type> argument is any of the other types (B<TYPE_INIT>, B<TYPE_READ>,
 307 ...) then I<data> is expected to be a function name. If the name is not
 308 prefixed with the plugin's package name collectd will add it automatically.
 309 The interface slightly differs from the C interface (which expects a function
 310 pointer instead) because Perl does not support to share references to
 311 subroutines between threads.
 312
 313 These functions are called in the various stages of the daemon (see the
 314 section "WRITING YOUR OWN PLUGINS" above) and are passed the following
 315 arguments:
 316
 317 =over 4
 318
 319 =item TYPE_CONFIG
 320
 321 The only argument passed is I<config-item>. See above for the layout of this
 322 data type.
 323
 324 =item TYPE_INIT
 325
 326 =item TYPE_READ
 327
 328 =item TYPE_SHUTDOWN
 329
 330 No arguments are passed.
 331
 332 =item TYPE_WRITE
 333
 334 The arguments passed are I<type>, I<data-set>, and I<value-list>. I<type> is a
 335 string. For the layout of I<data-set> and I<value-list> see above.
 336
 337 =item TYPE_FLUSH
 338
 339 The arguments passed are I<timeout> and I<identifier>. I<timeout> indicates
 340 that only data older than I<timeout> seconds is to be flushed. I<identifier>
 341 specifies which values are to be flushed.
 342
 343 =item TYPE_LOG
 344
 345 The arguments are I<log-level> and I<message>. The log level is small for
 346 important messages and high for less important messages. The least important
 347 level is B<LOG_DEBUG>, the most important level is B<LOG_ERR>. In between there
 348 are (from least to most important): B<LOG_INFO>, B<LOG_NOTICE>, and
 349 B<LOG_WARNING>. I<message> is simply a string B<without> a newline at the end.
 350
 351 =item TYPE_NOTIF
 352
 353 The only argument passed is I<notification>. See above for the layout of this
 354 data type.
 355
 356 =back
 357
 358 =item B<plugin_unregister> (I<type>, I<plugin>)
 359
 360 Removes a callback or data-set from collectd's internal list of
 361 functionsE<nbsp>/ datasets.
 362
 363 =item B<plugin_dispatch_values> (I<value-list>)
 364
 365 Submits a I<value-list> to the daemon. If the data-set identified by
 366 I<value-list>->{I<type>}
 367 is found (and the number of values matches the number of data-sources) then the
 368 type, data-set and value-list is passed to all write-callbacks that are
 369 registered with the daemon.
 370
 371 B<Note>: Prior to version 4.4 of collectd, the data-set type used to be passed
 372 as the first argument to B<plugin_register>. This syntax is still supported
 373 for backwards compatibility but has been deprecated and will be removed in
 374 some future version of collectd.
 375
 376 =item B<plugin_write> ([B<plugins> => I<...>][, B<datasets> => I<...>],
 377 B<valuelists> => I<...>)
 378
 379 Calls the write function of the given I<plugins> with the provided I<data
 380 sets> and I<value lists>. In contrast to B<plugin_dispatch_values>, it does
 381 not update collectd's internal cache and bypasses the filter mechanism (see
 382 L<collectd.conf(5)> for details). If the B<plugins> argument has been omitted,
 383 the values will be dispatched to all registered write plugins. If the
 384 B<datasets> argument has been omitted, the required data sets are looked up
 385 according to the C<type> member in the appropriate value list. The value of
 386 all three arguments may either be a single scalar or a reference to an array.
 387 If the B<datasets> argument has been specified, the number of data sets has to
 388 equal the number of specified value lists.
 389
 390 =item B<plugin_flush> ([B<timeout> => I<timeout>][, B<plugins> => I<...>][,
 391 B<identifiers> => I<...>])
 392
 393 Flush one or more plugins. I<timeout> and the specified I<identifiers> are
 394 passed on to the registered flush-callbacks. If omitted, the timeout defaults
 395 to C<-1>. The identifier defaults to the undefined value. If the B<plugins>
 396 argument has been specified, only named plugins will be flushed. The value of
 397 the B<plugins> and B<identifiers> arguments may either be a string or a
 398 reference to an array of strings.
 399
 400 =item B<plugin_flush_one> (I<timeout>, I<plugin>)
 401
 402 This is identical to using "plugin_flush (timeout =E<gt> I<timeout>, plugins
 403 =E<gt> I<plugin>".
 404
 405 B<Note>: Starting with version 4.5 of collectd, B<plugin_flush_one> has been
 406 deprecated and will be removed in some future version of collectd. Use
 407 B<plugin_flush> instead.
 408
 409 =item B<plugin_flush_all> (I<timeout>)
 410
 411 This is identical to using "plugin_flush (timeout =E<gt> I<timeout>)".
 412
 413 B<Note>: Starting with version 4.5 of collectd, B<plugin_flush_all> has been
 414 deprecated and will be removed in some future version of collectd. Use
 415 B<plugin_flush> instead.
 416
 417 =item B<plugin_dispatch_notification> (I<notification>)
 418
 419 Submits a I<notification> to the daemon which will then pass it to all
 420 notification-callbacks that are registered.
 421
 422 =item B<plugin_log> (I<log-level>, I<message>)
 423
 424 Submits a I<message> of level I<log-level> to collectd's logging mechanism.
 425 The message is passed to all log-callbacks that are registered with collectd.
 426
 427 =item B<ERROR>, B<WARNING>, B<NOTICE>, B<INFO>, B<DEBUG> (I<message>)
 428
 429 Wrappers around B<plugin_log>, using B<LOG_ERR>, B<LOG_WARNING>,
 430 B<LOG_NOTICE>, B<LOG_INFO> and B<LOG_DEBUG> respectively as I<log-level>.
 431
 432 =back
 433
 434 The following function provides the filter chain C-interface to Perl-modules.
 435 It is exported by the ":filter_chain" export tag (see the section "EXPORTS"
 436 below).
 437
 438 =over 4
 439
 440 =item B<fc_register> (I<type>, I<name>, I<proc>)
 441
 442 Registers filter chain callbacks with collectd.
 443
 444 I<type> may be any of:
 445
 446 =over 4
 447
 448 =item FC_MATCH
 449
 450 =item FC_TARGET
 451
 452 =back
 453
 454 I<name> is the name of the match or target. By this name, the callbacks are
 455 identified in the configuration file when specifying a B<Match> or B<Target>
 456 block (see L<collectd.conf(5)> for details).
 457
 458 I<proc> is a hash reference. The hash includes up to three callbacks: an
 459 optional constructor (B<create>) and destructor (B<destroy>) and a mandatory
 460 B<match> or B<invoke> callback. B<match> is called whenever processing an
 461 appropriate match, while B<invoke> is called whenever processing an
 462 appropriate target (see the section "FILTER CONFIGURATION" in
 463 L<collectd.conf(5)> for details). Just like any other callbacks, filter chain
 464 callbacks are identified by the function name rather than a function pointer
 465 because Perl does not support to share references to subroutines between
 466 threads. The following arguments are passed to the callbacks:
 467
 468 =over 4
 469
 470 =item create
 471
 472 The arguments passed are I<config-item> and I<user-data>. See above for the
 473 layout of the config-item data-type. I<user-data> is a reference to a scalar
 474 value that may be used to store any information specific to this particular
 475 instance. The daemon does not care about this information at all. It's for the
 476 plugin's use only.
 477
 478 =item destroy
 479
 480 The only argument passed is I<user-data> which is a reference to the user data
 481 initialized in the B<create> callback. This callback may be used to cleanup
 482 instance-specific information and settings.
 483
 484 =item match, invoke
 485
 486 The arguments passed are I<data-set>, I<value-list>, I<meta> and I<user-data>.
 487 See above for the layout of the data-set and value-list data-types. I<meta> is
 488 a pointer to an array of meta information, just like the B<meta> member of the
 489 notification data-type (see above). I<user-data> is a reference to the user
 490 data initialized in the B<create> callback.
 491
 492 =back
 493
 494 =back
 495
 496 =head1 GLOBAL VARIABLES
 497
 498 =over 4
 499
 500 =item B<$hostname_g>
 501
 502 As the name suggests this variable keeps the hostname of the system collectd
 503 is running on. The value might be influenced by the B<Hostname> or
 504 B<FQDNLookup> configuration options (see L<collectd.conf(5)> for details).
 505
 506 =item B<$interval_g>
 507
 508 This variable keeps the interval in seconds in which the read functions are
 509 queried (see the B<Interval> configuration option).
 510
 511 =back
 512
 513 Any changes to these variables will be globally visible in collectd.
 514
 515 =head1 EXPORTS
 516
 517 By default no symbols are exported. However, the following export tags are
 518 available (B<:all> will export all of them):
 519
 520 =over 4
 521
 522 =item B<:plugin>
 523
 524 =over 4
 525
 526 =item B<plugin_register> ()
 527
 528 =item B<plugin_unregister> ()
 529
 530 =item B<plugin_dispatch_values> ()
 531
 532 =item B<plugin_flush> ()
 533
 534 =item B<plugin_flush_one> ()
 535
 536 =item B<plugin_flush_all> ()
 537
 538 =item B<plugin_dispatch_notification> ()
 539
 540 =item B<plugin_log> ()
 541
 542 =back
 543
 544 =item B<:types>
 545
 546 =over 4
 547
 548 =item B<TYPE_CONFIG>
 549
 550 =item B<TYPE_INIT>
 551
 552 =item B<TYPE_READ>
 553
 554 =item B<TYPE_WRITE>
 555
 556 =item B<TYPE_FLUSH>
 557
 558 =item B<TYPE_SHUTDOWN>
 559
 560 =item B<TYPE_LOG>
 561
 562 =item B<TYPE_DATASET>
 563
 564 =back
 565
 566 =item B<:ds_types>
 567
 568 =over 4
 569
 570 =item B<DS_TYPE_COUNTER>
 571
 572 =item B<DS_TYPE_GAUGE>
 573
 574 =item B<DS_TYPE_DERIVE>
 575
 576 =item B<DS_TYPE_ABSOLUTE>
 577
 578 =back
 579
 580 =item B<:log>
 581
 582 =over 4
 583
 584 =item B<ERROR> ()
 585
 586 =item B<WARNING> ()
 587
 588 =item B<NOTICE> ()
 589
 590 =item B<INFO> ()
 591
 592 =item B<DEBUG> ()
 593
 594 =item B<LOG_ERR>
 595
 596 =item B<LOG_WARNING>
 597
 598 =item B<LOG_NOTICE>
 599
 600 =item B<LOG_INFO>
 601
 602 =item B<LOG_DEBUG>
 603
 604 =back
 605
 606 =item B<:filter_chain>
 607
 608 =over 4
 609
 610 =item B<fc_register>
 611
 612 =item B<FC_MATCH_NO_MATCH>
 613
 614 =item B<FC_MATCH_MATCHES>
 615
 616 =item B<FC_TARGET_CONTINUE>
 617
 618 =item B<FC_TARGET_STOP>
 619
 620 =item B<FC_TARGET_RETURN>
 621
 622 =back
 623
 624 =item B<:fc_types>
 625
 626 =over 4
 627
 628 =item B<FC_MATCH>
 629
 630 =item B<FC_TARGET>
 631
 632 =back
 633
 634 =item B<:notif>
 635
 636 =over 4
 637
 638 =item B<NOTIF_FAILURE>
 639
 640 =item B<NOTIF_WARNING>
 641
 642 =item B<NOTIF_OKAY>
 643
 644 =back
 645
 646 =item B<:globals>
 647
 648 =over 4
 649
 650 =item B<$hostname_g>
 651
 652 =item B<$interval_g>
 653
 654 =back
 655
 656 =back
 657
 658 =head1 EXAMPLES
 659
 660 Any Perl plugin will start similar to:
 661
 662   package Collectd::Plugins::FooBar;
 663
 664   use strict;
 665   use warnings;
 666
 667   use Collectd qw( :all );
 668
 669 A very simple read function might look like:
 670
 671   sub foobar_read
 672   {
 673     my $vl = { plugin => 'foobar' };
 674     $vl->{'values'} = [ rand(42) ];
 675     plugin_dispatch_values ('gauge', $vl);
 676     return 1;
 677   }
 678
 679 A very simple write function might look like:
 680
 681   sub foobar_write
 682   {
 683     my ($type, $ds, $vl) = @_;
 684     for (my $i = 0; $i < scalar (@$ds); ++$i) {
 685       print "$vl->{'plugin'} ($vl->{'type'}): $vl->{'values'}->[$i]\n";
 686     }
 687     return 1;
 688   }
 689
 690 A very simple match callback might look like:
 691
 692   sub foobar_match
 693   {
 694     my ($ds, $vl, $meta, $user_data) = @_;
 695     if (matches($ds, $vl)) {
 696       return FC_MATCH_MATCHES;
 697     } else {
 698       return FC_MATCH_NO_MATCH;
 699     }
 700   }
 701
 702 To register those functions with collectd:
 703
 704   plugin_register (TYPE_READ, "foobar", "foobar_read");
 705   plugin_register (TYPE_WRITE, "foobar", "foobar_write");
 706
 707   fc_register (FC_MATCH, "foobar", "foobar_match");
 708
 709 See the section "DATA TYPES" above for a complete documentation of the data
 710 types used by the read, write and match functions.
 711
 712 =head1 NOTES
 713
 714 =over 4
 715
 716 =item
 717
 718 Please feel free to send in new plugins to collectd's mailing list at
 719 E<lt>collectdE<nbsp>atE<nbsp>verplant.orgE<gt> for review and, possibly,
 720 inclusion in the main distribution. In the latter case, we will take care of
 721 keeping the plugin up to date and adapting it to new versions of collectd.
 722
 723 Before submitting your plugin, please take a look at
 724 L<http://collectd.org/dev-info.shtml>.
 725
 726 =back
 727
 728 =head1 CAVEATS
 729
 730 =over 4
 731
 732 =item
 733
 734 collectd is heavily multi-threaded. Each collectd thread accessing the perl
 735 plugin will be mapped to a Perl interpreter thread (see L<threads(3perl)>).
 736 Any such thread will be created and destroyed transparently and on-the-fly.
 737
 738 Hence, any plugin has to be thread-safe if it provides several entry points
 739 from collectd (i.E<nbsp>e. if it registers more than one callback or if a
 740 registered callback may be called more than once in parallel). Please note
 741 that no data is shared between threads by default. You have to use the
 742 B<threads::shared> module to do so.
 743
 744 =item
 745
 746 Each function name registered with collectd has to be available before the
 747 first thread has been created (i.E<nbsp>e. basically at compile time). This
 748 basically means that hacks (yes, I really consider this to be a hack) like
 749 C<*foo = \&bar; plugin_register (TYPE_READ, "plugin", "foo");> most likely
 750 will not work. This is due to the fact that the symbol table is not shared
 751 across different threads.
 752
 753 =item
 754
 755 Each plugin is usually only loaded once and kept in memory for performance
 756 reasons. Therefore, END blocks are only executed once when collectd shuts
 757 down. You should not rely on END blocks anyway - use B<shutdown functions>
 758 instead.
 759
 760 =item
 761
 762 The perl plugin exports the internal API of collectd which is considered
 763 unstable and subject to change at any time. We try hard to not break backwards
 764 compatibility in the Perl API during the life cycle of one major release.
 765 However, this cannot be guaranteed at all times. Watch out for warnings
 766 dispatched by the perl plugin after upgrades.
 767
 768 =back
 769
 770 =head1 KNOWN BUGS
 771
 772 =over 4
 773
 774 =item
 775
 776 Currently, it is not possible to flush a single Perl plugin only. You can
 777 either flush all Perl plugins or none at all and you have to use C<perl> as
 778 plugin name when doing so.
 779
 780 =back
 781
 782 =head1 SEE ALSO
 783
 784 L<collectd(1)>,
 785 L<collectd.conf(5)>,
 786 L<collectd-exec(5)>,
 787 L<types.db(5)>,
 788 L<perl(1)>,
 789 L<threads(3perl)>,
 790 L<threads::shared(3perl)>,
 791 L<perldebug(1)>
 792
 793 =head1 AUTHOR
 794
 795 The C<perl plugin> has been written by Sebastian Harl
 796 E<lt>shE<nbsp>atE<nbsp>tokkee.orgE<gt>.
 797
 798 This manpage has been written by Florian Forster
 799 E<lt>octoE<nbsp>atE<nbsp>verplant.orgE<gt> and Sebastian Harl
 800 E<lt>shE<nbsp>atE<nbsp>tokkee.orgE<gt>.
 801
 802 =cut
 803