src/liboconfig/scanner.l

   1 /**
   2  * collectd - src/liboconfig/scanner.l
   3  * Copyright (C) 2007  Florian Forster
   4  * Copyright (C) 2008  Sebastian Harl
   5  *
   6  * Permission is hereby granted, free of charge, to any person obtaining a
   7  * copy of this software and associated documentation files (the "Software"),
   8  * to deal in the Software without restriction, including without limitation
   9  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
  10  * and/or sell copies of the Software, and to permit persons to whom the
  11  * Software is furnished to do so, subject to the following conditions:
  12  *
  13  * The above copyright notice and this permission notice shall be included in
  14  * all copies or substantial portions of the Software.
  15  *
  16  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  17  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  18  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  19  * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  20  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  21  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  22  * DEALINGS IN THE SOFTWARE.
  23  *
  24  * Authors:
  25  *   Florian Forster <octo at collectd.org>
  26  *   Sebastian Harl <sh at tokkee.org>
  27  */
  28
  29 %{
  30 #include <stdlib.h>
  31 #include <string.h>
  32 #include "oconfig.h"
  33 #include "aux_types.h"
  34 #include "parser.h"
  35
  36 #ifdef __clang__
  37 #pragma clang diagnostic push
  38 #pragma clang diagnostic ignored "-Wmissing-noreturn"
  39 #endif
  40
  41
  42 /* multiline string buffer */
  43 static char *ml_buffer = NULL;
  44 static int   ml_pos    = 0;
  45 static int   ml_len    = 0;
  46
  47 #define ml_free (ml_len - ml_pos)
  48
  49 static void ml_append (char *);
  50
  51 #ifdef yyterminate
  52 # undef yyterminate
  53 #endif
  54 #define yyterminate() \
  55         do { free (ml_buffer); ml_buffer = NULL; ml_pos = 0; ml_len = 0; \
  56                 return YY_NULL; } while (0)
  57 %}
  58 %option yylineno
  59 %option noyywrap
  60 %option noinput
  61 %option nounput
  62 %x ML
  63 WHITE_SPACE [\ \t\b]
  64 NON_WHITE_SPACE [^\ \t\b]
  65 EOL (\r\n|\n)
  66 QUOTED_STRING ([^\\"]+|\\.)*
  67 UNQUOTED_STRING [0-9A-Za-z_]+
  68 HEX_NUMBER 0[xX][0-9a-fA-F]+
  69 OCT_NUMBER 0[0-7]+
  70 DEC_NUMBER [\+\-]?[0-9]+
  71 FLOAT_NUMBER [\+\-]?[0-9]*\.[0-9]+([eE][\+\-][0-9]+)?
  72 NUMBER ({FLOAT_NUMBER}|{HEX_NUMBER}|{OCT_NUMBER}|{DEC_NUMBER})
  73 BOOL_TRUE (true|yes|on)
  74 BOOL_FALSE (false|no|off)
  75 COMMENT #.*
  76 PORT (6(5(5(3[0-5]|[0-2][0-9])|[0-4][0-9][0-9])|[0-4][0-9][0-9][0-9])|[1-5][0-9][0-9][0-9][0-9]|[1-9][0-9]?[0-9]?[0-9]?)
  77
  78 IP_BYTE (2(5[0-5]|[0-4][0-9])|1[0-9][0-9]|[1-9]?[0-9])
  79 IPV4_ADDR {IP_BYTE}\.{IP_BYTE}\.{IP_BYTE}\.{IP_BYTE}(:{PORT})?
  80
  81 /* IPv6 address according to http://www.ietf.org/rfc/rfc2373.txt
  82  * This supports embedded IPv4 addresses as well but does not strictly check
  83  * for the right prefix (::0:<v4> or ::FFFF:<v4>) because there are too many
  84  * ways to correctly represent the zero bytes. It's up to the user to check
  85  * for valid addresses. */
  86 HEX16 ([0-9A-Fa-f]{1,4})
  87 V6_PART ({HEX16}:{HEX16}|{IPV4_ADDR})
  88 IPV6_BASE ({HEX16}:){6}{V6_PART}|::({HEX16}:){5}{V6_PART}|({HEX16})?::({HEX16}:){4}{V6_PART}|(({HEX16}:){0,1}{HEX16})?::({HEX16}:){3}{V6_PART}|(({HEX16}:){0,2}{HEX16})?::({HEX16}:){2}{V6_PART}|(({HEX16}:){0,3}{HEX16})?::{HEX16}:{V6_PART}|(({HEX16}:){0,4}{HEX16})?::{V6_PART}|(({HEX16}:){0,5}{HEX16})?::{HEX16}|(({HEX16}:){0,6}{HEX16})?::
  89 IPV6_ADDR ({IPV6_BASE})|(\[{IPV6_BASE}\](:{PORT})?)
  90
  91 %%
  92 {WHITE_SPACE}           |
  93 {COMMENT}               {/* ignore */}
  94
  95 \\{EOL}                 {/* continue line */}
  96
  97 {EOL}                   {return (EOL);}
  98 "/"                     {return (SLASH);}
  99 "<"                     {return (OPENBRAC);}
 100 ">"                     {return (CLOSEBRAC);}
 101 {BOOL_TRUE}             {yylval.boolean = 1; return (BTRUE);}
 102 {BOOL_FALSE}            {yylval.boolean = 0; return (BFALSE);}
 103
 104 {IPV4_ADDR}             {yylval.string = yytext; return (UNQUOTED_STRING);}
 105 {IPV6_ADDR}             {yylval.string = yytext; return (UNQUOTED_STRING);}
 106
 107 {NUMBER}                {yylval.number = strtod (yytext, NULL); return (NUMBER);}
 108
 109 \"{QUOTED_STRING}\"     {yylval.string = yytext; return (QUOTED_STRING);}
 110 {UNQUOTED_STRING}       {yylval.string = yytext; return (UNQUOTED_STRING);}
 111
 112 \"{QUOTED_STRING}\\{EOL} {
 113         int len = strlen (yytext);
 114
 115         ml_pos = 0;
 116
 117         /* remove "\\<EOL>" */
 118         if ('\r' == yytext[len - 2])
 119                 len -= 3;
 120         else
 121                 len -= 2;
 122         yytext[len] = '\0';
 123
 124         ml_append (yytext);
 125         BEGIN (ML);
 126 }
 127 <ML>^{WHITE_SPACE}+ {/* remove leading white-space */}
 128 <ML>{NON_WHITE_SPACE}{QUOTED_STRING}\\{EOL} {
 129         int len = strlen (yytext);
 130
 131         /* remove "\\<EOL>" */
 132         if ('\r' == yytext[len - 2])
 133                 len -= 3;
 134         else
 135                 len -= 2;
 136         yytext[len] = '\0';
 137
 138         ml_append(yytext);
 139 }
 140 <ML>{NON_WHITE_SPACE}{QUOTED_STRING}\" {
 141         ml_append(yytext);
 142         yylval.string = ml_buffer;
 143
 144         BEGIN (INITIAL);
 145         return (QUOTED_STRING);
 146 }
 147 %%
 148 static void ml_append (char *string)
 149 {
 150         int len = strlen (string);
 151         int s;
 152
 153         if (ml_free <= len) {
 154                 ml_len += len - ml_free + 1;
 155                 ml_buffer = realloc (ml_buffer, ml_len);
 156                 if (NULL == ml_buffer)
 157                         YY_FATAL_ERROR ("out of dynamic memory in ml_append");
 158         }
 159
 160         s = snprintf (ml_buffer + ml_pos, ml_free, "%s", string);
 161         if ((0 > s) || (ml_free <= s))
 162                 YY_FATAL_ERROR ("failed to write to multiline buffer");
 163
 164         ml_pos += s;
 165         return;
 166 } /* ml_append */
 167
 168 #ifdef __clang__
 169 #pragma clang diagnostic pop
 170 #endif