src/liboconfig/scanner.l

   1 /**
   2  * collectd - src/liboconfig/scanner.l
   3  * Copyright (C) 2007  Florian Forster
   4  * Copyright (C) 2008  Sebastian Harl
   5  *
   6  * Permission is hereby granted, free of charge, to any person obtaining a
   7  * copy of this software and associated documentation files (the "Software"),
   8  * to deal in the Software without restriction, including without limitation
   9  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
  10  * and/or sell copies of the Software, and to permit persons to whom the
  11  * Software is furnished to do so, subject to the following conditions:
  12  *
  13  * The above copyright notice and this permission notice shall be included in
  14  * all copies or substantial portions of the Software.
  15  *
  16  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  17  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  18  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  19  * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  20  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  21  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  22  * DEALINGS IN THE SOFTWARE.
  23  *
  24  * Authors:
  25  *   Florian Forster <octo at collectd.org>
  26  *   Sebastian Harl <sh at tokkee.org>
  27  */
  28
  29 %{
  30 #include <stdlib.h>
  31 #include "oconfig.h"
  32 #include "aux_types.h"
  33 #include "parser.h"
  34
  35 /* multiline string buffer */
  36 static char *ml_buffer = NULL;
  37 static int   ml_pos    = 0;
  38 static int   ml_len    = 0;
  39
  40 #define ml_free (ml_len - ml_pos)
  41
  42 static void ml_append (char *);
  43
  44 #ifdef yyterminate
  45 # undef yyterminate
  46 #endif
  47 #define yyterminate() \
  48         do { free (ml_buffer); ml_buffer = NULL; ml_pos = 0; ml_len = 0; \
  49                 return YY_NULL; } while (0)
  50 %}
  51 %option yylineno
  52 %option noyywrap
  53 %x ML
  54 WHITE_SPACE [\ \t\b]
  55 NON_WHITE_SPACE [^\ \t\b]
  56 EOL (\r\n|\n)
  57 QUOTED_STRING ([^\\"]+|\\.)*
  58 UNQUOTED_STRING [0-9A-Za-z_]+
  59 HEX_NUMBER 0[xX][0-9a-fA-F]+
  60 OCT_NUMBER 0[0-7]+
  61 DEC_NUMBER [\+\-]?[0-9]+
  62 FLOAT_NUMBER [\+\-]?[0-9]*\.[0-9]+([eE][\+\-][0-9]+)?
  63 NUMBER ({FLOAT_NUMBER}|{HEX_NUMBER}|{OCT_NUMBER}|{DEC_NUMBER})
  64 BOOL_TRUE (true|yes|on)
  65 BOOL_FALSE (false|no|off)
  66 COMMENT #.*
  67 PORT (6(5(5(3[0-5]|[0-2][0-9])|[0-4][0-9][0-9])|[0-4][0-9][0-9][0-9])|[1-5][0-9][0-9][0-9][0-9]|[1-9][0-9]?[0-9]?[0-9]?)
  68
  69 IP_BYTE (2(5[0-5]|[0-4][0-9])|1[0-9][0-9]|[1-9]?[0-9])
  70 IPV4_ADDR {IP_BYTE}\.{IP_BYTE}\.{IP_BYTE}\.{IP_BYTE}(:{PORT})?
  71
  72 /* IPv6 address according to http://www.ietf.org/rfc/rfc2373.txt
  73  * This supports embedded IPv4 addresses as well but does not strictly check
  74  * for the right prefix (::0:<v4> or ::FFFF:<v4>) because there are too many
  75  * ways to correctly represent the zero bytes. It's up to the user to check
  76  * for valid addresses. */
  77 HEX16 ([0-9A-Fa-f]{1,4})
  78 V6_PART ({HEX16}:{HEX16}|{IPV4_ADDR})
  79 IPV6_BASE ({HEX16}:){6}{V6_PART}|::({HEX16}:){5}{V6_PART}|({HEX16})?::({HEX16}:){4}{V6_PART}|(({HEX16}:){0,1}{HEX16})?::({HEX16}:){3}{V6_PART}|(({HEX16}:){0,2}{HEX16})?::({HEX16}:){2}{V6_PART}|(({HEX16}:){0,3}{HEX16})?::{HEX16}:{V6_PART}|(({HEX16}:){0,4}{HEX16})?::{V6_PART}|(({HEX16}:){0,5}{HEX16})?::{HEX16}|(({HEX16}:){0,6}{HEX16})?::
  80 IPV6_ADDR ({IPV6_BASE})|(\[{IPV6_BASE}\](:{PORT})?)
  81
  82 %%
  83 {WHITE_SPACE}           |
  84 {COMMENT}               {/* ignore */}
  85
  86 \\{EOL}                 {/* continue line */}
  87
  88 {EOL}                   {return (EOL);}
  89 "/"                     {return (SLASH);}
  90 "<"                     {return (OPENBRAC);}
  91 ">"                     {return (CLOSEBRAC);}
  92 {BOOL_TRUE}             {yylval.boolean = 1; return (BTRUE);}
  93 {BOOL_FALSE}            {yylval.boolean = 0; return (BFALSE);}
  94
  95 {IPV4_ADDR}             {yylval.string = yytext; return (UNQUOTED_STRING);}
  96 {IPV6_ADDR}             {yylval.string = yytext; return (UNQUOTED_STRING);}
  97
  98 {NUMBER}                {yylval.number = strtod (yytext, NULL); return (NUMBER);}
  99
 100 \"{QUOTED_STRING}\"     {yylval.string = yytext; return (QUOTED_STRING);}
 101 {UNQUOTED_STRING}       {yylval.string = yytext; return (UNQUOTED_STRING);}
 102
 103 \"{QUOTED_STRING}\\{EOL} {
 104         int len = strlen (yytext);
 105
 106         ml_pos = 0;
 107
 108         /* remove "\\<EOL>" */
 109         if ('\r' == yytext[len - 2])
 110                 len -= 3;
 111         else
 112                 len -= 2;
 113         yytext[len] = '\0';
 114
 115         ml_append (yytext);
 116         BEGIN (ML);
 117 }
 118 <ML>^{WHITE_SPACE}+ {/* remove leading white-space */}
 119 <ML>{NON_WHITE_SPACE}{QUOTED_STRING}\\{EOL} {
 120         int len = strlen (yytext);
 121
 122         /* remove "\\<EOL>" */
 123         if ('\r' == yytext[len - 2])
 124                 len -= 3;
 125         else
 126                 len -= 2;
 127         yytext[len] = '\0';
 128
 129         ml_append(yytext);
 130 }
 131 <ML>{NON_WHITE_SPACE}{QUOTED_STRING}\" {
 132         ml_append(yytext);
 133         yylval.string = ml_buffer;
 134
 135         BEGIN (INITIAL);
 136         return (QUOTED_STRING);
 137 }
 138 %%
 139 static void ml_append (char *string)
 140 {
 141         int len = strlen (string);
 142         int s;
 143
 144         if (ml_free <= len) {
 145                 ml_len += len - ml_free + 1;
 146                 ml_buffer = (char *)realloc (ml_buffer, ml_len);
 147                 if (NULL == ml_buffer)
 148                         YY_FATAL_ERROR ("out of dynamic memory in ml_append");
 149         }
 150
 151         s = snprintf (ml_buffer + ml_pos, ml_free, "%s", string);
 152         if ((0 > s) || (ml_free <= s))
 153                 YY_FATAL_ERROR ("failed to write to multiline buffer");
 154
 155         ml_pos += s;
 156         return;
 157 } /* ml_append */
 158