src/liboconfig/scanner.l

   1 /**
   2  * collectd - src/liboconfig/scanner.l
   3  * Copyright (C) 2007  Florian Forster
   4  * Copyright (C) 2008  Sebastian Harl
   5  *
   6  * Permission is hereby granted, free of charge, to any person obtaining a
   7  * copy of this software and associated documentation files (the "Software"),
   8  * to deal in the Software without restriction, including without limitation
   9  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
  10  * and/or sell copies of the Software, and to permit persons to whom the
  11  * Software is furnished to do so, subject to the following conditions:
  12  *
  13  * The above copyright notice and this permission notice shall be included in
  14  * all copies or substantial portions of the Software.
  15  *
  16  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  17  * IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  18  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  19  * AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  20  * LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  21  * FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  22  * DEALINGS IN THE SOFTWARE.
  23  *
  24  * Authors:
  25  *   Florian Forster <octo at collectd.org>
  26  *   Sebastian Harl <sh at tokkee.org>
  27  */
  28
  29 %{
  30 /* lex and yacc do some weird stuff, so turn off some warnings. */
  31 #if defined(__clang__)
  32 # pragma clang diagnostic ignored "-Wunused-function"
  33 # pragma clang diagnostic ignored "-Wunneeded-internal-declaration"
  34 #endif
  35
  36 #include <stdlib.h>
  37 #include "oconfig.h"
  38 #include "aux_types.h"
  39 #include "parser.h"
  40
  41 /* multiline string buffer */
  42 static char *ml_buffer = NULL;
  43 static int   ml_pos    = 0;
  44 static int   ml_len    = 0;
  45
  46 #define ml_free (ml_len - ml_pos)
  47
  48 static void ml_append (char *);
  49
  50 #ifdef yyterminate
  51 # undef yyterminate
  52 #endif
  53 #define yyterminate() \
  54         do { free (ml_buffer); ml_buffer = NULL; ml_pos = 0; ml_len = 0; \
  55                 return YY_NULL; } while (0)
  56 %}
  57 %option yylineno
  58 %option noyywrap
  59 %x ML
  60 WHITE_SPACE [\ \t\b]
  61 NON_WHITE_SPACE [^\ \t\b]
  62 EOL (\r\n|\n)
  63 QUOTED_STRING ([^\\"]+|\\.)*
  64 UNQUOTED_STRING [0-9A-Za-z_]+
  65 HEX_NUMBER 0[xX][0-9a-fA-F]+
  66 OCT_NUMBER 0[0-7]+
  67 DEC_NUMBER [\+\-]?[0-9]+
  68 FLOAT_NUMBER [\+\-]?[0-9]*\.[0-9]+([eE][\+\-][0-9]+)?
  69 NUMBER ({FLOAT_NUMBER}|{HEX_NUMBER}|{OCT_NUMBER}|{DEC_NUMBER})
  70 BOOL_TRUE (true|yes|on)
  71 BOOL_FALSE (false|no|off)
  72 COMMENT #.*
  73 PORT (6(5(5(3[0-5]|[0-2][0-9])|[0-4][0-9][0-9])|[0-4][0-9][0-9][0-9])|[1-5][0-9][0-9][0-9][0-9]|[1-9][0-9]?[0-9]?[0-9]?)
  74
  75 IP_BYTE (2(5[0-5]|[0-4][0-9])|1[0-9][0-9]|[1-9]?[0-9])
  76 IPV4_ADDR {IP_BYTE}\.{IP_BYTE}\.{IP_BYTE}\.{IP_BYTE}(:{PORT})?
  77
  78 /* IPv6 address according to http://www.ietf.org/rfc/rfc2373.txt
  79  * This supports embedded IPv4 addresses as well but does not strictly check
  80  * for the right prefix (::0:<v4> or ::FFFF:<v4>) because there are too many
  81  * ways to correctly represent the zero bytes. It's up to the user to check
  82  * for valid addresses. */
  83 HEX16 ([0-9A-Fa-f]{1,4})
  84 V6_PART ({HEX16}:{HEX16}|{IPV4_ADDR})
  85 IPV6_BASE ({HEX16}:){6}{V6_PART}|::({HEX16}:){5}{V6_PART}|({HEX16})?::({HEX16}:){4}{V6_PART}|(({HEX16}:){0,1}{HEX16})?::({HEX16}:){3}{V6_PART}|(({HEX16}:){0,2}{HEX16})?::({HEX16}:){2}{V6_PART}|(({HEX16}:){0,3}{HEX16})?::{HEX16}:{V6_PART}|(({HEX16}:){0,4}{HEX16})?::{V6_PART}|(({HEX16}:){0,5}{HEX16})?::{HEX16}|(({HEX16}:){0,6}{HEX16})?::
  86 IPV6_ADDR ({IPV6_BASE})|(\[{IPV6_BASE}\](:{PORT})?)
  87
  88 %%
  89 {WHITE_SPACE}           |
  90 {COMMENT}               {/* ignore */}
  91
  92 \\{EOL}                 {/* continue line */}
  93
  94 {EOL}                   {return (EOL);}
  95 "/"                     {return (SLASH);}
  96 "<"                     {return (OPENBRAC);}
  97 ">"                     {return (CLOSEBRAC);}
  98 {BOOL_TRUE}             {yylval.boolean = 1; return (BTRUE);}
  99 {BOOL_FALSE}            {yylval.boolean = 0; return (BFALSE);}
 100
 101 {IPV4_ADDR}             {yylval.string = yytext; return (UNQUOTED_STRING);}
 102 {IPV6_ADDR}             {yylval.string = yytext; return (UNQUOTED_STRING);}
 103
 104 {NUMBER}                {yylval.number = strtod (yytext, NULL); return (NUMBER);}
 105
 106 \"{QUOTED_STRING}\"     {yylval.string = yytext; return (QUOTED_STRING);}
 107 {UNQUOTED_STRING}       {yylval.string = yytext; return (UNQUOTED_STRING);}
 108
 109 \"{QUOTED_STRING}\\{EOL} {
 110         int len = strlen (yytext);
 111
 112         ml_pos = 0;
 113
 114         /* remove "\\<EOL>" */
 115         if ('\r' == yytext[len - 2])
 116                 len -= 3;
 117         else
 118                 len -= 2;
 119         yytext[len] = '\0';
 120
 121         ml_append (yytext);
 122         BEGIN (ML);
 123 }
 124 <ML>^{WHITE_SPACE}+ {/* remove leading white-space */}
 125 <ML>{NON_WHITE_SPACE}{QUOTED_STRING}\\{EOL} {
 126         int len = strlen (yytext);
 127
 128         /* remove "\\<EOL>" */
 129         if ('\r' == yytext[len - 2])
 130                 len -= 3;
 131         else
 132                 len -= 2;
 133         yytext[len] = '\0';
 134
 135         ml_append(yytext);
 136 }
 137 <ML>{NON_WHITE_SPACE}{QUOTED_STRING}\" {
 138         ml_append(yytext);
 139         yylval.string = ml_buffer;
 140
 141         BEGIN (INITIAL);
 142         return (QUOTED_STRING);
 143 }
 144 %%
 145 static void ml_append (char *string)
 146 {
 147         int len = strlen (string);
 148         int s;
 149
 150         if (ml_free <= len) {
 151                 ml_len += len - ml_free + 1;
 152                 ml_buffer = (char *)realloc (ml_buffer, ml_len);
 153                 if (NULL == ml_buffer)
 154                         YY_FATAL_ERROR ("out of dynamic memory in ml_append");
 155         }
 156
 157         s = snprintf (ml_buffer + ml_pos, ml_free, "%s", string);
 158         if ((0 > s) || (ml_free <= s))
 159                 YY_FATAL_ERROR ("failed to write to multiline buffer");
 160
 161         ml_pos += s;
 162         return;
 163 } /* ml_append */
 164