onis

   1 #!/usr/bin/perl
   2 ##########################################################################
   3 #    onis 0.7.2                                               2005-01-21 #
   4 #---=============--------------------------------------------------------#
   5 # Language: Perl                                                         #
   6 # Purpose:  Generating statistics                                        #
   7 # Input:    IRC-Logfiles                                                 #
   8 # Output:   One HTML file                                                #
   9 # Version:  0.7.2 (unstable)                                             #
  10 # License:  GPL                                                          #
  11 # Homepage: http://verplant.org/onis/                                    #
  12 # Authors:  Florian octo Forster <octo@verplant.org>                     #
  13 #           Contributions are listed in THANKS                           #
  14 ##########################################################################
  15
  16 BEGIN
  17 {
  18         if ($0 =~ m#^(.*)[/\\]#) { chdir ($1); }
  19
  20         unshift (@INC, 'lib');
  21
  22         # 0x0010   Language (make not-translated lines red/yellow)
  23         # 0x0020   Parser (dropped lines)
  24         # 0x0040   Parser (time information)
  25         # 0x0100   Data::Core (host unsharp)
  26         # 0x0200   Data::Persistent
  27         # 0x0400   Data::Core (dump incoming data to stderr)
  28         # 0x0800   Data::Core (initializing)
  29         # 0x1000   Onis::Users
  30         $::DEBUG = 0x0000;
  31 }
  32
  33 use strict;
  34 use warnings;
  35
  36 use Onis::Config qw/get_config parse_argv read_config/;
  37 use File::Basename qw/dirname/;
  38 use Fcntl qw/:flock/;
  39
  40 use vars qw/$VERSION $REVISION/;
  41
  42 $VERSION = '';
  43 $REVISION = '$LastChangedRevision$';
  44
  45 if (!$VERSION)
  46 {
  47         $VERSION = $REVISION;
  48         $VERSION =~ s/^\D*(\d+).*/r$1/;
  49 }
  50
  51 our $FileInfo;
  52 our $PURGE_LOGS = 0;
  53
  54 print STDERR $/, __FILE__, ': $Id$' if ($::DEBUG);
  55
  56 parse_argv (@ARGV);
  57 read_config (get_config ('config') ? get_config ('config') : 'config');
  58 read_config (scalar get_config ('theme')) if (get_config ('theme'));
  59
  60 my $output = get_config ('output');
  61 if (!$output)
  62 {
  63         $output = "reports/onis.html";
  64 }
  65
  66 foreach ('Core', get_config ('plugin'))
  67 {
  68         my $module = ucfirst (lc ($_));
  69         require "Onis/Plugins/$module.pm";
  70 }
  71
  72 if (!get_config ('input'))
  73 {
  74         print STDERR <<EOF;
  75
  76 Usage: $0 [options] <logfile> [logfile logfile ..]
  77
  78 Options:
  79         --config                Specify alternate config file
  80         --output <file>         Defines the file to write the HTML to.
  81         --overwrite <bool>      Overwrites files without prompting.
  82         --channel <channel>     Defines the channel's name.
  83         --logtype <type>        Defines the logfile's type.
  84                                 See 'config' for a complete list.
  85         --user <name>           Define's the generator's name.
  86
  87 For a full list of all options please read the ``config'' file.
  88 EOF
  89         exit (1);
  90 }
  91
  92 if (-e $output)
  93 {
  94         my $overwrite = 0;
  95         if (get_config ('overwrite'))
  96         {
  97                 my $tmp = lc (get_config ('overwrite'));
  98                 if ($tmp eq 'true' or $tmp eq 'yes' or $tmp eq 'on')
  99                 {
 100                         $overwrite = 1;
 101                 }
 102         }
 103
 104         if (!$overwrite)
 105         {
 106                 print STDERR <<MESSAGE;
 107
 108 WARNING: The output file ``$output'' already exists
 109
 110   You can set the ``overwrite'' option in the config
 111   file to disable this dialog.
 112
 113 MESSAGE
 114                 print STDERR 'Are you sure you want to overwrite it? [Y|n] ';
 115                 my $answer = <STDIN>;
 116                 exit (1) if ($answer =~ m/n/i);
 117         }
 118 }
 119
 120 my $logtype = 'Eggdrop';
 121 if (get_config ('logtype'))
 122 {
 123         $logtype = ucfirst (lc (get_config ('logtype')));
 124 }
 125
 126 require "Onis/Parser/$logtype.pm";
 127 require Onis::Parser::Persistent;
 128 require Onis::Data::Persistent;
 129 import Onis::Parser (qw(parse last_date));
 130 import Onis::Parser::Persistent (qw(newfile));
 131 import Onis::Data::Persistent ();
 132
 133 $FileInfo = Onis::Data::Persistent->new ('FileInfo', 'inode', qw(mtime));
 134
 135 if (get_config ('purge_logs'))
 136 {
 137         my $temp = lc (get_config ('purge_logs'));
 138         if (($temp eq 'truncate') or ($temp eq 'shorten'))
 139         {
 140                 $PURGE_LOGS = 1;
 141         }
 142         elsif (($temp eq 'delete') or ($temp eq 'remove')
 143                         or ($temp eq 'del'))
 144         {
 145                 $PURGE_LOGS = 2;
 146         }
 147 }
 148
 149 for (get_config ('input'))
 150 {
 151         my $file = $_;
 152         my $logfile;
 153         my $status = 4;
 154         my $position = 0;
 155         my $mtime;
 156         my $size;
 157         my $inode;
 158
 159         ($inode, $size, $mtime) = (stat ($file))[1,7,9];
 160
 161         print STDERR $/, $/, __FILE__, " --- New File ``$file'' ---" if ($::DEBUG & 0x200);
 162
 163         if (!defined ($mtime))
 164         {
 165                 print STDERR $/, __FILE__, ": Unable to stat file ``$file''";
 166                 next;
 167         }
 168         else
 169         {
 170                 my ($old_mtime) = $FileInfo->get ($inode);
 171
 172                 print STDERR $/, __FILE__, ": ``$file'': " if ($::DEBUG & 0x200);
 173
 174                 if (defined ($old_mtime))
 175                 {
 176                         if ($old_mtime == $mtime)
 177                         {
 178                                 print STDERR "File did not change. Skipping." if ($::DEBUG & 0x200);
 179                                 next;
 180                         }
 181                         elsif ($old_mtime < $mtime)
 182                         {
 183                                 print STDERR "File changed. Reading it again." if ($::DEBUG & 0x200);
 184                         }
 185                         else
 186                         {
 187                                 print STDERR "File ``$file'' is older than expected. There might be a problem!";
 188                         }
 189                 }
 190                 else
 191                 {
 192                         print STDERR "File appears to be new. Reading it." if ($::DEBUG & 0x200);
 193                 }
 194                 $FileInfo->put ($inode, $mtime);
 195         }
 196
 197         # truncate
 198         if ($PURGE_LOGS == 1)
 199         {
 200                 unless (open ($logfile, '+< ' . $file))
 201                 {
 202                         print STDERR $/, __FILE__, ": Unable to open file ``$file'': $!";
 203                         next;
 204                 }
 205         }
 206         else
 207         {
 208                 unless (open ($logfile, '< ' . $file))
 209                 {
 210                         print STDERR $/, __FILE__, ": Unable to open file ``$file'': $!";
 211                         next;
 212                 }
 213         }
 214
 215         if ($PURGE_LOGS)
 216         {
 217                 unless (flock ($logfile, LOCK_EX))
 218                 {
 219                         print STDERR $/, __FILE__, ": Unable to get an exclusive lock for file ``$file'': $!";
 220                         close ($logfile);
 221                         next;
 222                 }
 223         }
 224         else
 225         {
 226                 unless (flock ($logfile, LOCK_SH))
 227                 {
 228                         print STDERR $/, __FILE__, ": Unable to get a shared lock for file ``$file'': $!";
 229                         close ($logfile);
 230                         next;
 231                 }
 232         }
 233
 234         newfile ($FileInfo->{$inode});
 235         while (<$logfile>)
 236         {
 237                 s/\n|\r//g;
 238                 $status = parse ($_);
 239
 240                 # 0 == rewind file
 241                 # 1 == line parsed
 242                 # 2 == unable to parse
 243                 # 3 == line old
 244                 # 4 == don't have date
 245
 246                 if ($status == 0)
 247                 {
 248                         print STDERR $/, __FILE__, ": Rewinding file ``$file''" if ($::DEBUG & 0x200);
 249                         seek ($logfile, 0, 0);
 250                         $position = 0;
 251                 }
 252                 elsif (($status == 1) or ($status == 2)
 253                                 or ($status == 3))
 254                 {
 255                         $position = tell ($logfile);
 256                 }
 257                 elsif ($status == 4)
 258                 {
 259                         # void
 260                 }
 261                 else
 262                 {
 263                         print STDERR $/, __FILE__, ": Parser returned unknown status code: ``$status''";
 264                 }
 265         }
 266
 267         if ($PURGE_LOGS and (($status == 1)
 268                                 or ($status == 2)
 269                                 or ($status == 3)))
 270         {
 271                 if (($PURGE_LOGS > 1)
 272                         #and (($position + 1) >= $size)
 273                         )
 274                 {
 275                         # delete file
 276                         print STDERR $/, __FILE__, ": Deleting empty file ``$file''" if ($::DEBUG & 0x200);
 277                         close ($logfile);
 278
 279                         if (-w $file)
 280                         {
 281                                 unless (unlink ($file))
 282                                 {
 283                                         print STDERR $/, __FILE__, ": Unable to delete empty file ``$file'': $!";
 284                                 }
 285                                 delete ($FileInfo->{$inode});
 286                         }
 287                         else
 288                         {
 289                                 print STDERR $/, __FILE__, ": Won't delete ``$file''. Set it to writeable first!";
 290                         }
 291                 }
 292                 else
 293                 {
 294                         seek ($logfile, 0, 0);
 295                         if (truncate ($logfile, 0))
 296                         {
 297                                 print $logfile &last_date ();
 298                                 print STDERR $/, __FILE__, ": Truncated ``$file''" if ($::DEBUG & 0x200);
 299                         }
 300                         else
 301                         {
 302                                 print STDERR $/, __FILE__, ": Couldn't truncate file ``$file'': $!";
 303                         }
 304
 305                         close ($logfile);
 306                 }
 307         }
 308         else
 309         {
 310                 close ($logfile);
 311         }
 312 }
 313
 314 require Onis::Data::Core;
 315 require Onis::Html;
 316 import Onis::Data::Core qw#print_output#;
 317 import Onis::Html qw#open_file close_file#;
 318
 319 if (open_file ($output))
 320 {
 321         print_output ();
 322         close_file ();
 323 }
 324 else
 325 {
 326         # Fail and make noise! ;)
 327         print STDERR <<MESSAGE;
 328
 329 ERROR: Unable to open output file
 330
 331 The output file ``$output'' could not be opened. Please make sure to set
 332 the permissions right and try again.
 333
 334 MESSAGE
 335         exit (1);
 336 }
 337
 338 exit (0);
 339
 340 END
 341 {
 342         print $/ if ($::DEBUG);
 343 }