CMakeLists.txt

   1 #
   2 # SuperTux - root build script
   3 # Copyright (C) 2006 Christoph Sommer <christoph.sommer@2006.expires.deltadevelopment.de>
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  18 #
  19
  20
  21 #
  22 # INSTRUCTIONS:
  23 # -------------
  24 #
  25 # Create a directory build/ and change to it. Run
  26 #
  27 #   cmake ..
  28 #
  29 # This creates a set of Makefiles to build the project. Run
  30 #
  31 #   make
  32 #
  33
  34
  35 ## Project name to use as command prefix.
  36
  37 PROJECT(SUPERTUX)
  38
  39 ## Version, for display in title bar.
  40 ## Will add r<revision number> to the end if svnversion is available.
  41 SET(SUPERTUX_VERSION "0.3.3-SVN")
  42
  43 ### CMake configuration
  44
  45 # allow building with CMake 2.6. Set compatibility options. Use some bundled modules as a fallback
  46 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
  47 IF(COMMAND cmake_policy)
  48         CMAKE_POLICY(SET CMP0003 NEW)
  49 ENDIF(COMMAND cmake_policy)
  50
  51 SET(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${CMAKE_CURRENT_SOURCE_DIR}/mk/cmake)
  52
  53 ## For autopackage
  54 OPTION(ENABLE_BINRELOC "Enable autopackage's BINRELOC features" OFF)
  55 SET(APPDATADIR "${CMAKE_INSTALL_PREFIX}/share/games/supertux2")
  56
  57 ## Check endianess
  58
  59 INCLUDE(TestBigEndian)
  60 TEST_BIG_ENDIAN(WORDS_BIGENDIAN)
  61
  62 ## Add lots of dependencies to compiler switches
  63
  64 SET(Boost_ADDITIONAL_VERSIONS "1.41" "1.41.0")
  65 FIND_PACKAGE(Boost REQUIRED)
  66 INCLUDE_DIRECTORIES(SYSTEM ${Boost_INCLUDE_DIR})
  67 LINK_DIRECTORIES(${Boost_LIBRARY_DIRS})
  68
  69 FIND_PACKAGE(SDL REQUIRED)
  70 INCLUDE_DIRECTORIES(${SDL_INCLUDE_DIR})
  71 SET(HAVE_SDL TRUE)
  72
  73 FIND_PACKAGE(SDL_image REQUIRED)
  74 INCLUDE_DIRECTORIES(${SDLIMAGE_INCLUDE_DIR})
  75
  76 OPTION(ENABLE_OPENGL "Enable OpenGL support" ON)
  77 IF(ENABLE_OPENGL)
  78   FIND_PACKAGE(OpenGL)
  79   IF(OPENGL_FOUND)
  80     INCLUDE_DIRECTORIES(${OPENGL_INCLUDE_DIR})
  81     SET(HAVE_OPENGL TRUE)
  82   ENDIF(OPENGL_FOUND)
  83
  84   FIND_PACKAGE(GLEW)
  85   IF(GLEW_FOUND)
  86     INCLUDE_DIRECTORIES(${GLEW_INCLUDE_DIR})
  87   ENDIF(GLEW_FOUND)
  88 ENDIF(ENABLE_OPENGL)
  89
  90 FIND_PACKAGE(OpenAL REQUIRED)
  91 INCLUDE_DIRECTORIES(${OPENAL_INCLUDE_DIR})
  92
  93 FIND_PACKAGE(OggVorbis REQUIRED)
  94 INCLUDE_DIRECTORIES(${VORBIS_INCLUDE_DIR})
  95
  96 FIND_PACKAGE(PhysFS REQUIRED)
  97 INCLUDE_DIRECTORIES(${PHYSFS_INCLUDE_DIR})
  98
  99 FIND_PACKAGE(CURL)
 100 IF(CURL_FOUND)
 101   INCLUDE_DIRECTORIES(${CURL_INCLUDE_DIR})
 102   SET(HAVE_LIBCURL TRUE)
 103 ENDIF(CURL_FOUND)
 104
 105 #FIND_PACKAGE(ICONV REQUIRED)
 106 #INCLUDE_DIRECTORIES(${ICONV_INCLUDE_DIR})
 107 #LINK_LIBRARIES(${ICONV_LIBRARY})
 108
 109 ## Find revision of WC
 110 MARK_AS_ADVANCED(SVNVERSION_EXECUTABLE)
 111 FIND_PROGRAM(SVNVERSION_EXECUTABLE svnversion)
 112
 113 IF(SVNVERSION_EXECUTABLE)
 114   ADD_CUSTOM_TARGET(svnversion ALL
 115                     ${CMAKE_COMMAND} -E echo "#ifndef VERSION_H" > "${CMAKE_BINARY_DIR}/version.h.tmp"
 116                     COMMAND ${CMAKE_COMMAND} -E echo "#define VERSION_H" >> "${CMAKE_BINARY_DIR}/version.h.tmp"
 117                     COMMAND ${CMAKE_COMMAND} >> "${CMAKE_BINARY_DIR}/version.h.tmp" -E echo_append "#define PACKAGE_VERSION \"${SUPERTUX_VERSION} r"
 118                     COMMAND ${SVNVERSION_EXECUTABLE} -n ${CMAKE_CURRENT_SOURCE_DIR} >> "${CMAKE_BINARY_DIR}/version.h.tmp"
 119                     COMMAND ${CMAKE_COMMAND} >>  "${CMAKE_BINARY_DIR}/version.h.tmp" -E echo "\""
 120                     COMMAND ${CMAKE_COMMAND} -E echo "#endif" >>  "${CMAKE_BINARY_DIR}/version.h.tmp"
 121                     COMMAND ${CMAKE_COMMAND} -E copy_if_different "${CMAKE_BINARY_DIR}/version.h.tmp" "${CMAKE_BINARY_DIR}/version.h"
 122                     COMMAND ${CMAKE_COMMAND} -E remove "${CMAKE_BINARY_DIR}/version.h.tmp"
 123                     WORKING_DIRECTORY "${CMAKE_BINARY_DIR}"
 124                     COMMENT "Updating ${CMAKE_BINARY_DIR}/version.h..."
 125                     VERBATIM)
 126 ELSE(SVNVERSION_EXECUTABLE)
 127   ADD_CUSTOM_TARGET(svnversion ALL
 128                     ${CMAKE_COMMAND} -E echo "#ifndef VERSION_H" > "${CMAKE_BINARY_DIR}/version.h.tmp"
 129                     COMMAND ${CMAKE_COMMAND} -E echo "#define VERSION_H" >> "${CMAKE_BINARY_DIR}/version.h.tmp"
 130                     COMMAND ${CMAKE_COMMAND} >> "${CMAKE_BINARY_DIR}/version.h.tmp" -E echo "#define PACKAGE_VERSION \"${SUPERTUX_VERSION}\""
 131                     COMMAND ${CMAKE_COMMAND} -E echo "#endif" >>  "${CMAKE_BINARY_DIR}/version.h.tmp"
 132                     COMMAND ${CMAKE_COMMAND} -E copy_if_different "${CMAKE_BINARY_DIR}/version.h.tmp" "${CMAKE_BINARY_DIR}/version.h"
 133                     COMMAND ${CMAKE_COMMAND} -E remove "${CMAKE_BINARY_DIR}/version.h.tmp"
 134                     WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
 135                     COMMENT "Updating ${CMAKE_BINARY_DIR}/version.h..."
 136                     VERBATIM)
 137 ENDIF(SVNVERSION_EXECUTABLE)
 138
 139 SET_SOURCE_FILES_PROPERTIES(${CMAKE_BINARY_DIR}/version.h
 140                             PROPERTIES GENERATED true)
 141 SET_SOURCE_FILES_PROPERTIES(${CMAKE_CURRENT_SOURCE_DIR}/src/supertux/main.cpp
 142                             PROPERTIES OBJECT_DEPENDS "${CMAKE_BINARY_DIR}/version.h")
 143 SET_SOURCE_FILES_PROPERTIES(${CMAKE_CURRENT_SOURCE_DIR}/src/supertux/title_screen.cpp
 144                             PROPERTIES OBJECT_DEPENDS "${CMAKE_BINARY_DIR}/version.h")
 145 SET_SOURCE_FILES_PROPERTIES(${CMAKE_CURRENT_SOURCE_DIR}/src/addon/addon_manager.cpp
 146                             PROPERTIES OBJECT_DEPENDS "${CMAKE_BINARY_DIR}/version.h")
 147 ## Check platform-dependent build options
 148
 149 INCLUDE(ConfigureChecks)
 150
 151 ## Also execute instructions in external/squirrel/CMakeLists.txt
 152
 153 ADD_SUBDIRECTORY(${CMAKE_CURRENT_SOURCE_DIR}/external/squirrel)
 154
 155 ## Add squirrel lib dir to search path
 156
 157 LINK_DIRECTORIES(${CMAKE_CURRENT_SOURCE_DIR}/external/squirrel)
 158
 159 ## Some additional include paths
 160
 161 include_directories (${CMAKE_BINARY_DIR}/)
 162 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/src/)
 163 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/external/squirrel/include/)
 164 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/external/tinygettext/)
 165 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/external/findlocale/)
 166 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/external/obstack/)
 167 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/external/binreloc/)
 168
 169 ## MSVC Compatibility headers and definitions
 170
 171 IF(MSVC)
 172 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/mk/msvc)
 173 ADD_DEFINITIONS(-D_USE_MATH_DEFINES -DNOMINMAX)
 174 ENDIF(MSVC)
 175
 176 ## Build list of sources for supertux binary
 177
 178 FILE(GLOB SUPERTUX_SOURCES_C RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} external/obstack/*.c external/findlocale/findlocale.c)
 179
 180 FILE(GLOB SUPERTUX_SOURCES_CXX RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} src/main.cpp src/*/*.cpp src/supertux/menu/*.cpp src/video/sdl/*.cpp)
 181
 182 FILE(GLOB TINYGETTEXT_SOURCES_CXX RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} external/tinygettext/tinygettext/*.cpp)
 183 SET_SOURCE_FILES_PROPERTIES(${TINYGETTEXT_SOURCES_CXX} PROPERTIES COMPILE_DEFINITIONS HAVE_SDL)
 184
 185 IF(HAVE_OPENGL)
 186   FILE(GLOB SUPERTUX_OPENGL_SOURCES RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} src/video/gl/*.cpp)
 187   SET(SUPERTUX_SOURCES_CXX ${SUPERTUX_SOURCES_CXX} ${SUPERTUX_OPENGL_SOURCES})
 188 ENDIF(HAVE_OPENGL)
 189
 190 ## Build miniswig and generate miniswig wrapper
 191
 192 OPTION(GENERATE_WRAPPER "Build miniswig and generate the wrapper" OFF)
 193 IF(GENERATE_WRAPPER)
 194   ADD_SUBDIRECTORY(tools/miniswig)
 195   ADD_CUSTOM_COMMAND(
 196     OUTPUT ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.cpp ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.hpp
 197     COMMAND cd ${CMAKE_CURRENT_SOURCE_DIR} && ${CMAKE_CXX_COMPILER}
 198     ARGS -x "c++" -E -CC -DSCRIPTING_API src/scripting/wrapper.interface.hpp -o ${CMAKE_CURRENT_BINARY_DIR}/miniswig.tmp -I${CMAKE_CURRENT_SOURCE_DIR}/src
 199     COMMAND tools/miniswig/miniswig
 200     ARGS --input miniswig.tmp --output-cpp ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.cpp --output-hpp ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.hpp --module supertux --select-namespace scripting
 201     DEPENDS tools/miniswig/miniswig
 202     IMPLICIT_DEPENDS CXX ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.interface.hpp
 203   )
 204 ENDIF(GENERATE_WRAPPER)
 205
 206 IF(NOT EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.cpp)
 207   SET(SUPERTUX_SOURCES_CXX ${SUPERTUX_SOURCES_CXX} ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.cpp)
 208 ENDIF(NOT EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.cpp)
 209
 210 ## Compile everything at once (roughly equivalent to cat *.cpp | gcc)
 211
 212 OPTION(COMPILE_AMALGATION "Compile all the files together at once (experimental)" OFF)
 213 IF(COMPILE_AMALGATION)
 214   FILE(WRITE ${CMAKE_CURRENT_BINARY_DIR}/amalgation.cpp "// Includes all source files of the project\n")
 215   FOREACH(ST_FILE ${SUPERTUX_SOURCES_CXX})
 216     FILE(RELATIVE_PATH CXX_FILE ${CMAKE_CURRENT_SOURCE_DIR}/src "${CMAKE_CURRENT_SOURCE_DIR}/${ST_FILE}")
 217     FILE(APPEND ${CMAKE_CURRENT_BINARY_DIR}/amalgation.cpp "#include \"${CXX_FILE}\"\n")
 218   ENDFOREACH(ST_FILE)
 219   ## Build instead of CXX sources
 220   SET(SUPERTUX_SOURCES_CXX ${CMAKE_CURRENT_BINARY_DIR}/amalgation.cpp)
 221 ELSE(COMPILE_AMALGATION)
 222   IF(EXISTS ${CMAKE_CURRENT_BINARY_DIR}/amalgation.cpp)
 223     FILE(REMOVE ${CMAKE_CURRENT_BINARY_DIR}/amalgation.cpp)
 224   ENDIF(EXISTS ${CMAKE_CURRENT_BINARY_DIR}/amalgation.cpp)
 225 ENDIF(COMPILE_AMALGATION)
 226
 227 ## Debug options
 228
 229 OPTION(WERROR "Stop on first compiler warning" OFF)
 230 OPTION(WARNINGS "Enable long list of warnings for compiler to check" OFF)
 231 IF(CMAKE_COMPILER_IS_GNUCC)
 232   SET(CMAKE_CXX_FLAGS_DEBUG "-O0 -g" CACHE STRING "Debug flags")
 233   SET(CMAKE_C_FLAGS_DEBUG "-O0 -g" CACHE STRING "Debug flags")
 234   SET(CMAKE_CXX_FLAGS_PROFILE "-pg" CACHE STRING "Profile flags")
 235   SET(CMAKE_C_FLAGS_PROFILE "-pg" CACHE STRING "Profile flags")
 236   SET(CMAKE_LD_FLAGS_PROFILE "-lgmon" CACHE STRING "Profile flags")
 237   ADD_DEFINITIONS(-Wall -Wextra -funit-at-a-time)
 238   IF(WERROR)
 239     ADD_DEFINITIONS(-Werror)
 240   ELSE(WERROR)
 241     REMOVE_DEFINITIONS(-Werror)
 242   ENDIF(WERROR)
 243   IF(WARNINGS)
 244     ADD_DEFINITIONS(-fdiagnostics-show-option -pedantic -Wno-long-long -Wcast-align -Wdisabled-optimization -Winit-self -Winvalid-pch -Wlogical-op -Wmissing-include-dirs -Wmissing-noreturn -Wpacked -Wredundant-decls -Wstack-protector -Wconversion -Wundef -Wsign-conversion -Wshadow -Winline -Wunsafe-loop-optimizations -Wfloat-equal -Wswitch-default -Wswitch-enum -Wcast-qual -Wsign-promo -Woverloaded-virtual -Wmissing-format-attribute -Wstrict-overflow=5 -Wformat=2-Weffc++ -Wabi -Wctor-dtor-privacy -Wstrict-null-sentinel -Wno-unused-parameter)
 245     # -ansi fails in MinGW
 246     # still left:  -Wold-style-cast -Wpadded
 247   ENDIF(WARNINGS)
 248 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 249
 250 ## If xgettext is available, generate messages.pot for sources
 251
 252 OPTION(GENERATE_MESSAGESPOT "Generate messages.pot files" OFF)
 253 IF(GENERATE_MESSAGESPOT)
 254   MARK_AS_ADVANCED(
 255     XGETTEXT_EXECUTABLE
 256   )
 257   FIND_PROGRAM(XGETTEXT_EXECUTABLE xgettext)
 258   IF(NOT XGETTEXT_EXECUTABLE)
 259     MESSAGE(STATUS "Warning: xgettext not found - will not update messages.pot")
 260   ELSE(NOT XGETTEXT_EXECUTABLE)
 261     MESSAGE(STATUS "Found xgettext: ${XGETTEXT_EXECUTABLE}")
 262
 263     SET(MESSAGES_POT_FILE ${CMAKE_CURRENT_SOURCE_DIR}/data/locale/messages.pot)
 264     ADD_CUSTOM_COMMAND(
 265       OUTPUT ${MESSAGES_POT_FILE}
 266       COMMAND ${XGETTEXT_EXECUTABLE}
 267       ARGS --keyword=_ --language=C++ --output=${MESSAGES_POT_FILE} ${SUPERTUX_SOURCES_CXX}
 268       DEPENDS ${SUPERTUX_SOURCES_CXX}
 269       WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 270       COMMENT "Generating POT file ${MESSAGES_POT_FILE}"
 271     )
 272     LIST(APPEND MESSAGES_POT_FILES ${MESSAGES_POT_FILE})
 273
 274     FILE(GLOB SUPERTUX_LEVEL_DIRS RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} data/levels/*)
 275     LIST(REMOVE_ITEM SUPERTUX_LEVEL_DIRS "data/levels/.svn")
 276     FOREACH(SUPERTUX_LEVEL_DIR ${SUPERTUX_LEVEL_DIRS})
 277       FILE(GLOB SUPERTUX_LEVELS RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} ${SUPERTUX_LEVEL_DIR}/*.stl ${SUPERTUX_LEVEL_DIR}/*.stwm ${SUPERTUX_LEVEL_DIR}/*.txt)
 278
 279       ## Do not add target if SUPERTUX_LEVELS is empty. This is needed for cmake <=2.4
 280       IF(SUPERTUX_LEVELS)
 281       SET(MESSAGES_POT_FILE ${CMAKE_CURRENT_SOURCE_DIR}/${SUPERTUX_LEVEL_DIR}/messages.pot)
 282       ADD_CUSTOM_COMMAND(
 283         OUTPUT ${MESSAGES_POT_FILE}
 284         COMMAND ${XGETTEXT_EXECUTABLE}
 285         ARGS --keyword="_:1" --language=Lisp --force-po --sort-by-file "--output=${MESSAGES_POT_FILE}" ${SUPERTUX_LEVELS}
 286         DEPENDS ${SUPERTUX_LEVELS}
 287         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 288         COMMENT "Generating POT file ${MESSAGES_POT_FILE}"
 289       )
 290       LIST(APPEND MESSAGES_POT_FILES ${MESSAGES_POT_FILE})
 291       ENDIF(SUPERTUX_LEVELS)
 292
 293     ENDFOREACH(SUPERTUX_LEVEL_DIR)
 294
 295     ADD_CUSTOM_TARGET(
 296       supertux2-messages ALL
 297       DEPENDS ${MESSAGES_POT_FILES}
 298     )
 299
 300   ENDIF(NOT XGETTEXT_EXECUTABLE)
 301 ENDIF(GENERATE_MESSAGESPOT)
 302
 303 ## Some additional compiler switches
 304 IF(CMAKE_COMPILER_IS_GNUCC)
 305   ADD_DEFINITIONS(-fno-strict-aliasing)
 306 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 307
 308 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 309   ADD_DEFINITIONS(-DMACOSX)
 310 ENDIF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 311
 312
 313 ## On Windows, add an icon
 314
 315 IF(WIN32)
 316 #  SET(SUPERTUX_SOURCES_C ${SUPERTUX_SOURCES_C} ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.rc)
 317   IF(MINGW)
 318     ADD_CUSTOM_COMMAND(
 319     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/supertux_rc.o
 320     COMMAND windres.exe -I${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons -i${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.rc -o ${CMAKE_CURRENT_BINARY_DIR}/supertux_rc.o)
 321     SET(SUPERTUX_SOURCES_C ${SUPERTUX_SOURCES_C} ${CMAKE_CURRENT_BINARY_DIR}/supertux_rc.o)
 322   ELSE(MINGW)
 323     SET(SUPERTUX_EXE_SRCS ${SUPERTUX_EXE_SRCS} supertux.rc)
 324   ENDIF(MINGW)
 325 ENDIF(WIN32)
 326
 327 ## Add binreloc.c if enabled
 328 IF(ENABLE_BINRELOC)
 329   SET(SUPERTUX_SOURCES_C ${SUPERTUX_SOURCES_C} ${CMAKE_CURRENT_SOURCE_DIR}/external/binreloc/binreloc.c)
 330 ENDIF(ENABLE_BINRELOC)
 331
 332
 333 ## Generate supertux executable in the right place
 334
 335 SET(EXECUTABLE_OUTPUT_PATH ${CMAKE_CURRENT_SOURCE_DIR})
 336
 337 ## Add target for supertux binary
 338
 339 ADD_EXECUTABLE(supertux2 ${CMAKE_BINARY_DIR}/version.h ${SUPERTUX_SOURCES_C} ${SUPERTUX_SOURCES_CXX} ${TINYGETTEXT_SOURCES_CXX})
 340 ADD_DEPENDENCIES(supertux2 svnversion)
 341
 342 ## Link supertux binary with squirrel and other libraries
 343
 344 TARGET_LINK_LIBRARIES(supertux2 squirrel)
 345 TARGET_LINK_LIBRARIES(supertux2 ${SDL_LIBRARY})
 346 TARGET_LINK_LIBRARIES(supertux2 ${SDLIMAGE_LIBRARY})
 347 TARGET_LINK_LIBRARIES(supertux2 ${OPENAL_LIBRARY})
 348 TARGET_LINK_LIBRARIES(supertux2 ${OGGVORBIS_LIBRARIES})
 349 TARGET_LINK_LIBRARIES(supertux2 ${PHYSFS_LIBRARY})
 350 IF(HAVE_OPENGL)
 351     TARGET_LINK_LIBRARIES(supertux2 ${OPENGL_LIBRARY})
 352     TARGET_LINK_LIBRARIES(supertux2 ${GLEW_LIBRARY})
 353 ENDIF(HAVE_OPENGL)
 354 IF(HAVE_LIBCURL)
 355   TARGET_LINK_LIBRARIES(supertux2 ${CURL_LIBRARY})
 356 ENDIF(HAVE_LIBCURL)
 357
 358 ## Install stuff
 359
 360 IF(WIN32 AND NOT UNIX)
 361
 362   SET(INSTALL_SUBDIR_BIN "." CACHE STRING "Installation subdir for binaries")
 363   SET(INSTALL_SUBDIR_SHARE "data" CACHE STRING "Installation subdir for data")
 364   SET(INSTALL_SUBDIR_DOC "." CACHE STRING "Installation subdir for docs")
 365
 366   FILE(GLOB DLLS "${CMAKE_CURRENT_SOURCE_DIR}/*.dll")
 367   INSTALL(FILES ${DLLS} DESTINATION ${INSTALL_SUBDIR_BIN})
 368
 369   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.png ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.ico DESTINATION ".")
 370
 371 ELSE(WIN32 AND NOT UNIX)
 372 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 373
 374   SET(INSTALL_SUBDIR_BIN "SuperTux.app/Contents/MacOS" CACHE STRING "Installation subdir for binaries")
 375   SET(INSTALL_SUBDIR_SHARE "SuperTux.app/Contents/Resources/data" CACHE STRING "Installation subdir for data")
 376   SET(INSTALL_SUBDIR_DOC "SuperTux.app/Contents/Resources" CACHE STRING "Installation subdir for docs")
 377
 378   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/tools/darwin/info.plist DESTINATION "SuperTux.app/Contents/")
 379
 380   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.png ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.icns DESTINATION "SuperTux.app/Contents/Resources/")
 381
 382 ELSE(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 383
 384   SET(INSTALL_SUBDIR_BIN "games" CACHE STRING "Installation subdir for binaries")
 385   SET(INSTALL_SUBDIR_SHARE "share/games/supertux2" CACHE STRING "Installation subdir for data")
 386   SET(INSTALL_SUBDIR_DOC "share/doc/supertux2" CACHE STRING "Installation subdir for docs")
 387
 388   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/supertux2.desktop DESTINATION "share/applications")
 389
 390   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.png ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.xpm DESTINATION "share/pixmaps/")
 391
 392 ENDIF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 393 ENDIF(WIN32 AND NOT UNIX)
 394
 395 INSTALL(TARGETS supertux2 DESTINATION ${INSTALL_SUBDIR_BIN})
 396
 397 INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/INSTALL ${CMAKE_CURRENT_SOURCE_DIR}/README ${CMAKE_CURRENT_SOURCE_DIR}/COPYING ${CMAKE_CURRENT_SOURCE_DIR}/WHATSNEW.txt DESTINATION ${INSTALL_SUBDIR_DOC})
 398
 399 INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/data/credits.txt DESTINATION ${INSTALL_SUBDIR_SHARE})
 400
 401 INSTALL(DIRECTORY data/images
 402                   data/fonts
 403                   data/levels
 404                   data/music
 405                   data/scripts
 406                   data/speech
 407                   data/sounds
 408                   data/locale
 409                                DESTINATION ${INSTALL_SUBDIR_SHARE} PATTERN ".svn" EXCLUDE)
 410
 411 ## Create config.h now that INSTALL_SUBDIR_* have been set.
 412
 413 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h )
 414
 415
 416 ## CPack/Installation-specific stuff
 417
 418 INCLUDE(InstallRequiredSystemLibraries)
 419 SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Jump'n'Run Game featuring Tux")
 420 SET(CPACK_PACKAGE_VENDOR "SuperTux Devel Team")
 421 SET(CPACK_PACKAGE_CONTACT "SuperTux Devel Team <supertux-devel@lists.lethargik.org>")
 422 SET(CPACK_DEBIAN_PACKAGE_NAME "supertux2")
 423 SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6 (>= 2.5), libgcc1 (>= 1:4.1), libgl1-mesa-glx | libgl1, libogg0 (>= 1.1.3), libopenal0a, libphysfs-1.0-0, libsdl-image1.2 (>= 1.2.5), libsdl1.2debian (>= 1.2.10-1), libstdc++6 (>= 4.1.2), libvorbis0a (>= 1.1.2), libvorbisfile3 (>= 1.1.2), libcurl3 (>= 7.16)")
 424 SET(CPACK_DEBIAN_PACKAGE_DESCRIPTION "Classic 2D jump 'n run sidescroller with Tux\n SuperTux is a classic 2D jump 'n run sidescroller game in a similar\n style like the original SuperMario games. This release of SuperTux\n features 9 enemies, 26 playable levels, software and OpenGL rendering\n modes, configurable joystick and keyboard input, new music and\n completely redone graphics.\n .\n This is a development snapshot of SuperTux. It may suffer from\n critical bugs and has not been fully tested. \n .\n Homepage: http://supertux.lethargik.org/")
 425 SET(CPACK_DEBIAN_PACKAGE_SECTION "games")
 426 SET(CPACK_RPM_PACKAGE_NAME "supertux2")
 427 SET(CPACK_RPM_PACKAGE_DESCRIPTION "Classic 2D jump 'n run sidescroller with Tux\n SuperTux is a classic 2D jump 'n run sidescroller game in a similar\n style like the original SuperMario games. This release of SuperTux\n features 9 enemies, 26 playable levels, software and OpenGL rendering\n modes, configurable joystick and keyboard input, new music and\n completely redone graphics.\n .\n This is a development snapshot of SuperTux. It may suffer from\n critical bugs and has not been fully tested. \n .\n Homepage: http://supertux.lethargik.org/")
 428 SET(CPACK_RPM_PACKAGE_LICENSE "GNU General Public License (GPL)")
 429 SET(CPACK_RPM_PACKAGE_GROUP "Amusements/Games/Action/Arcade")
 430 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 431   # The OS X PackageMaker doesn't seem to like files with no extension
 432 ELSE(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 433   SET(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README")
 434   SET(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/COPYING")
 435 ENDIF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 436 SET(CPACK_PACKAGE_VERSION_MAJOR "0")
 437 SET(CPACK_PACKAGE_VERSION_MINOR "3")
 438 SET(CPACK_PACKAGE_VERSION_PATCH "3-SVN")
 439 SET(CPACK_PACKAGE_INSTALL_DIRECTORY "SuperTux ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 440 SET(CPACK_PACKAGE_EXECUTABLES "..\\\\supertux2" "SuperTux ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 441 IF(WIN32 AND NOT UNIX)
 442   SET(CPACK_NSIS_INSTALLED_ICON_NAME "..\\\\supertux2")
 443   SET(CPACK_NSIS_DISPLAY_NAME "SuperTux ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 444 ELSE(WIN32 AND NOT UNIX)
 445 ENDIF(WIN32 AND NOT UNIX)
 446 INCLUDE(CPack)
 447
 448 # move some config clutter to the advanced section
 449 MARK_AS_ADVANCED(
 450   INSTALL_SUBDIR_BIN
 451   INSTALL_SUBDIR_SHARE
 452   INSTALL_SUBDIR_DOC
 453 )
 454
 455 MARK_AS_ADVANCED(
 456         CMAKE_BACKWARDS_COMPATIBILITY
 457         CMAKE_BUILD_TYPE
 458         CMAKE_INSTALL_PREFIX
 459         EXECUTABLE_OUTPUT_PATH
 460         LIBRARY_OUTPUT_PATH
 461         CMAKE_OSX_ARCHITECTURES
 462         CMAKE_OSX_SYSROOT
 463 )
 464
 465 MARK_AS_ADVANCED(
 466         ENABLE_BINRELOC
 467         APPDATADIR
 468 )
 469
 470 MARK_AS_ADVANCED(
 471         Boost_INCLUDE_DIR
 472         Boost_LIBRARIES
 473 )
 474
 475 MARK_AS_ADVANCED(
 476         SDLMAIN_LIBRARY
 477         SDL_INCLUDE_DIR
 478         SDL_LIBRARY
 479 )
 480
 481 MARK_AS_ADVANCED(
 482         SDLIMAGE_INCLUDE_DIR
 483         SDLIMAGE_LIBRARY
 484 )
 485
 486 MARK_AS_ADVANCED(
 487         OPENAL_INCLUDE_DIR
 488         OPENAL_LIBRARY
 489 )
 490
 491 MARK_AS_ADVANCED(
 492         OGG_LIBRARY
 493         VORBISENC_LIBRARY
 494         VORBISFILE_LIBRARY
 495         VORBIS_INCLUDE_DIR
 496         VORBIS_LIBRARY
 497 )
 498
 499 MARK_AS_ADVANCED(
 500         PHYSFS_INCLUDE_DIR
 501         PHYSFS_LIBRARY
 502 )