CMakeLists.txt

   1 #
   2 # SuperTux - root build script
   3 # Copyright (C) 2006 Christoph Sommer <christoph.sommer@2006.expires.deltadevelopment.de>
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  18 #
  19
  20
  21 #
  22 # INSTRUCTIONS:
  23 # -------------
  24 #
  25 # Create a directory build/ and change to it. Run
  26 #
  27 #   cmake ..
  28 #
  29 # This creates a set of Makefiles to build the project. Run
  30 #
  31 #   make
  32 #
  33
  34
  35 ## Project name to use as command prefix.
  36
  37 PROJECT(SUPERTUX)
  38
  39 ## Version, for display in title bar.
  40 ## Will add 'commit <hash>' to the end if git is available and this is a git repository.
  41 SET(SUPERTUX_VERSION "0.3.4-GIT")
  42
  43 ### CMake configuration
  44
  45 # allow building with CMake 2.6. Set compatibility options. Use some bundled modules as a fallback
  46 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
  47 IF(COMMAND cmake_policy)
  48         CMAKE_POLICY(SET CMP0003 NEW)
  49 ENDIF(COMMAND cmake_policy)
  50
  51 SET(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${CMAKE_CURRENT_SOURCE_DIR}/mk/cmake)
  52
  53 ## For autopackage
  54 SET(APPDATADIR "${CMAKE_INSTALL_PREFIX}/share/games/supertux2")
  55
  56 ## Check endianess
  57
  58 INCLUDE(TestBigEndian)
  59 TEST_BIG_ENDIAN(WORDS_BIGENDIAN)
  60
  61 ## Add lots of dependencies to compiler switches
  62
  63 SET(Boost_ADDITIONAL_VERSIONS "1.41" "1.41.0")
  64 FIND_PACKAGE(Boost REQUIRED)
  65 INCLUDE_DIRECTORIES(SYSTEM ${Boost_INCLUDE_DIR})
  66 LINK_DIRECTORIES(${Boost_LIBRARY_DIRS})
  67
  68 INCLUDE(FindPkgConfig)
  69 PKG_SEARCH_MODULE(SDL2 REQUIRED sdl2>=2.0.1)
  70 PKG_SEARCH_MODULE(SDL2IMAGE REQUIRED SDL2_image>=2.0.0)
  71 SET(HAVE_SDL TRUE)
  72
  73 OPTION(ENABLE_OPENGL "Enable OpenGL support" ON)
  74 OPTION(GLBINDING_ENABLED "Use glbinding instead of GLEW" OFF)
  75 OPTION(GLBINDING_DEBUG_OUTPUT "Enable glbinding debug output for each called OpenGL function" OFF)
  76 IF(ENABLE_OPENGL)
  77   FIND_PACKAGE(OpenGL)
  78   IF(OPENGL_FOUND)
  79     INCLUDE_DIRECTORIES(${OPENGL_INCLUDE_DIR})
  80     SET(HAVE_OPENGL TRUE)
  81   ENDIF(OPENGL_FOUND)
  82
  83   IF(GLBINDING_ENABLED)
  84     FIND_PACKAGE(GLBINDING REQUIRED)
  85     IF(GLBINDING_FOUND)
  86       INCLUDE_DIRECTORIES(${GLBINDING_INCLUDES})
  87       ADD_DEFINITIONS(-DUSE_GLBINDING)
  88       IF (GLBINDING_DEBUG_OUTPUT)
  89         ADD_DEFINITIONS(-DUSE_GLBINDING_DEBUG_OUTPUT)
  90       ENDIF()
  91     ENDIF()
  92   ELSE()
  93     FIND_PACKAGE(GLEW REQUIRED)
  94     IF(GLEW_FOUND)
  95       INCLUDE_DIRECTORIES(${GLEW_INCLUDE_DIR})
  96     ENDIF(GLEW_FOUND)
  97   ENDIF()
  98 ENDIF(ENABLE_OPENGL)
  99
 100 FIND_PACKAGE(OpenAL REQUIRED)
 101 INCLUDE_DIRECTORIES(${OPENAL_INCLUDE_DIR})
 102
 103 FIND_PACKAGE(OggVorbis REQUIRED)
 104 INCLUDE_DIRECTORIES(${VORBIS_INCLUDE_DIR})
 105
 106 FIND_PACKAGE(PhysFS REQUIRED)
 107 INCLUDE_DIRECTORIES(${PHYSFS_INCLUDE_DIR})
 108
 109 FIND_PACKAGE(CURL)
 110 IF(CURL_FOUND)
 111   INCLUDE_DIRECTORIES(${CURL_INCLUDE_DIR})
 112   SET(HAVE_LIBCURL TRUE)
 113 ENDIF(CURL_FOUND)
 114
 115 #FIND_PACKAGE(ICONV REQUIRED)
 116 #INCLUDE_DIRECTORIES(${ICONV_INCLUDE_DIR})
 117 #LINK_LIBRARIES(${ICONV_LIBRARY})
 118
 119 ## Find revision of WC
 120 MARK_AS_ADVANCED(GIT_EXECUTABLE)
 121 FIND_PROGRAM(GIT_EXECUTABLE git)
 122
 123 # The .git directory inside the base directory
 124 SET(GIT_CFG_DIR "${CMAKE_BINARY_DIR}/.git/")
 125
 126 IF(GIT_EXECUTABLE AND EXISTS ${GIT_CFG_DIR})
 127   ADD_CUSTOM_TARGET(gitversion ALL
 128                     ${CMAKE_COMMAND} -E echo "#ifndef VERSION_H" > "${CMAKE_BINARY_DIR}/version.h.tmp"
 129                     COMMAND ${CMAKE_COMMAND} -E echo "#define VERSION_H" >> "${CMAKE_BINARY_DIR}/version.h.tmp"
 130                     COMMAND ${CMAKE_COMMAND} >> "${CMAKE_BINARY_DIR}/version.h.tmp" -E echo_append "#define PACKAGE_VERSION \"${SUPERTUX_VERSION} commit "
 131                     COMMAND ${GIT_EXECUTABLE} rev-parse --sq HEAD >> "${CMAKE_BINARY_DIR}/version.h.tmp"
 132                     COMMAND ${CMAKE_COMMAND} >>  "${CMAKE_BINARY_DIR}/version.h.tmp" -E echo "\""
 133                     COMMAND ${CMAKE_COMMAND} -E echo "#endif" >>  "${CMAKE_BINARY_DIR}/version.h.tmp"
 134                     COMMAND ${CMAKE_COMMAND} -E copy_if_different "${CMAKE_BINARY_DIR}/version.h.tmp" "${CMAKE_BINARY_DIR}/version.h"
 135                     COMMAND ${CMAKE_COMMAND} -E remove "${CMAKE_BINARY_DIR}/version.h.tmp"
 136                     WORKING_DIRECTORY "${CMAKE_BINARY_DIR}"
 137                     COMMENT "Updating ${CMAKE_BINARY_DIR}/version.h..."
 138                     VERBATIM)
 139 ELSE(GIT_EXECUTABLE AND EXISTS ${GIT_CFG_DIR})
 140   ADD_CUSTOM_TARGET(gitversion ALL
 141                     ${CMAKE_COMMAND} -E echo "#ifndef VERSION_H" > "${CMAKE_BINARY_DIR}/version.h.tmp"
 142                     COMMAND ${CMAKE_COMMAND} -E echo "#define VERSION_H" >> "${CMAKE_BINARY_DIR}/version.h.tmp"
 143                     COMMAND ${CMAKE_COMMAND} >> "${CMAKE_BINARY_DIR}/version.h.tmp" -E echo "#define PACKAGE_VERSION \"${SUPERTUX_VERSION}\""
 144                     COMMAND ${CMAKE_COMMAND} -E echo "#endif" >>  "${CMAKE_BINARY_DIR}/version.h.tmp"
 145                     COMMAND ${CMAKE_COMMAND} -E copy_if_different "${CMAKE_BINARY_DIR}/version.h.tmp" "${CMAKE_BINARY_DIR}/version.h"
 146                     COMMAND ${CMAKE_COMMAND} -E remove "${CMAKE_BINARY_DIR}/version.h.tmp"
 147                     WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
 148                     COMMENT "Updating ${CMAKE_BINARY_DIR}/version.h..."
 149                     VERBATIM)
 150 ENDIF(GIT_EXECUTABLE AND EXISTS ${GIT_CFG_DIR})
 151
 152 SET_SOURCE_FILES_PROPERTIES(${CMAKE_BINARY_DIR}/version.h
 153                             PROPERTIES GENERATED true)
 154 SET_SOURCE_FILES_PROPERTIES(${CMAKE_CURRENT_SOURCE_DIR}/src/supertux/main.cpp
 155                             PROPERTIES OBJECT_DEPENDS "${CMAKE_BINARY_DIR}/version.h")
 156 SET_SOURCE_FILES_PROPERTIES(${CMAKE_CURRENT_SOURCE_DIR}/src/supertux/title_screen.cpp
 157                             PROPERTIES OBJECT_DEPENDS "${CMAKE_BINARY_DIR}/version.h")
 158 SET_SOURCE_FILES_PROPERTIES(${CMAKE_CURRENT_SOURCE_DIR}/src/addon/addon_manager.cpp
 159                             PROPERTIES OBJECT_DEPENDS "${CMAKE_BINARY_DIR}/version.h")
 160 ## Check platform-dependent build options
 161
 162 INCLUDE(ConfigureChecks)
 163
 164 ## Also execute instructions in external/squirrel/CMakeLists.txt
 165
 166 ADD_SUBDIRECTORY(${CMAKE_CURRENT_SOURCE_DIR}/external/squirrel)
 167
 168 ## Add squirrel lib dir to search path
 169
 170 LINK_DIRECTORIES(${CMAKE_CURRENT_SOURCE_DIR}/external/squirrel)
 171
 172 ## Some additional include paths
 173
 174 include_directories (${CMAKE_BINARY_DIR}/)
 175 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/src/)
 176 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/external/squirrel/include/)
 177 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/external/tinygettext/include/)
 178 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/external/findlocale/)
 179 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/external/obstack/)
 180
 181 ## MSVC Compatibility headers and definitions
 182
 183 IF(MSVC)
 184 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/mk/msvc)
 185   ADD_DEFINITIONS(-D_USE_MATH_DEFINES -DNOMINMAX)
 186 ENDIF(MSVC)
 187
 188 ## Build list of sources for supertux binary
 189
 190 FILE(GLOB SUPERTUX_SOURCES_C RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} external/obstack/*.c external/findlocale/findlocale.c)
 191
 192 FILE(GLOB SUPERTUX_SOURCES_CXX RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} src/main.cpp src/*/*.cpp src/supertux/menu/*.cpp src/video/sdl/*.cpp)
 193
 194 FILE(GLOB TINYGETTEXT_SOURCES_CXX RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} external/tinygettext/src/*.cpp)
 195 SET_SOURCE_FILES_PROPERTIES(${TINYGETTEXT_SOURCES_CXX} PROPERTIES COMPILE_DEFINITIONS HAVE_SDL)
 196
 197 IF(HAVE_OPENGL)
 198   FILE(GLOB SUPERTUX_OPENGL_SOURCES RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} src/video/gl/*.cpp)
 199   SET(SUPERTUX_SOURCES_CXX ${SUPERTUX_SOURCES_CXX} ${SUPERTUX_OPENGL_SOURCES})
 200 ENDIF(HAVE_OPENGL)
 201
 202 ## Build miniswig and generate miniswig wrapper
 203
 204 OPTION(GENERATE_WRAPPER "Build miniswig and generate the wrapper" OFF)
 205 IF(GENERATE_WRAPPER)
 206   ADD_SUBDIRECTORY(tools/miniswig)
 207   ADD_CUSTOM_COMMAND(
 208     OUTPUT ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.cpp ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.hpp
 209     COMMAND cd ${CMAKE_CURRENT_SOURCE_DIR} && ${CMAKE_CXX_COMPILER}
 210     ARGS -x "c++" -E -CC -DSCRIPTING_API src/scripting/wrapper.interface.hpp -o ${CMAKE_CURRENT_BINARY_DIR}/miniswig.tmp -I${CMAKE_CURRENT_SOURCE_DIR}/src
 211     COMMAND tools/miniswig/miniswig
 212     ARGS --input miniswig.tmp --output-cpp ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.cpp --output-hpp ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.hpp --module supertux --select-namespace scripting
 213     DEPENDS tools/miniswig/miniswig
 214     IMPLICIT_DEPENDS CXX ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.interface.hpp
 215   )
 216 ENDIF(GENERATE_WRAPPER)
 217
 218 IF(NOT EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.cpp)
 219   SET(SUPERTUX_SOURCES_CXX ${SUPERTUX_SOURCES_CXX} ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.cpp)
 220 ENDIF(NOT EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.cpp)
 221
 222 ## Compile everything at once (roughly equivalent to cat *.cpp | gcc)
 223
 224 OPTION(COMPILE_AMALGATION "Compile all the files together at once (experimental)" OFF)
 225 IF(COMPILE_AMALGATION)
 226   FILE(WRITE ${CMAKE_CURRENT_BINARY_DIR}/amalgation.cpp "// Includes all source files of the project\n")
 227   FOREACH(ST_FILE ${SUPERTUX_SOURCES_CXX})
 228     FILE(RELATIVE_PATH CXX_FILE ${CMAKE_CURRENT_SOURCE_DIR}/src "${CMAKE_CURRENT_SOURCE_DIR}/${ST_FILE}")
 229     FILE(APPEND ${CMAKE_CURRENT_BINARY_DIR}/amalgation.cpp "#include \"${CXX_FILE}\"\n")
 230   ENDFOREACH(ST_FILE)
 231   ## Build instead of CXX sources
 232   SET(SUPERTUX_SOURCES_CXX ${CMAKE_CURRENT_BINARY_DIR}/amalgation.cpp)
 233 ELSE(COMPILE_AMALGATION)
 234   IF(EXISTS ${CMAKE_CURRENT_BINARY_DIR}/amalgation.cpp)
 235     FILE(REMOVE ${CMAKE_CURRENT_BINARY_DIR}/amalgation.cpp)
 236   ENDIF(EXISTS ${CMAKE_CURRENT_BINARY_DIR}/amalgation.cpp)
 237 ENDIF(COMPILE_AMALGATION)
 238
 239 ## Debug options
 240
 241 OPTION(WERROR "Stop on first compiler warning" OFF)
 242 OPTION(WARNINGS "Enable long list of warnings for compiler to check" OFF)
 243
 244 # http://www.guyrutenberg.com/2014/01/05/enabling-c11-c0x-in-cmake/
 245 include(CheckCXXCompilerFlag)
 246 CHECK_CXX_COMPILER_FLAG("-std=c++11" COMPILER_SUPPORTS_CXX11)
 247 if(COMPILER_SUPPORTS_CXX11)
 248         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")
 249 else(COMPILER_SUPPORTS_CXX11)
 250   CHECK_CXX_COMPILER_FLAG("-std=c++0x" COMPILER_SUPPORTS_CXX0X)
 251   if(COMPILER_SUPPORTS_CXX0X)
 252         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++0x")
 253   else(COMPILER_SUPPORTS_CXX0X)
 254         message(STATUS "The compiler ${CMAKE_CXX_COMPILER} has no C++11 support. Please use a different C++ compiler.")
 255   endif(COMPILER_SUPPORTS_CXX0X)
 256 endif(COMPILER_SUPPORTS_CXX11)
 257
 258
 259 IF(CMAKE_COMPILER_IS_GNUCC)
 260   SET(CMAKE_CXX_FLAGS_DEBUG "-O0 -g" CACHE STRING "Debug flags")
 261   SET(CMAKE_C_FLAGS_DEBUG "-O0 -g" CACHE STRING "Debug flags")
 262   SET(CMAKE_CXX_FLAGS_PROFILE "-pg" CACHE STRING "Profile flags")
 263   SET(CMAKE_C_FLAGS_PROFILE "-pg" CACHE STRING "Profile flags")
 264   SET(CMAKE_LD_FLAGS_PROFILE "-lgmon" CACHE STRING "Profile flags")
 265   ADD_DEFINITIONS(-Wall -Wextra -Wno-unused-parameter -funit-at-a-time)
 266   IF(WERROR)
 267     ADD_DEFINITIONS(-Werror)
 268   ELSE(WERROR)
 269     REMOVE_DEFINITIONS(-Werror)
 270   ENDIF(WERROR)
 271   IF(WARNINGS)
 272     # temporarily disabled:
 273     #   -Wsign-conversion -Wfloat-equal -Wconversion -Wundef -Wswitch-default
 274     #   -Wswitch-enum -Wsign-promo -Wcast-qual -Woverloaded-virtual -Wmissing-format-attribute
 275     #   -Wold-style-cast -Wpadded -Wabi -Winline -Wunsafe-loop-optimizations -Wstrict-overflow=5
 276     # fails on MinGW:
 277     #   -ansi
 278     # fails on clang:
 279     #   -Wlogical-op -Wstrict-null-sentinel
 280     SET(SUPERTUX2_EXTRA_WARNING_FLAGS "-fdiagnostics-show-option -pedantic -Wno-long-long -Wcast-align -Wdisabled-optimization -Winit-self -Winvalid-pch -Wmissing-include-dirs -Wmissing-noreturn -Wpacked -Wredundant-decls -Wstack-protector -Wformat=2 -Weffc++ -Wctor-dtor-privacy  -Wno-unused-parameter -Wshadow -Wnon-virtual-dtor -Wcast-qual")
 281   ENDIF(WARNINGS)
 282 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 283
 284 ## If xgettext is available, generate messages.pot for sources
 285
 286 OPTION(GENERATE_MESSAGESPOT "Generate messages.pot files" OFF)
 287 IF(GENERATE_MESSAGESPOT)
 288   MARK_AS_ADVANCED(
 289     XGETTEXT_EXECUTABLE
 290   )
 291   FIND_PROGRAM(XGETTEXT_EXECUTABLE xgettext)
 292   IF(NOT XGETTEXT_EXECUTABLE)
 293     MESSAGE(STATUS "Warning: xgettext not found - will not update messages.pot")
 294   ELSE(NOT XGETTEXT_EXECUTABLE)
 295     MESSAGE(STATUS "Found xgettext: ${XGETTEXT_EXECUTABLE}")
 296
 297     SET(MESSAGES_POT_FILE ${CMAKE_CURRENT_SOURCE_DIR}/data/locale/messages.pot)
 298     ADD_CUSTOM_COMMAND(
 299       OUTPUT ${MESSAGES_POT_FILE}
 300       COMMAND ${XGETTEXT_EXECUTABLE}
 301       ARGS --keyword=_ --language=C++ --output=${MESSAGES_POT_FILE} ${SUPERTUX_SOURCES_CXX}
 302       DEPENDS ${SUPERTUX_SOURCES_CXX}
 303       WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 304       COMMENT "Generating POT file ${MESSAGES_POT_FILE}"
 305     )
 306     LIST(APPEND MESSAGES_POT_FILES ${MESSAGES_POT_FILE})
 307
 308     FILE(GLOB SUPERTUX_LEVEL_DIRS RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} data/levels/*)
 309     FOREACH(SUPERTUX_LEVEL_DIR ${SUPERTUX_LEVEL_DIRS})
 310       FILE(GLOB SUPERTUX_LEVELS RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} ${SUPERTUX_LEVEL_DIR}/*.stl ${SUPERTUX_LEVEL_DIR}/*.stwm ${SUPERTUX_LEVEL_DIR}/*.txt)
 311
 312       ## Do not add target if SUPERTUX_LEVELS is empty. This is needed for cmake <=2.4
 313       IF(SUPERTUX_LEVELS)
 314       SET(MESSAGES_POT_FILE ${CMAKE_CURRENT_SOURCE_DIR}/${SUPERTUX_LEVEL_DIR}/messages.pot)
 315       ADD_CUSTOM_COMMAND(
 316         OUTPUT ${MESSAGES_POT_FILE}
 317         COMMAND ${XGETTEXT_EXECUTABLE}
 318         ARGS --keyword="_:1" --language=Lisp --force-po --sort-by-file "--output=${MESSAGES_POT_FILE}" ${SUPERTUX_LEVELS}
 319         DEPENDS ${SUPERTUX_LEVELS}
 320         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 321         COMMENT "Generating POT file ${MESSAGES_POT_FILE}"
 322       )
 323       LIST(APPEND MESSAGES_POT_FILES ${MESSAGES_POT_FILE})
 324       ENDIF(SUPERTUX_LEVELS)
 325
 326     ENDFOREACH(SUPERTUX_LEVEL_DIR)
 327
 328     ADD_CUSTOM_TARGET(
 329       supertux2-messages ALL
 330       DEPENDS ${MESSAGES_POT_FILES}
 331     )
 332
 333   ENDIF(NOT XGETTEXT_EXECUTABLE)
 334 ENDIF(GENERATE_MESSAGESPOT)
 335
 336 ## Some additional compiler switches
 337 IF(CMAKE_COMPILER_IS_GNUCC)
 338   ADD_DEFINITIONS(-fno-strict-aliasing)
 339 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 340
 341 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 342   ADD_DEFINITIONS(-DMACOSX)
 343 ENDIF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 344
 345
 346 ## On Windows, add an icon
 347
 348 IF(WIN32)
 349 #  SET(SUPERTUX_SOURCES_C ${SUPERTUX_SOURCES_C} ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.rc)
 350   IF(MINGW)
 351     ADD_CUSTOM_COMMAND(
 352     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/supertux_rc.o
 353     COMMAND ${CMAKE_RC_COMPILER} -I${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons -i${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.rc -o ${CMAKE_CURRENT_BINARY_DIR}/supertux_rc.o)
 354     SET(SUPERTUX_SOURCES_C ${SUPERTUX_SOURCES_C} ${CMAKE_CURRENT_BINARY_DIR}/supertux_rc.o)
 355   ELSE(MINGW)
 356     SET(SUPERTUX_EXE_SRCS ${SUPERTUX_EXE_SRCS} supertux.rc)
 357   ENDIF(MINGW)
 358 ENDIF(WIN32)
 359
 360 ## Generate supertux executable in the right place
 361
 362 SET(EXECUTABLE_OUTPUT_PATH ${CMAKE_CURRENT_SOURCE_DIR})
 363
 364 ## Add target for supertux binary
 365
 366 ADD_LIBRARY(supertux2_c OBJECT ${SUPERTUX_SOURCES_C})
 367 ADD_EXECUTABLE(supertux2 ${CMAKE_BINARY_DIR}/version.h ${SUPERTUX_SOURCES_CXX} ${TINYGETTEXT_SOURCES_CXX} $<TARGET_OBJECTS:supertux2_c>)
 368 ADD_DEPENDENCIES(supertux2 gitversion)
 369 SET_TARGET_PROPERTIES(supertux2 PROPERTIES COMPILE_FLAGS "${SUPERTUX2_EXTRA_WARNING_FLAGS}")
 370
 371 ## Link supertux binary with squirrel and other libraries
 372
 373 TARGET_INCLUDE_DIRECTORIES(supertux2 SYSTEM PUBLIC ${SDL2_INCLUDE_DIRS})
 374 TARGET_INCLUDE_DIRECTORIES(supertux2 SYSTEM PUBLIC ${SDL2IMAGE_INCLUDE_DIRS})
 375 TARGET_LINK_LIBRARIES(supertux2 ${SDL2_LIBRARIES})
 376 TARGET_LINK_LIBRARIES(supertux2 ${SDL2IMAGE_LIBRARIES})
 377
 378 TARGET_LINK_LIBRARIES(supertux2 squirrel)
 379 TARGET_LINK_LIBRARIES(supertux2 ${OPENAL_LIBRARY})
 380 TARGET_LINK_LIBRARIES(supertux2 ${OGGVORBIS_LIBRARIES})
 381 TARGET_LINK_LIBRARIES(supertux2 ${PHYSFS_LIBRARY})
 382 IF(HAVE_OPENGL)
 383     TARGET_LINK_LIBRARIES(supertux2 ${OPENGL_LIBRARY})
 384     IF(GLBINDING_FOUND)
 385       TARGET_LINK_LIBRARIES(supertux2 ${GLBINDING_LIBRARIES})
 386     ELSE()
 387       TARGET_LINK_LIBRARIES(supertux2 ${GLEW_LIBRARY})
 388     ENDIF()
 389 ENDIF(HAVE_OPENGL)
 390 IF(HAVE_LIBCURL)
 391   TARGET_LINK_LIBRARIES(supertux2 ${CURL_LIBRARY})
 392 ENDIF(HAVE_LIBCURL)
 393
 394 ## Install stuff
 395
 396 IF(WIN32 AND NOT UNIX)
 397
 398   SET(INSTALL_SUBDIR_BIN "." CACHE STRING "Installation subdir for binaries")
 399   SET(INSTALL_SUBDIR_SHARE "data" CACHE STRING "Installation subdir for data")
 400   SET(INSTALL_SUBDIR_DOC "." CACHE STRING "Installation subdir for docs")
 401
 402   FILE(GLOB DLLS "${CMAKE_CURRENT_SOURCE_DIR}/*.dll")
 403   INSTALL(FILES ${DLLS} DESTINATION ${INSTALL_SUBDIR_BIN})
 404
 405   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.png ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.ico DESTINATION ".")
 406
 407 ELSE(WIN32 AND NOT UNIX)
 408 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 409
 410   SET(INSTALL_SUBDIR_BIN "SuperTux.app/Contents/MacOS" CACHE STRING "Installation subdir for binaries")
 411   SET(INSTALL_SUBDIR_SHARE "SuperTux.app/Contents/Resources/data" CACHE STRING "Installation subdir for data")
 412   SET(INSTALL_SUBDIR_DOC "SuperTux.app/Contents/Resources" CACHE STRING "Installation subdir for docs")
 413
 414   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/tools/darwin/info.plist DESTINATION "SuperTux.app/Contents/")
 415   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/tools/darwin/receipt DESTINATION "SuperTux.app/Contents/_MASReceipt/")
 416
 417   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.png ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.icns DESTINATION "SuperTux.app/Contents/Resources/")
 418
 419 ELSE(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 420
 421   SET(INSTALL_SUBDIR_BIN "games" CACHE STRING "Installation subdir for binaries")
 422   SET(INSTALL_SUBDIR_SHARE "share/games/supertux2" CACHE STRING "Installation subdir for data")
 423   SET(INSTALL_SUBDIR_DOC "share/doc/supertux2" CACHE STRING "Installation subdir for docs")
 424
 425   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/supertux2.desktop DESTINATION "share/applications")
 426
 427   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.png ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.xpm DESTINATION "share/pixmaps/")
 428
 429 ENDIF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 430 ENDIF(WIN32 AND NOT UNIX)
 431
 432 INSTALL(TARGETS supertux2 DESTINATION ${INSTALL_SUBDIR_BIN})
 433
 434 INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/INSTALL.md ${CMAKE_CURRENT_SOURCE_DIR}/README.md ${CMAKE_CURRENT_SOURCE_DIR}/COPYING ${CMAKE_CURRENT_SOURCE_DIR}/WHATSNEW.txt DESTINATION ${INSTALL_SUBDIR_DOC})
 435
 436 INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/data/credits.txt DESTINATION ${INSTALL_SUBDIR_SHARE})
 437
 438 INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/supertux2.appdata.xml DESTINATION "share/appdata" )
 439
 440 INSTALL(DIRECTORY data/images
 441                   data/fonts
 442                   data/levels
 443                   data/music
 444                   data/scripts
 445                   data/speech
 446                   data/sounds
 447                   data/locale
 448                   DESTINATION ${INSTALL_SUBDIR_SHARE})
 449
 450 ## Create config.h now that INSTALL_SUBDIR_* have been set.
 451
 452 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h )
 453
 454
 455 ## CPack/Installation-specific stuff
 456
 457 INCLUDE(InstallRequiredSystemLibraries)
 458 SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Jump'n'Run Game featuring Tux")
 459 SET(CPACK_PACKAGE_VENDOR "SuperTux Devel Team")
 460 SET(CPACK_PACKAGE_CONTACT "SuperTux Devel Team <supertux-devel@lists.lethargik.org>")
 461 SET(CPACK_DEBIAN_PACKAGE_NAME "supertux2")
 462 SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6 (>= 2.5), libgcc1 (>= 1:4.1), libgl1-mesa-glx | libgl1, libogg0 (>= 1.1.3), libopenal0a, libphysfs-1.0-0, libsdl-image1.2 (>= 1.2.5), libsdl1.2debian (>= 1.2.10-1), libstdc++6 (>= 4.1.2), libvorbis0a (>= 1.1.2), libvorbisfile3 (>= 1.1.2), libcurl3 (>= 7.16)")
 463 SET(CPACK_DEBIAN_PACKAGE_DESCRIPTION "Classic 2D jump 'n run sidescroller with Tux\n SuperTux is a classic 2D jump 'n run sidescroller game in a similar\n style like the original SuperMario games. This release of SuperTux\n features 9 enemies, 26 playable levels, software and OpenGL rendering\n modes, configurable joystick and keyboard input, new music and\n completely redone graphics.\n .\n This is a development snapshot of SuperTux. It may suffer from\n critical bugs and has not been fully tested. \n .\n Homepage: http://supertux.lethargik.org/")
 464 SET(CPACK_DEBIAN_PACKAGE_SECTION "games")
 465 SET(CPACK_RPM_PACKAGE_NAME "supertux2")
 466 SET(CPACK_RPM_PACKAGE_DESCRIPTION "Classic 2D jump 'n run sidescroller with Tux\n SuperTux is a classic 2D jump 'n run sidescroller game in a similar\n style like the original SuperMario games. This release of SuperTux\n features 9 enemies, 26 playable levels, software and OpenGL rendering\n modes, configurable joystick and keyboard input, new music and\n completely redone graphics.\n .\n This is a development snapshot of SuperTux. It may suffer from\n critical bugs and has not been fully tested. \n .\n Homepage: http://supertux.lethargik.org/")
 467 SET(CPACK_RPM_PACKAGE_LICENSE "GNU General Public License (GPL)")
 468 SET(CPACK_RPM_PACKAGE_GROUP "Amusements/Games/Action/Arcade")
 469 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 470   # The OS X PackageMaker doesn't seem to like files with no extension
 471 ELSE(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 472   SET(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README.md")
 473   SET(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/COPYING")
 474 ENDIF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 475 SET(CPACK_PACKAGE_VERSION_MAJOR "0")
 476 SET(CPACK_PACKAGE_VERSION_MINOR "3")
 477 SET(CPACK_PACKAGE_VERSION_PATCH "4-GIT")
 478 SET(CPACK_PACKAGE_INSTALL_DIRECTORY "SuperTux ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 479 SET(CPACK_PACKAGE_EXECUTABLES "..\\\\supertux2" "SuperTux ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 480 IF(WIN32 AND NOT UNIX)
 481   SET(CPACK_NSIS_INSTALLED_ICON_NAME "..\\\\supertux2")
 482   SET(CPACK_NSIS_DISPLAY_NAME "SuperTux ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 483 ELSE(WIN32 AND NOT UNIX)
 484 ENDIF(WIN32 AND NOT UNIX)
 485 INCLUDE(CPack)
 486
 487 # move some config clutter to the advanced section
 488 MARK_AS_ADVANCED(
 489   INSTALL_SUBDIR_BIN
 490   INSTALL_SUBDIR_SHARE
 491   INSTALL_SUBDIR_DOC
 492 )
 493
 494 MARK_AS_ADVANCED(
 495         CMAKE_BACKWARDS_COMPATIBILITY
 496         CMAKE_BUILD_TYPE
 497         CMAKE_INSTALL_PREFIX
 498         EXECUTABLE_OUTPUT_PATH
 499         LIBRARY_OUTPUT_PATH
 500         CMAKE_OSX_ARCHITECTURES
 501         CMAKE_OSX_SYSROOT
 502 )
 503
 504 MARK_AS_ADVANCED(
 505         APPDATADIR
 506 )
 507
 508 MARK_AS_ADVANCED(
 509         Boost_INCLUDE_DIR
 510         Boost_LIBRARIES
 511 )
 512
 513 MARK_AS_ADVANCED(
 514         SDL2_INCLUDE_DIRS
 515         SDL2_LIBRARIES
 516 )
 517
 518 MARK_AS_ADVANCED(
 519         SDL2IMAGE_INCLUDE_DIRS
 520         SDL2IMAGE_LIBRARIES
 521 )
 522
 523 MARK_AS_ADVANCED(
 524         OPENAL_INCLUDE_DIR
 525         OPENAL_LIBRARY
 526 )
 527
 528 MARK_AS_ADVANCED(
 529         OGG_LIBRARY
 530         VORBISENC_LIBRARY
 531         VORBISFILE_LIBRARY
 532         VORBIS_INCLUDE_DIR
 533         VORBIS_LIBRARY
 534 )
 535
 536 MARK_AS_ADVANCED(
 537         PHYSFS_INCLUDE_DIR
 538         PHYSFS_LIBRARY
 539 )