CMakeLists.txt

   1 #
   2 # SuperTux - root build script
   3 # Copyright (C) 2006 Christoph Sommer <christoph.sommer@2006.expires.deltadevelopment.de>
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  18 #
  19
  20
  21 #
  22 # INSTRUCTIONS:
  23 # -------------
  24 #
  25 # Create a directory build/ and change to it. Run
  26 #
  27 #   cmake ..
  28 #
  29 # This creates a set of Makefiles to build the project. Run
  30 #
  31 #   make
  32 #
  33
  34
  35 ## Project name to use as command prefix
  36
  37 PROJECT(SUPERTUX)
  38
  39
  40 ### CMake configuration
  41
  42 # allow building with CMake 2.6. Set compatibility options. Use some bundled modules as a fallback
  43 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
  44 IF(COMMAND cmake_policy)
  45         CMAKE_POLICY(SET CMP0003 NEW)
  46 ENDIF(COMMAND cmake_policy)
  47
  48 SET(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${SUPERTUX_SOURCE_DIR}/mk/cmake)
  49
  50 ## For autopackage
  51 OPTION(ENABLE_BINRELOC "Enable autopackage's BINRELOC features" OFF)
  52 SET(APPDATADIR "${CMAKE_INSTALL_PREFIX}/share/games/supertux2")
  53
  54 ## Check endianess
  55
  56 INCLUDE(TestBigEndian)
  57 TEST_BIG_ENDIAN(WORDS_BIGENDIAN)
  58
  59 ## Add lots of dependencies to compiler switches
  60
  61 FIND_PACKAGE(SDL REQUIRED)
  62 INCLUDE_DIRECTORIES(${SDL_INCLUDE_DIR})
  63
  64 FIND_PACKAGE(SDL_image REQUIRED)
  65 INCLUDE_DIRECTORIES(${SDLIMAGE_INCLUDE_DIR})
  66
  67 OPTION(ENABLE_OPENGL "Enable OpenGL support" ON)
  68 IF(ENABLE_OPENGL)
  69   FIND_PACKAGE(OpenGL)
  70   IF(${OPENGL_FOUND} STREQUAL "YES")
  71     INCLUDE_DIRECTORIES(${OPENGL_INCLUDE_DIR})
  72     SET(HAVE_OPENGL TRUE)
  73   ENDIF(${OPENGL_FOUND} STREQUAL "YES")
  74 ENDIF(ENABLE_OPENGL)
  75
  76 FIND_PACKAGE(OpenAL REQUIRED)
  77 INCLUDE_DIRECTORIES(${OPENAL_INCLUDE_DIR})
  78
  79 FIND_PACKAGE(OggVorbis REQUIRED)
  80 INCLUDE_DIRECTORIES(${OGGVORBIS_INCLUDE_DIR})
  81
  82 FIND_PACKAGE(PhysFS REQUIRED)
  83 INCLUDE_DIRECTORIES(${PHYSFS_INCLUDE_DIR})
  84
  85 FIND_PACKAGE(CURL)
  86 IF(CURL_FOUND)
  87   INCLUDE_DIRECTORIES(${CURL_INCLUDE_DIR})
  88   SET(HAVE_LIBCURL TRUE)
  89 ENDIF(CURL_FOUND)
  90
  91 #FIND_PACKAGE(ICONV REQUIRED)
  92 #INCLUDE_DIRECTORIES(${ICONV_INCLUDE_DIR})
  93 #LINK_LIBRARIES(${ICONV_LIBRARY})
  94
  95 ## Find revision of WC
  96 MARK_AS_ADVANCED(SVNVERSION_EXECUTABLE)
  97 FIND_PROGRAM(SVNVERSION_EXECUTABLE svnversion)
  98 IF(SVNVERSION_EXECUTABLE)
  99   EXECUTE_PROCESS(COMMAND svnversion -n ${SUPERTUX_SOURCE_DIR}
 100                   OUTPUT_VARIABLE SUPERTUX_WC_REVISION)
 101   SET(REVISION " r${SUPERTUX_WC_REVISION}")
 102 ENDIF(SVNVERSION_EXECUTABLE)
 103
 104 ## Check platform-dependent build options
 105
 106 INCLUDE(ConfigureChecks)
 107
 108 ## Create config.h and version.h
 109
 110 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h )
 111 configure_file(version.h.cmake ${CMAKE_BINARY_DIR}/version.h )
 112 include_directories (${CMAKE_BINARY_DIR}/)
 113
 114 ## Also execute instructions in src/squirrel/CMakeLists.txt
 115
 116 ADD_SUBDIRECTORY(external/squirrel)
 117
 118 ## Add squirrel lib dir to search path
 119
 120 LINK_DIRECTORIES(external/squirrel)
 121
 122 ## Some additional include paths
 123
 124 include_directories (${SUPERTUX_SOURCE_DIR}/src/)
 125 include_directories (${SUPERTUX_SOURCE_DIR}/external/squirrel/include/)
 126 include_directories (${SUPERTUX_SOURCE_DIR}/external/)
 127 include_directories (${SUPERTUX_SOURCE_DIR}/external/findlocale/)
 128 include_directories (${SUPERTUX_SOURCE_DIR}/external/obstack/)
 129
 130 ## Build list of sources for supertux binary
 131
 132 FILE(GLOB SUPERTUX_SOURCES_C RELATIVE ${SUPERTUX_SOURCE_DIR} external/obstack/*.c external/findlocale/findlocale.c)
 133
 134 FILE(GLOB SUPERTUX_SOURCES_CXX RELATIVE ${SUPERTUX_SOURCE_DIR} src/main.cpp src/*/*.cpp src/supertux/menu/*.cpp src/video/sdl/*.cpp external/tinygettext/*.cpp)
 135
 136 IF(HAVE_OPENGL)
 137   FILE(GLOB SUPERTUX_OPENGL_SOURCES RELATIVE ${SUPERTUX_SOURCE_DIR} src/video/gl/*.cpp)
 138   SET(SUPERTUX_SOURCES_CXX ${SUPERTUX_SOURCES_CXX} ${SUPERTUX_OPENGL_SOURCES})
 139 ENDIF(HAVE_OPENGL)
 140
 141 ## Precompile "a few" headers in GCC
 142 OPTION(PRECOMPILE_HEADERS "Precompile headers (experimental)" OFF)
 143 IF(PRECOMPILE_HEADERS)
 144   FILE(GLOB PRECOMPILED_HEADERS RELATIVE ${SUPERTUX_SOURCE_DIR} src/badguy/badguy.hpp
 145            src/scripting/wrapper.hpp src/video/*.hpp src/math/*.hpp)
 146   FILE(WRITE ${SUPERTUX_BINARY_DIR}/precompile.hh "// Precompiled headers\n")
 147   FILE(APPEND ${SUPERTUX_BINARY_DIR}/precompile.hh "#ifndef __SUPERTUX_PRECOMPILED_HEADER\n")
 148   FILE(APPEND ${SUPERTUX_BINARY_DIR}/precompile.hh "#define __SUPERTUX_PRECOMPILED_HEADER\n")
 149   FOREACH(PRECOMPILED_HEADER ${PRECOMPILED_HEADERS})
 150     FILE(RELATIVE_PATH PRECOMPILED_HEADER ${SUPERTUX_SOURCE_DIR}/src "${SUPERTUX_SOURCE_DIR}/${PRECOMPILED_HEADER}")
 151     FILE(APPEND ${SUPERTUX_BINARY_DIR}/precompile.hh "#include \"${PRECOMPILED_HEADER}\"\n")
 152   ENDFOREACH(PRECOMPILED_HEADER)
 153   FILE(APPEND ${SUPERTUX_BINARY_DIR}/precompile.hh "#endif /*__SUPERTUX_PRECOMPILED_HEADER*/\n")
 154   ADD_CUSTOM_COMMAND(
 155     OUTPUT ${SUPERTUX_BINARY_DIR}/precompile.hh.gch
 156     COMMAND ${CMAKE_CXX_COMPILER} -x "c++-header" $(CXX_FLAGS) ${SUPERTUX_BINARY_DIR}/precompile.hh
 157     DEPENDS ${PRECOMPILED_HEADERS}
 158     COMMENT "Building precompiled header..."
 159   )
 160   ## Make certain it is built
 161   SET(SUPERTUX_SOURCES_CXX ${SUPERTUX_BINARY_DIR}/precompile.hh.gch ${SUPERTUX_SOURCES_CXX})
 162   SET(CMAKE_CXX_FLAGS "-include ${SUPERTUX_BINARY_DIR}/precompile.hh" ${CMAKE_CXX_FLAGS})
 163 ELSE(PRECOMPILE_HEADERS)
 164   IF(EXISTS ${SUPERTUX_BINARY_DIR}/precompile.hh)
 165     FILE(REMOVE ${SUPERTUX_BINARY_DIR}/precompile.hh)
 166   ENDIF(EXISTS ${SUPERTUX_BINARY_DIR}/precompile.hh)
 167   IF(EXISTS ${SUPERTUX_BINARY_DIR}/precompile.hh.gch)
 168     FILE(REMOVE ${SUPERTUX_BINARY_DIR}/precompile.hh.gch)
 169   ENDIF(EXISTS ${SUPERTUX_BINARY_DIR}/precompile.hh.gch)
 170 ENDIF(PRECOMPILE_HEADERS)
 171
 172
 173 ## Debug options
 174
 175 OPTION(WERROR "Stop on first compiler warning" OFF)
 176 OPTION(WARNINGS "Enable long list of warnings for compiler to check" ON)
 177 IF(CMAKE_COMPILER_IS_GNUCC)
 178   ADD_DEFINITIONS(-Wall -Wextra -funit-at-a-time)
 179   SET(CMAKE_CXX_FLAGS_DEBUG "-O0 -g")
 180   SET(CMAKE_C_FLAGS_DEBUG "-O0 -g")
 181   SET(CMAKE_CXX_FLAGS_PROFILE "-pg")
 182   SET(CMAKE_C_FLAGS_PROFILE "-pg")
 183   SET(CMAKE_LD_FLAGS_PROFILE "-pg")
 184   IF(WERROR)
 185     ADD_DEFINITIONS(-Werror)
 186   ELSE(WERROR)
 187     REMOVE_DEFINITIONS(-Werror)
 188   ENDIF(WERROR)
 189   IF(WARNINGS)
 190     SET(CMAKE_C_FLAGS "-fdiagnostics-show-option -pedantic -Wno-long-long -Wcast-align -Wdisabled-optimization -Winit-self -Winvalid-pch -Wlogical-op -Wmissing-include-dirs -Wmissing-noreturn -Wpacked -Wredundant-decls -Wstack-protector")
 191     SET(CMAKE_CXX_FLAGS "-fdiagnostics-show-option -pedantic -Wno-long-long -Weffc++ -Wabi -Wctor-dtor-privacy -Wstrict-null-sentinel -Wcast-align -Wdisabled-optimization -Winit-self -Winvalid-pch -Wlogical-op -Wmissing-include-dirs -Wmissing-noreturn -Wpacked -Wredundant-decls -Wstack-protector")
 192     # -ansi fails in MinGW
 193     # still left:  -Wold-style-cast -Wpadded -Wconversion -Wundef -Wsign-conversion -Wshadow -Winline -Wunsafe-loop-optimizations -Wfloat-equal -Wswitch-default -Wswitch-enum -Wcast-qual -Wsign-promo -Woverloaded-virtual -Wmissing-format-attribute -Wstrict-overflow=5 -Wformat=2
 194   ENDIF(WARNINGS)
 195 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 196
 197 ## Add in squirrel debug stuff
 198
 199 OPTION(ENABLE_SQDBG "Build squirrel script interpreter with debugging options" OFF)
 200 IF(ENABLE_SQDBG)
 201   include_directories (${SUPERTUX_SOURCE_DIR}/external/squirrel/)
 202   FILE(GLOB SQDBG_SOURCES RELATIVE ${SUPERTUX_SOURCE_DIR} external/squirrel/sqdbg/*.cpp)
 203   SET(SUPERTUX_SOURCES_CXX ${SQDBG_SOURCES} ${SUPERTUX_SOURCES_CXX})
 204 ENDIF(ENABLE_SQDBG)
 205
 206 ## Build miniswig and generate miniswig wrapper
 207
 208 OPTION(GENERATE_WRAPPER "Build miniswig and generate the wrapper" ${DEBUG})
 209 IF(GENERATE_WRAPPER)
 210   ADD_SUBDIRECTORY(tools/miniswig)
 211   ADD_CUSTOM_COMMAND(
 212     OUTPUT ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.cpp ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.hpp
 213     COMMAND cd ${SUPERTUX_SOURCE_DIR} && ${CMAKE_CXX_COMPILER}
 214     ARGS -x "c++" -E -CC -DSCRIPTING_API src/scripting/wrapper.interface.hpp -o ${SUPERTUX_BINARY_DIR}/miniswig.tmp -I${SUPERTUX_SOURCE_DIR}/src
 215     COMMAND tools/miniswig/miniswig
 216     ARGS --input miniswig.tmp --output-cpp ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.cpp --output-hpp ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.hpp --module supertux --select-namespace Scripting
 217     DEPENDS tools/miniswig/miniswig
 218     IMPLICIT_DEPENDS CXX ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.interface.hpp
 219   )
 220 ENDIF(GENERATE_WRAPPER)
 221
 222 IF(NOT EXISTS ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.cpp)
 223   SET(SUPERTUX_SOURCES_CXX ${SUPERTUX_SOURCES_CXX} ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.cpp)
 224 ENDIF(NOT EXISTS ${SUPERTUX_SOURCE_DIR}/src/scripting/wrapper.cpp)
 225
 226 ## If xgettext is available, generate messages.pot for sources
 227
 228 OPTION(GENERATE_MESSAGESPOT "Generate messages.pot files" ${DEBUG})
 229 IF(GENERATE_MESSAGESPOT)
 230   MARK_AS_ADVANCED(
 231     XGETTEXT_EXECUTABLE
 232   )
 233   FIND_PROGRAM(XGETTEXT_EXECUTABLE xgettext)
 234   IF(NOT XGETTEXT_EXECUTABLE)
 235     MESSAGE(STATUS "Warning: xgettext not found - will not update messages.pot")
 236   ELSE(NOT XGETTEXT_EXECUTABLE)
 237     MESSAGE(STATUS "Found xgettext: ${XGETTEXT_EXECUTABLE}")
 238
 239     SET(MESSAGES_POT_FILE ${SUPERTUX_SOURCE_DIR}/data/locale/messages.pot)
 240     ADD_CUSTOM_COMMAND(
 241       OUTPUT ${MESSAGES_POT_FILE}
 242       COMMAND ${XGETTEXT_EXECUTABLE}
 243       ARGS --keyword=_ --language=C++ --output=${MESSAGES_POT_FILE} ${SUPERTUX_SOURCES_CXX}
 244       DEPENDS ${SUPERTUX_SOURCES_CXX}
 245       WORKING_DIRECTORY ${SUPERTUX_SOURCE_DIR}
 246       COMMENT "Generating POT file ${MESSAGES_POT_FILE}"
 247     )
 248     LIST(APPEND MESSAGES_POT_FILES ${MESSAGES_POT_FILE})
 249
 250     FILE(GLOB SUPERTUX_LEVEL_DIRS RELATIVE ${SUPERTUX_SOURCE_DIR} data/levels/*)
 251     LIST(REMOVE_ITEM SUPERTUX_LEVEL_DIRS "data/levels/.svn")
 252     FOREACH(SUPERTUX_LEVEL_DIR ${SUPERTUX_LEVEL_DIRS})
 253       FILE(GLOB SUPERTUX_LEVELS RELATIVE ${SUPERTUX_SOURCE_DIR} ${SUPERTUX_LEVEL_DIR}/*.stl ${SUPERTUX_LEVEL_DIR}/*.stwm ${SUPERTUX_LEVEL_DIR}/*.txt)
 254
 255       ## Do not add target if SUPERTUX_LEVELS is empty. This is needed for cmake <=2.4
 256       IF(SUPERTUX_LEVELS)
 257       SET(MESSAGES_POT_FILE ${SUPERTUX_SOURCE_DIR}/${SUPERTUX_LEVEL_DIR}/messages.pot)
 258       ADD_CUSTOM_COMMAND(
 259         OUTPUT ${MESSAGES_POT_FILE}
 260         COMMAND ${XGETTEXT_EXECUTABLE}
 261         ARGS --keyword="_:1" --language=Lisp --force-po --sort-by-file "--output=${MESSAGES_POT_FILE}" ${SUPERTUX_LEVELS}
 262         DEPENDS ${SUPERTUX_LEVELS}
 263         WORKING_DIRECTORY ${SUPERTUX_SOURCE_DIR}
 264         COMMENT "Generating POT file ${MESSAGES_POT_FILE}"
 265       )
 266       LIST(APPEND MESSAGES_POT_FILES ${MESSAGES_POT_FILE})
 267       ENDIF(SUPERTUX_LEVELS)
 268
 269     ENDFOREACH(SUPERTUX_LEVEL_DIR)
 270
 271     ADD_CUSTOM_TARGET(
 272       supertux2-messages ALL
 273       DEPENDS ${MESSAGES_POT_FILES}
 274     )
 275
 276   ENDIF(NOT XGETTEXT_EXECUTABLE)
 277 ENDIF(GENERATE_MESSAGESPOT)
 278
 279 ## Some additional compiler switches
 280 IF(CMAKE_COMPILER_IS_GNUCC)
 281   ADD_DEFINITIONS(-fno-strict-aliasing)
 282 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 283
 284 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 285   ADD_DEFINITIONS(-DMACOSX)
 286 ENDIF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 287
 288
 289 ## On Windows, add an icon
 290
 291 IF(WIN32)
 292   SET(SUPERTUX_SOURCES_C ${SUPERTUX_SOURCES_C} ${SUPERTUX_SOURCE_DIR}/data/images/engine/icons/supertux.rc)
 293   IF(MINGW)
 294     ADD_CUSTOM_COMMAND(
 295     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/supertux_rc.o
 296     COMMAND windres.exe -I${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons -i${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.rc -o ${CMAKE_CURRENT_BINARY_DIR}/supertux_rc.o)
 297     SET(SUPERTUX_SOURCES_C ${SUPERTUX_SOURCES_C} ${CMAKE_CURRENT_BINARY_DIR}/supertux_rc.o)
 298   ELSE(MINGW)
 299     SET(SUPERTUX_EXE_SRCS ${SUPERTUX_EXE_SRCS} supertux.rc)
 300   ENDIF(MINGW)
 301 ENDIF(WIN32)
 302
 303 ## Add binreloc.c if enabled
 304 IF(ENABLE_BINRELOC)
 305   SET(SUPERTUX_SOURCES_C ${SUPERTUX_SOURCES_C} ${SUPERTUX_SOURCE_DIR}/external/binreloc/binreloc.c)
 306 ENDIF(ENABLE_BINRELOC)
 307
 308
 309 ## Generate supertux executable in the right place
 310
 311 SET(EXECUTABLE_OUTPUT_PATH ${SUPERTUX_SOURCE_DIR})
 312
 313 ## Add target for supertux binary
 314
 315 ADD_EXECUTABLE(supertux2 ${SUPERTUX_SOURCES_C} ${SUPERTUX_SOURCES_CXX})
 316
 317 ## Link supertux binary with squirrel and other libraries
 318
 319 TARGET_LINK_LIBRARIES(supertux2 squirrel)
 320 TARGET_LINK_LIBRARIES(supertux2 ${SDL_LIBRARY})
 321 TARGET_LINK_LIBRARIES(supertux2 ${SDLIMAGE_LIBRARY})
 322 TARGET_LINK_LIBRARIES(supertux2 ${OPENAL_LIBRARY})
 323 TARGET_LINK_LIBRARIES(supertux2 ${OGGVORBIS_LIBRARIES})
 324 TARGET_LINK_LIBRARIES(supertux2 ${PHYSFS_LIBRARY})
 325 IF(HAVE_OPENGL)
 326     TARGET_LINK_LIBRARIES(supertux2 ${OPENGL_LIBRARY})
 327 ENDIF(HAVE_OPENGL)
 328 IF(HAVE_LIBCURL)
 329   TARGET_LINK_LIBRARIES(supertux2 ${CURL_LIBRARY})
 330 ENDIF(HAVE_LIBCURL)
 331
 332 ## Install stuff
 333
 334 IF(WIN32 AND NOT UNIX)
 335
 336   SET(INSTALL_SUBDIR_BIN ".")
 337   SET(INSTALL_SUBDIR_SHARE "data/")
 338   SET(INSTALL_SUBDIR_DOC ".")
 339
 340   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/SDL.dll
 341                 ${SUPERTUX_SOURCE_DIR}/SDL_image.dll
 342                 ${SUPERTUX_SOURCE_DIR}/iconv.dll
 343                 ${SUPERTUX_SOURCE_DIR}/libogg-0.dll
 344                 ${SUPERTUX_SOURCE_DIR}/libphysfs-1-0-0.dll
 345                 ${SUPERTUX_SOURCE_DIR}/OpenAl32.dll
 346                 ${SUPERTUX_SOURCE_DIR}/wrap_oal.dll
 347                 ${SUPERTUX_SOURCE_DIR}/libcurl-4.dll DESTINATION ${INSTALL_SUBDIR_BIN})
 348
 349   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/data/images/engine/icons/supertux.png ${SUPERTUX_SOURCE_DIR}/data/images/engine/icons/supertux.ico DESTINATION ".")
 350
 351 ELSE(WIN32 AND NOT UNIX)
 352 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 353
 354   SET(INSTALL_SUBDIR_BIN "SuperTux.app/Contents/MacOS/")
 355   SET(INSTALL_SUBDIR_SHARE "SuperTux.app/Contents/Resources/data/")
 356   SET(INSTALL_SUBDIR_DOC "SuperTux.app/Contents/Resources/")
 357
 358   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/tools/darwin/info.plist DESTINATION "SuperTux.app/Contents/")
 359
 360   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/data/images/engine/icons/supertux.png ${SUPERTUX_SOURCE_DIR}/data/images/engine/icons/supertux.icns DESTINATION "SuperTux.app/Contents/Resources/")
 361
 362 ELSE(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 363
 364   SET(INSTALL_SUBDIR_BIN "games/")
 365   SET(INSTALL_SUBDIR_SHARE "share/games/supertux2/")
 366   SET(INSTALL_SUBDIR_DOC "share/doc/supertux2/")
 367
 368   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/supertux2.desktop DESTINATION "share/applications")
 369
 370   INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/data/images/engine/icons/supertux.png ${SUPERTUX_SOURCE_DIR}/data/images/engine/icons/supertux.xpm DESTINATION "share/pixmaps/")
 371
 372 ENDIF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 373 ENDIF(WIN32 AND NOT UNIX)
 374
 375 INSTALL(TARGETS supertux2 DESTINATION ${INSTALL_SUBDIR_BIN})
 376
 377 INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/INSTALL ${SUPERTUX_SOURCE_DIR}/README ${SUPERTUX_SOURCE_DIR}/COPYING ${SUPERTUX_SOURCE_DIR}/WHATSNEW.txt DESTINATION ${INSTALL_SUBDIR_DOC})
 378
 379 INSTALL(FILES ${SUPERTUX_SOURCE_DIR}/data/credits.txt DESTINATION ${INSTALL_SUBDIR_SHARE})
 380
 381 INSTALL(DIRECTORY data/images
 382                   data/fonts
 383                   data/levels
 384                   data/music
 385                   data/scripts
 386                   data/speech
 387                   data/sounds
 388                   data/locale
 389                                DESTINATION ${INSTALL_SUBDIR_SHARE} PATTERN ".svn" EXCLUDE)
 390
 391
 392 ## CPack/Installation-specific stuff
 393
 394 INCLUDE(InstallRequiredSystemLibraries)
 395 SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Jump'n'Run Game featuring Tux")
 396 SET(CPACK_PACKAGE_VENDOR "SuperTux Devel Team")
 397 SET(CPACK_PACKAGE_CONTACT "SuperTux Devel Team <supertux-devel@lists.lethargik.org>")
 398 SET(CPACK_DEBIAN_PACKAGE_NAME "supertux2")
 399 SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6 (>= 2.5), libgcc1 (>= 1:4.1), libgl1-mesa-glx | libgl1, libogg0 (>= 1.1.3), libopenal0a, libphysfs-1.0-0, libsdl-image1.2 (>= 1.2.5), libsdl1.2debian (>= 1.2.10-1), libstdc++6 (>= 4.1.2), libvorbis0a (>= 1.1.2), libvorbisfile3 (>= 1.1.2), libcurl3 (>= 7.16)")
 400 SET(CPACK_DEBIAN_PACKAGE_DESCRIPTION "Classic 2D jump 'n run sidescroller with Tux\n SuperTux is a classic 2D jump 'n run sidescroller game in a similar\n style like the original SuperMario games. This release of SuperTux\n features 9 enemies, 26 playable levels, software and OpenGL rendering\n modes, configurable joystick and keyboard input, new music and\n completely redone graphics.\n .\n This is a development snapshot of SuperTux. It may suffer from\n critical bugs and has not been fully tested. \n .\n Homepage: http://supertux.lethargik.org/")
 401 SET(CPACK_DEBIAN_PACKAGE_SECTION "games")
 402 SET(CPACK_RPM_PACKAGE_NAME "supertux2")
 403 SET(CPACK_RPM_PACKAGE_DESCRIPTION "Classic 2D jump 'n run sidescroller with Tux\n SuperTux is a classic 2D jump 'n run sidescroller game in a similar\n style like the original SuperMario games. This release of SuperTux\n features 9 enemies, 26 playable levels, software and OpenGL rendering\n modes, configurable joystick and keyboard input, new music and\n completely redone graphics.\n .\n This is a development snapshot of SuperTux. It may suffer from\n critical bugs and has not been fully tested. \n .\n Homepage: http://supertux.lethargik.org/")
 404 SET(CPACK_RPM_PACKAGE_LICENSE "GNU General Public License (GPL)")
 405 SET(CPACK_RPM_PACKAGE_GROUP "Amusements/Games/Action/Arcade")
 406 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 407   # The OS X PackageMaker doesn't seem to like files with no extension
 408 ELSE(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 409   SET(CPACK_PACKAGE_DESCRIPTION_FILE "${SUPERTUX_SOURCE_DIR}/README")
 410   SET(CPACK_RESOURCE_FILE_LICENSE "${SUPERTUX_SOURCE_DIR}/COPYING")
 411 ENDIF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 412 SET(CPACK_PACKAGE_VERSION_MAJOR "0")
 413 SET(CPACK_PACKAGE_VERSION_MINOR "3")
 414 SET(CPACK_PACKAGE_VERSION_PATCH "2-SVN")
 415 SET(CPACK_PACKAGE_INSTALL_DIRECTORY "SuperTux ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 416 SET(CPACK_PACKAGE_EXECUTABLES "..\\\\supertux2" "SuperTux ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 417 IF(WIN32 AND NOT UNIX)
 418   SET(CPACK_NSIS_INSTALLED_ICON_NAME "..\\\\supertux2")
 419   SET(CPACK_NSIS_DISPLAY_NAME "SuperTux ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 420 ELSE(WIN32 AND NOT UNIX)
 421 ENDIF(WIN32 AND NOT UNIX)
 422 INCLUDE(CPack)
 423
 424 # move some config clutter to the advanced section
 425 MARK_AS_ADVANCED(
 426         CMAKE_BACKWARDS_COMPATIBILITY
 427         CMAKE_BUILD_TYPE
 428         CMAKE_INSTALL_PREFIX
 429         EXECUTABLE_OUTPUT_PATH
 430         LIBRARY_OUTPUT_PATH
 431         CMAKE_OSX_ARCHITECTURES
 432         CMAKE_OSX_SYSROOT
 433 )
 434
 435 MARK_AS_ADVANCED(
 436         ENABLE_BINRELOC
 437         APPDATADIR
 438 )
 439
 440 MARK_AS_ADVANCED(
 441         SDLMAIN_LIBRARY
 442         SDL_INCLUDE_DIR
 443         SDL_LIBRARY
 444 )
 445
 446 MARK_AS_ADVANCED(
 447         SDLIMAGE_INCLUDE_DIR
 448         SDLIMAGE_LIBRARY
 449 )
 450
 451 MARK_AS_ADVANCED(
 452         OPENAL_INCLUDE_DIR
 453         OPENAL_LIBRARY
 454 )
 455
 456 MARK_AS_ADVANCED(
 457         OGG_LIBRARY
 458         VORBISENC_LIBRARY
 459         VORBISFILE_LIBRARY
 460         VORBIS_INCLUDE_DIR
 461         VORBIS_LIBRARY
 462 )
 463
 464 MARK_AS_ADVANCED(
 465         PHYSFS_INCLUDE_DIR
 466         PHYSFS_LIBRARY
 467 )