CMakeLists.txt

   1 #
   2 # SuperTux - root build script
   3 # Copyright (C) 2006 Christoph Sommer <christoph.sommer@2006.expires.deltadevelopment.de>
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  18 #
  19
  20
  21 #
  22 # INSTRUCTIONS:
  23 # -------------
  24 #
  25 # Create a directory build/ and change to it. Run
  26 #
  27 #   cmake ..
  28 #
  29 # This creates a set of Makefiles to build the project. Run
  30 #
  31 #   make
  32 #
  33
  34
  35 ## Project name to use as command prefix
  36
  37 PROJECT(SUPERTUX)
  38
  39
  40 ### CMake configuration
  41
  42 # allow building with CMake 2.6. Set compatibility options. Use some bundled modules as a fallback
  43 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
  44 IF(COMMAND cmake_policy)
  45         CMAKE_POLICY(SET CMP0003 NEW)
  46 ENDIF(COMMAND cmake_policy)
  47
  48 SET(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${CMAKE_CURRENT_SOURCE_DIR}/mk/cmake)
  49
  50 ## For autopackage
  51 OPTION(ENABLE_BINRELOC "Enable autopackage's BINRELOC features" OFF)
  52 SET(APPDATADIR "${CMAKE_INSTALL_PREFIX}/share/games/supertux2")
  53
  54 ## Check endianess
  55
  56 INCLUDE(TestBigEndian)
  57 TEST_BIG_ENDIAN(WORDS_BIGENDIAN)
  58
  59 ## Add lots of dependencies to compiler switches
  60
  61 SET(Boost_ADDITIONAL_VERSIONS "1.41" "1.41.0")
  62 FIND_PACKAGE(Boost REQUIRED)
  63 INCLUDE_DIRECTORIES(SYSTEM ${Boost_INCLUDE_DIR})
  64 LINK_DIRECTORIES(${Boost_LIBRARY_DIRS})
  65
  66 FIND_PACKAGE(SDL REQUIRED)
  67 INCLUDE_DIRECTORIES(${SDL_INCLUDE_DIR})
  68 SET(HAVE_SDL TRUE)
  69
  70 FIND_PACKAGE(SDL_image REQUIRED)
  71 INCLUDE_DIRECTORIES(${SDLIMAGE_INCLUDE_DIR})
  72
  73 OPTION(ENABLE_OPENGL "Enable OpenGL support" ON)
  74 IF(ENABLE_OPENGL)
  75   FIND_PACKAGE(OpenGL)
  76   IF(OPENGL_FOUND)
  77     INCLUDE_DIRECTORIES(${OPENGL_INCLUDE_DIR})
  78     SET(HAVE_OPENGL TRUE)
  79   ENDIF(OPENGL_FOUND)
  80
  81   FIND_PACKAGE(GLEW)
  82   IF(GLEW_FOUND)
  83     INCLUDE_DIRECTORIES(${GLEW_INCLUDE_DIR})
  84   ENDIF(GLEW_FOUND)
  85 ENDIF(ENABLE_OPENGL)
  86
  87 FIND_PACKAGE(OpenAL REQUIRED)
  88 INCLUDE_DIRECTORIES(${OPENAL_INCLUDE_DIR})
  89
  90 FIND_PACKAGE(OggVorbis REQUIRED)
  91 INCLUDE_DIRECTORIES(${OGGVORBIS_INCLUDE_DIR})
  92
  93 FIND_PACKAGE(PhysFS REQUIRED)
  94 INCLUDE_DIRECTORIES(${PHYSFS_INCLUDE_DIR})
  95
  96 FIND_PACKAGE(CURL)
  97 IF(CURL_FOUND)
  98   INCLUDE_DIRECTORIES(${CURL_INCLUDE_DIR})
  99   SET(HAVE_LIBCURL TRUE)
 100 ENDIF(CURL_FOUND)
 101
 102 #FIND_PACKAGE(ICONV REQUIRED)
 103 #INCLUDE_DIRECTORIES(${ICONV_INCLUDE_DIR})
 104 #LINK_LIBRARIES(${ICONV_LIBRARY})
 105
 106 ## Find revision of WC
 107 MARK_AS_ADVANCED(SVNVERSION_EXECUTABLE)
 108 FIND_PROGRAM(SVNVERSION_EXECUTABLE svnversion)
 109 IF(SVNVERSION_EXECUTABLE)
 110   EXECUTE_PROCESS(COMMAND svnversion -n ${CMAKE_CURRENT_SOURCE_DIR}
 111                   OUTPUT_VARIABLE SUPERTUX_WC_REVISION)
 112   SET(REVISION " r${SUPERTUX_WC_REVISION}")
 113 ENDIF(SVNVERSION_EXECUTABLE)
 114
 115 ## Check platform-dependent build options
 116
 117 INCLUDE(ConfigureChecks)
 118
 119 ## Create config.h and version.h
 120
 121 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h )
 122 configure_file(version.h.cmake ${CMAKE_BINARY_DIR}/version.h )
 123 include_directories (${CMAKE_BINARY_DIR}/)
 124
 125 ## Also execute instructions in src/squirrel/CMakeLists.txt
 126
 127 ADD_SUBDIRECTORY(external/squirrel)
 128
 129 ## Add squirrel lib dir to search path
 130
 131 LINK_DIRECTORIES(external/squirrel)
 132
 133 ## Some additional include paths
 134
 135 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/src/)
 136 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/external/squirrel/include/)
 137 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/external/tinygettext/)
 138 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/external/findlocale/)
 139 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/external/obstack/)
 140 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/external/binreloc/)
 141
 142 ## Build list of sources for supertux binary
 143
 144 FILE(GLOB SUPERTUX_SOURCES_C RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} external/obstack/*.c external/findlocale/findlocale.c)
 145
 146 FILE(GLOB SUPERTUX_SOURCES_CXX RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} src/main.cpp src/*/*.cpp src/supertux/menu/*.cpp src/video/sdl/*.cpp)
 147
 148 FILE(GLOB TINYGETTEXT_SOURCES_CXX RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} external/tinygettext/tinygettext/*.cpp)
 149 SET_SOURCE_FILES_PROPERTIES(${TINYGETTEXT_SOURCES_CXX} PROPERTIES COMPILE_DEFINITIONS HAVE_SDL)
 150
 151 IF(HAVE_OPENGL)
 152   FILE(GLOB SUPERTUX_OPENGL_SOURCES RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} src/video/gl/*.cpp)
 153   SET(SUPERTUX_SOURCES_CXX ${SUPERTUX_SOURCES_CXX} ${SUPERTUX_OPENGL_SOURCES})
 154 ENDIF(HAVE_OPENGL)
 155
 156 ## Build miniswig and generate miniswig wrapper
 157
 158 OPTION(GENERATE_WRAPPER "Build miniswig and generate the wrapper" ${DEBUG})
 159 IF(GENERATE_WRAPPER)
 160   ADD_SUBDIRECTORY(tools/miniswig)
 161   ADD_CUSTOM_COMMAND(
 162     OUTPUT ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.cpp ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.hpp
 163     COMMAND cd ${CMAKE_CURRENT_SOURCE_DIR} && ${CMAKE_CXX_COMPILER}
 164     ARGS -x "c++" -E -CC -DSCRIPTING_API src/scripting/wrapper.interface.hpp -o ${CMAKE_CURRENT_BINARY_DIR}/miniswig.tmp -I${CMAKE_CURRENT_SOURCE_DIR}/src
 165     COMMAND tools/miniswig/miniswig
 166     ARGS --input miniswig.tmp --output-cpp ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.cpp --output-hpp ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.hpp --module supertux --select-namespace scripting
 167     DEPENDS tools/miniswig/miniswig
 168     IMPLICIT_DEPENDS CXX ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.interface.hpp
 169   )
 170 ENDIF(GENERATE_WRAPPER)
 171
 172 IF(NOT EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.cpp)
 173   SET(SUPERTUX_SOURCES_CXX ${SUPERTUX_SOURCES_CXX} ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.cpp)
 174 ENDIF(NOT EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.cpp)
 175
 176 ## Compile everything at once (roughly equivalent to cat *.cpp | gcc)
 177
 178 OPTION(COMPILE_AMALGATION "Compile all the files together at once (experimental)" OFF)
 179 IF(COMPILE_AMALGATION)
 180   FILE(WRITE ${CMAKE_CURRENT_BINARY_DIR}/amalgation.cpp "// Includes all source files of the project\n")
 181   FOREACH(ST_FILE ${SUPERTUX_SOURCES_CXX})
 182     FILE(RELATIVE_PATH CXX_FILE ${CMAKE_CURRENT_SOURCE_DIR}/src "${CMAKE_CURRENT_SOURCE_DIR}/${ST_FILE}")
 183     FILE(APPEND ${CMAKE_CURRENT_BINARY_DIR}/amalgation.cpp "#include \"${CXX_FILE}\"\n")
 184   ENDFOREACH(ST_FILE)
 185   ## Build instead of CXX sources
 186   SET(SUPERTUX_SOURCES_CXX ${CMAKE_CURRENT_BINARY_DIR}/amalgation.cpp)
 187 ELSE(COMPILE_AMALGATION)
 188   IF(EXISTS ${CMAKE_CURRENT_BINARY_DIR}/amalgation.cpp)
 189     FILE(REMOVE ${CMAKE_CURRENT_BINARY_DIR}/amalgation.cpp)
 190   ENDIF(EXISTS ${CMAKE_CURRENT_BINARY_DIR}/amalgation.cpp)
 191 ENDIF(COMPILE_AMALGATION)
 192
 193 ## Debug options
 194
 195 OPTION(WERROR "Stop on first compiler warning" OFF)
 196 OPTION(WARNINGS "Enable long list of warnings for compiler to check" ${DEBUG})
 197 IF(CMAKE_COMPILER_IS_GNUCC)
 198   SET(CMAKE_CXX_FLAGS_DEBUG "-O0 -g" CACHE STRING "Debug flags")
 199   SET(CMAKE_C_FLAGS_DEBUG "-O0 -g" CACHE STRING "Debug flags")
 200   SET(CMAKE_CXX_FLAGS_PROFILE "-pg" CACHE STRING "Profile flags")
 201   SET(CMAKE_C_FLAGS_PROFILE "-pg" CACHE STRING "Profile flags")
 202   SET(CMAKE_LD_FLAGS_PROFILE "-lgmon" CACHE STRING "Profile flags")
 203   ADD_DEFINITIONS(-Wall -Wextra -funit-at-a-time)
 204   IF(WERROR)
 205     ADD_DEFINITIONS(-Werror)
 206   ELSE(WERROR)
 207     REMOVE_DEFINITIONS(-Werror)
 208   ENDIF(WERROR)
 209   IF(WARNINGS)
 210     ADD_DEFINITIONS(-fdiagnostics-show-option -pedantic -Wno-long-long -Wcast-align -Wdisabled-optimization -Winit-self -Winvalid-pch -Wlogical-op -Wmissing-include-dirs -Wmissing-noreturn -Wpacked -Wredundant-decls -Wstack-protector -Wconversion -Wundef -Wsign-conversion -Wshadow -Winline -Wunsafe-loop-optimizations -Wfloat-equal -Wswitch-default -Wswitch-enum -Wcast-qual -Wsign-promo -Woverloaded-virtual -Wmissing-format-attribute -Wstrict-overflow=5 -Wformat=2-Weffc++ -Wabi -Wctor-dtor-privacy -Wstrict-null-sentinel)
 211     # -ansi fails in MinGW
 212     # still left:  -Wold-style-cast -Wpadded
 213   ENDIF(WARNINGS)
 214 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 215
 216 ## If xgettext is available, generate messages.pot for sources
 217
 218 OPTION(GENERATE_MESSAGESPOT "Generate messages.pot files" ${DEBUG})
 219 IF(GENERATE_MESSAGESPOT)
 220   MARK_AS_ADVANCED(
 221     XGETTEXT_EXECUTABLE
 222   )
 223   FIND_PROGRAM(XGETTEXT_EXECUTABLE xgettext)
 224   IF(NOT XGETTEXT_EXECUTABLE)
 225     MESSAGE(STATUS "Warning: xgettext not found - will not update messages.pot")
 226   ELSE(NOT XGETTEXT_EXECUTABLE)
 227     MESSAGE(STATUS "Found xgettext: ${XGETTEXT_EXECUTABLE}")
 228
 229     SET(MESSAGES_POT_FILE ${CMAKE_CURRENT_SOURCE_DIR}/data/locale/messages.pot)
 230     ADD_CUSTOM_COMMAND(
 231       OUTPUT ${MESSAGES_POT_FILE}
 232       COMMAND ${XGETTEXT_EXECUTABLE}
 233       ARGS --keyword=_ --language=C++ --output=${MESSAGES_POT_FILE} ${SUPERTUX_SOURCES_CXX}
 234       DEPENDS ${SUPERTUX_SOURCES_CXX}
 235       WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 236       COMMENT "Generating POT file ${MESSAGES_POT_FILE}"
 237     )
 238     LIST(APPEND MESSAGES_POT_FILES ${MESSAGES_POT_FILE})
 239
 240     FILE(GLOB SUPERTUX_LEVEL_DIRS RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} data/levels/*)
 241     LIST(REMOVE_ITEM SUPERTUX_LEVEL_DIRS "data/levels/.svn")
 242     FOREACH(SUPERTUX_LEVEL_DIR ${SUPERTUX_LEVEL_DIRS})
 243       FILE(GLOB SUPERTUX_LEVELS RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} ${SUPERTUX_LEVEL_DIR}/*.stl ${SUPERTUX_LEVEL_DIR}/*.stwm ${SUPERTUX_LEVEL_DIR}/*.txt)
 244
 245       ## Do not add target if SUPERTUX_LEVELS is empty. This is needed for cmake <=2.4
 246       IF(SUPERTUX_LEVELS)
 247       SET(MESSAGES_POT_FILE ${CMAKE_CURRENT_SOURCE_DIR}/${SUPERTUX_LEVEL_DIR}/messages.pot)
 248       ADD_CUSTOM_COMMAND(
 249         OUTPUT ${MESSAGES_POT_FILE}
 250         COMMAND ${XGETTEXT_EXECUTABLE}
 251         ARGS --keyword="_:1" --language=Lisp --force-po --sort-by-file "--output=${MESSAGES_POT_FILE}" ${SUPERTUX_LEVELS}
 252         DEPENDS ${SUPERTUX_LEVELS}
 253         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 254         COMMENT "Generating POT file ${MESSAGES_POT_FILE}"
 255       )
 256       LIST(APPEND MESSAGES_POT_FILES ${MESSAGES_POT_FILE})
 257       ENDIF(SUPERTUX_LEVELS)
 258
 259     ENDFOREACH(SUPERTUX_LEVEL_DIR)
 260
 261     ADD_CUSTOM_TARGET(
 262       supertux2-messages ALL
 263       DEPENDS ${MESSAGES_POT_FILES}
 264     )
 265
 266   ENDIF(NOT XGETTEXT_EXECUTABLE)
 267 ENDIF(GENERATE_MESSAGESPOT)
 268
 269 ## Some additional compiler switches
 270 IF(CMAKE_COMPILER_IS_GNUCC)
 271   ADD_DEFINITIONS(-fno-strict-aliasing)
 272 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 273
 274 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 275   ADD_DEFINITIONS(-DMACOSX)
 276 ENDIF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 277
 278
 279 ## On Windows, add an icon
 280
 281 IF(WIN32)
 282   SET(SUPERTUX_SOURCES_C ${SUPERTUX_SOURCES_C} ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.rc)
 283   IF(MINGW)
 284     ADD_CUSTOM_COMMAND(
 285     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/supertux_rc.o
 286     COMMAND windres.exe -I${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons -i${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.rc -o ${CMAKE_CURRENT_BINARY_DIR}/supertux_rc.o)
 287     SET(SUPERTUX_SOURCES_C ${SUPERTUX_SOURCES_C} ${CMAKE_CURRENT_BINARY_DIR}/supertux_rc.o)
 288   ELSE(MINGW)
 289     SET(SUPERTUX_EXE_SRCS ${SUPERTUX_EXE_SRCS} supertux.rc)
 290   ENDIF(MINGW)
 291 ENDIF(WIN32)
 292
 293 ## Add binreloc.c if enabled
 294 IF(ENABLE_BINRELOC)
 295   SET(SUPERTUX_SOURCES_C ${SUPERTUX_SOURCES_C} ${CMAKE_CURRENT_SOURCE_DIR}/external/binreloc/binreloc.c)
 296 ENDIF(ENABLE_BINRELOC)
 297
 298
 299 ## Generate supertux executable in the right place
 300
 301 SET(EXECUTABLE_OUTPUT_PATH ${CMAKE_CURRENT_SOURCE_DIR})
 302
 303 ## Add target for supertux binary
 304
 305 ADD_EXECUTABLE(supertux2 ${SUPERTUX_SOURCES_C} ${SUPERTUX_SOURCES_CXX} ${TINYGETTEXT_SOURCES_CXX})
 306
 307 ## Link supertux binary with squirrel and other libraries
 308
 309 TARGET_LINK_LIBRARIES(supertux2 squirrel)
 310 TARGET_LINK_LIBRARIES(supertux2 ${SDL_LIBRARY})
 311 TARGET_LINK_LIBRARIES(supertux2 ${SDLIMAGE_LIBRARY})
 312 TARGET_LINK_LIBRARIES(supertux2 ${OPENAL_LIBRARY})
 313 TARGET_LINK_LIBRARIES(supertux2 ${OGGVORBIS_LIBRARIES})
 314 TARGET_LINK_LIBRARIES(supertux2 ${PHYSFS_LIBRARY})
 315 IF(HAVE_OPENGL)
 316     TARGET_LINK_LIBRARIES(supertux2 ${OPENGL_LIBRARY})
 317     TARGET_LINK_LIBRARIES(supertux2 ${GLEW_LIBRARY})
 318 ENDIF(HAVE_OPENGL)
 319 IF(HAVE_LIBCURL)
 320   TARGET_LINK_LIBRARIES(supertux2 ${CURL_LIBRARY})
 321 ENDIF(HAVE_LIBCURL)
 322
 323 ## Install stuff
 324
 325 IF(WIN32 AND NOT UNIX)
 326
 327   SET(INSTALL_SUBDIR_BIN "." CACHE STRING "Installation subdir for binaries")
 328   SET(INSTALL_SUBDIR_SHARE "data" CACHE STRING "Installation subdir for data")
 329   SET(INSTALL_SUBDIR_DOC "." CACHE STRING "Installation subdir for docs")
 330
 331   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/SDL.dll
 332                 ${CMAKE_CURRENT_SOURCE_DIR}/SDL_image.dll
 333                 ${CMAKE_CURRENT_SOURCE_DIR}/iconv.dll
 334                 ${CMAKE_CURRENT_SOURCE_DIR}/libogg-0.dll
 335                 ${CMAKE_CURRENT_SOURCE_DIR}/libphysfs-1-0-0.dll
 336                 ${CMAKE_CURRENT_SOURCE_DIR}/OpenAl32.dll
 337                 ${CMAKE_CURRENT_SOURCE_DIR}/wrap_oal.dll
 338                 ${CMAKE_CURRENT_SOURCE_DIR}/libcurl-4.dll DESTINATION ${INSTALL_SUBDIR_BIN})
 339
 340   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.png ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.ico DESTINATION ".")
 341
 342 ELSE(WIN32 AND NOT UNIX)
 343 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 344
 345   SET(INSTALL_SUBDIR_BIN "SuperTux.app/Contents/MacOS" CACHE STRING "Installation subdir for binaries")
 346   SET(INSTALL_SUBDIR_SHARE "SuperTux.app/Contents/Resources/data" CACHE STRING "Installation subdir for data")
 347   SET(INSTALL_SUBDIR_DOC "SuperTux.app/Contents/Resources" CACHE STRING "Installation subdir for docs")
 348
 349   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/tools/darwin/info.plist DESTINATION "SuperTux.app/Contents/")
 350
 351   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.png ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.icns DESTINATION "SuperTux.app/Contents/Resources/")
 352
 353 ELSE(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 354
 355   SET(INSTALL_SUBDIR_BIN "games" CACHE STRING "Installation subdir for binaries")
 356   SET(INSTALL_SUBDIR_SHARE "share/games/supertux2" CACHE STRING "Installation subdir for data")
 357   SET(INSTALL_SUBDIR_DOC "share/doc/supertux2" CACHE STRING "Installation subdir for docs")
 358
 359   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/supertux2.desktop DESTINATION "share/applications")
 360
 361   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.png ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.xpm DESTINATION "share/pixmaps/")
 362
 363 ENDIF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 364 ENDIF(WIN32 AND NOT UNIX)
 365
 366 INSTALL(TARGETS supertux2 DESTINATION ${INSTALL_SUBDIR_BIN})
 367
 368 INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/INSTALL ${CMAKE_CURRENT_SOURCE_DIR}/README ${CMAKE_CURRENT_SOURCE_DIR}/COPYING ${CMAKE_CURRENT_SOURCE_DIR}/WHATSNEW.txt DESTINATION ${INSTALL_SUBDIR_DOC})
 369
 370 INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/data/credits.txt DESTINATION ${INSTALL_SUBDIR_SHARE})
 371
 372 INSTALL(DIRECTORY data/images
 373                   data/fonts
 374                   data/levels
 375                   data/music
 376                   data/scripts
 377                   data/speech
 378                   data/sounds
 379                   data/locale
 380                                DESTINATION ${INSTALL_SUBDIR_SHARE} PATTERN ".svn" EXCLUDE)
 381
 382
 383 ## CPack/Installation-specific stuff
 384
 385 INCLUDE(InstallRequiredSystemLibraries)
 386 SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Jump'n'Run Game featuring Tux")
 387 SET(CPACK_PACKAGE_VENDOR "SuperTux Devel Team")
 388 SET(CPACK_PACKAGE_CONTACT "SuperTux Devel Team <supertux-devel@lists.lethargik.org>")
 389 SET(CPACK_DEBIAN_PACKAGE_NAME "supertux2")
 390 SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6 (>= 2.5), libgcc1 (>= 1:4.1), libgl1-mesa-glx | libgl1, libogg0 (>= 1.1.3), libopenal0a, libphysfs-1.0-0, libsdl-image1.2 (>= 1.2.5), libsdl1.2debian (>= 1.2.10-1), libstdc++6 (>= 4.1.2), libvorbis0a (>= 1.1.2), libvorbisfile3 (>= 1.1.2), libcurl3 (>= 7.16)")
 391 SET(CPACK_DEBIAN_PACKAGE_DESCRIPTION "Classic 2D jump 'n run sidescroller with Tux\n SuperTux is a classic 2D jump 'n run sidescroller game in a similar\n style like the original SuperMario games. This release of SuperTux\n features 9 enemies, 26 playable levels, software and OpenGL rendering\n modes, configurable joystick and keyboard input, new music and\n completely redone graphics.\n .\n This is a development snapshot of SuperTux. It may suffer from\n critical bugs and has not been fully tested. \n .\n Homepage: http://supertux.lethargik.org/")
 392 SET(CPACK_DEBIAN_PACKAGE_SECTION "games")
 393 SET(CPACK_RPM_PACKAGE_NAME "supertux2")
 394 SET(CPACK_RPM_PACKAGE_DESCRIPTION "Classic 2D jump 'n run sidescroller with Tux\n SuperTux is a classic 2D jump 'n run sidescroller game in a similar\n style like the original SuperMario games. This release of SuperTux\n features 9 enemies, 26 playable levels, software and OpenGL rendering\n modes, configurable joystick and keyboard input, new music and\n completely redone graphics.\n .\n This is a development snapshot of SuperTux. It may suffer from\n critical bugs and has not been fully tested. \n .\n Homepage: http://supertux.lethargik.org/")
 395 SET(CPACK_RPM_PACKAGE_LICENSE "GNU General Public License (GPL)")
 396 SET(CPACK_RPM_PACKAGE_GROUP "Amusements/Games/Action/Arcade")
 397 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 398   # The OS X PackageMaker doesn't seem to like files with no extension
 399 ELSE(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 400   SET(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README")
 401   SET(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/COPYING")
 402 ENDIF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 403 SET(CPACK_PACKAGE_VERSION_MAJOR "0")
 404 SET(CPACK_PACKAGE_VERSION_MINOR "3")
 405 SET(CPACK_PACKAGE_VERSION_PATCH "2-SVN")
 406 SET(CPACK_PACKAGE_INSTALL_DIRECTORY "SuperTux ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 407 SET(CPACK_PACKAGE_EXECUTABLES "..\\\\supertux2" "SuperTux ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 408 IF(WIN32 AND NOT UNIX)
 409   SET(CPACK_NSIS_INSTALLED_ICON_NAME "..\\\\supertux2")
 410   SET(CPACK_NSIS_DISPLAY_NAME "SuperTux ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 411 ELSE(WIN32 AND NOT UNIX)
 412 ENDIF(WIN32 AND NOT UNIX)
 413 INCLUDE(CPack)
 414
 415 # move some config clutter to the advanced section
 416 MARK_AS_ADVANCED(
 417   INSTALL_SUBDIR_BIN
 418   INSTALL_SUBDIR_SHARE
 419   INSTALL_SUBDIR_DOC
 420 )
 421
 422 MARK_AS_ADVANCED(
 423         CMAKE_BACKWARDS_COMPATIBILITY
 424         CMAKE_BUILD_TYPE
 425         CMAKE_INSTALL_PREFIX
 426         EXECUTABLE_OUTPUT_PATH
 427         LIBRARY_OUTPUT_PATH
 428         CMAKE_OSX_ARCHITECTURES
 429         CMAKE_OSX_SYSROOT
 430 )
 431
 432 MARK_AS_ADVANCED(
 433         ENABLE_BINRELOC
 434         APPDATADIR
 435 )
 436
 437 MARK_AS_ADVANCED(
 438         Boost_INCLUDE_DIR
 439         Boost_LIBRARIES
 440 )
 441
 442 MARK_AS_ADVANCED(
 443         SDLMAIN_LIBRARY
 444         SDL_INCLUDE_DIR
 445         SDL_LIBRARY
 446 )
 447
 448 MARK_AS_ADVANCED(
 449         SDLIMAGE_INCLUDE_DIR
 450         SDLIMAGE_LIBRARY
 451 )
 452
 453 MARK_AS_ADVANCED(
 454         OPENAL_INCLUDE_DIR
 455         OPENAL_LIBRARY
 456 )
 457
 458 MARK_AS_ADVANCED(
 459         OGG_LIBRARY
 460         VORBISENC_LIBRARY
 461         VORBISFILE_LIBRARY
 462         VORBIS_INCLUDE_DIR
 463         VORBIS_LIBRARY
 464 )
 465
 466 MARK_AS_ADVANCED(
 467         PHYSFS_INCLUDE_DIR
 468         PHYSFS_LIBRARY
 469 )