CMakeLists.txt

   1 #
   2 # SuperTux - root build script
   3 # Copyright (C) 2006 Christoph Sommer <christoph.sommer@2006.expires.deltadevelopment.de>
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  18 #
  19
  20
  21 #
  22 # INSTRUCTIONS:
  23 # -------------
  24 #
  25 # Create a directory build/ and change to it. Run
  26 #
  27 #   cmake ..
  28 #
  29 # This creates a set of Makefiles to build the project. Run
  30 #
  31 #   make
  32 #
  33
  34
  35 ## Project name to use as command prefix.
  36
  37 PROJECT(SUPERTUX)
  38
  39 ## Version, for display in title bar.
  40 ## Will add 'commit <hash>' to the end if git is available.
  41 SET(SUPERTUX_VERSION "0.3.4-GIT")
  42
  43 ### CMake configuration
  44
  45 # allow building with CMake 2.6. Set compatibility options. Use some bundled modules as a fallback
  46 CMAKE_MINIMUM_REQUIRED(VERSION 2.6)
  47 IF(COMMAND cmake_policy)
  48         CMAKE_POLICY(SET CMP0003 NEW)
  49 ENDIF(COMMAND cmake_policy)
  50
  51 SET(CMAKE_MODULE_PATH ${CMAKE_MODULE_PATH} ${CMAKE_CURRENT_SOURCE_DIR}/mk/cmake)
  52
  53 ## For autopackage
  54 OPTION(ENABLE_BINRELOC "Enable autopackage's BINRELOC features" OFF)
  55 SET(APPDATADIR "${CMAKE_INSTALL_PREFIX}/share/games/supertux2")
  56
  57 ## Check endianess
  58
  59 INCLUDE(TestBigEndian)
  60 TEST_BIG_ENDIAN(WORDS_BIGENDIAN)
  61
  62 ## Add lots of dependencies to compiler switches
  63
  64 SET(Boost_ADDITIONAL_VERSIONS "1.41" "1.41.0")
  65 FIND_PACKAGE(Boost REQUIRED)
  66 INCLUDE_DIRECTORIES(SYSTEM ${Boost_INCLUDE_DIR})
  67 LINK_DIRECTORIES(${Boost_LIBRARY_DIRS})
  68
  69 INCLUDE(FindPkgConfig)
  70 PKG_SEARCH_MODULE(SDL2 REQUIRED sdl2)
  71 PKG_SEARCH_MODULE(SDL2IMAGE REQUIRED SDL2_image>=2.0.0)
  72 SET(HAVE_SDL TRUE)
  73
  74 OPTION(ENABLE_OPENGL "Enable OpenGL support" ON)
  75 IF(ENABLE_OPENGL)
  76   FIND_PACKAGE(OpenGL)
  77   IF(OPENGL_FOUND)
  78     INCLUDE_DIRECTORIES(${OPENGL_INCLUDE_DIR})
  79     SET(HAVE_OPENGL TRUE)
  80   ENDIF(OPENGL_FOUND)
  81
  82   FIND_PACKAGE(GLEW)
  83   IF(GLEW_FOUND)
  84     INCLUDE_DIRECTORIES(${GLEW_INCLUDE_DIR})
  85   ENDIF(GLEW_FOUND)
  86 ENDIF(ENABLE_OPENGL)
  87
  88 FIND_PACKAGE(OpenAL REQUIRED)
  89 INCLUDE_DIRECTORIES(${OPENAL_INCLUDE_DIR})
  90
  91 FIND_PACKAGE(OggVorbis REQUIRED)
  92 INCLUDE_DIRECTORIES(${VORBIS_INCLUDE_DIR})
  93
  94 FIND_PACKAGE(PhysFS REQUIRED)
  95 INCLUDE_DIRECTORIES(${PHYSFS_INCLUDE_DIR})
  96
  97 FIND_PACKAGE(CURL)
  98 IF(CURL_FOUND)
  99   INCLUDE_DIRECTORIES(${CURL_INCLUDE_DIR})
 100   SET(HAVE_LIBCURL TRUE)
 101 ENDIF(CURL_FOUND)
 102
 103 #FIND_PACKAGE(ICONV REQUIRED)
 104 #INCLUDE_DIRECTORIES(${ICONV_INCLUDE_DIR})
 105 #LINK_LIBRARIES(${ICONV_LIBRARY})
 106
 107 ## Find revision of WC
 108 MARK_AS_ADVANCED(GIT_EXECUTABLE)
 109 FIND_PROGRAM(GIT_EXECUTABLE git)
 110
 111 IF(GIT_EXECUTABLE)
 112   ADD_CUSTOM_TARGET(gitversion ALL
 113                     ${CMAKE_COMMAND} -E echo "#ifndef VERSION_H" > "${CMAKE_BINARY_DIR}/version.h.tmp"
 114                     COMMAND ${CMAKE_COMMAND} -E echo "#define VERSION_H" >> "${CMAKE_BINARY_DIR}/version.h.tmp"
 115                     COMMAND ${CMAKE_COMMAND} >> "${CMAKE_BINARY_DIR}/version.h.tmp" -E echo_append "#define PACKAGE_VERSION \"${SUPERTUX_VERSION} commit "
 116                     COMMAND ${GIT_EXECUTABLE} rev-parse --sq HEAD >> "${CMAKE_BINARY_DIR}/version.h.tmp"
 117                     COMMAND ${CMAKE_COMMAND} >>  "${CMAKE_BINARY_DIR}/version.h.tmp" -E echo "\""
 118                     COMMAND ${CMAKE_COMMAND} -E echo "#endif" >>  "${CMAKE_BINARY_DIR}/version.h.tmp"
 119                     COMMAND ${CMAKE_COMMAND} -E copy_if_different "${CMAKE_BINARY_DIR}/version.h.tmp" "${CMAKE_BINARY_DIR}/version.h"
 120                     COMMAND ${CMAKE_COMMAND} -E remove "${CMAKE_BINARY_DIR}/version.h.tmp"
 121                     WORKING_DIRECTORY "${CMAKE_BINARY_DIR}"
 122                     COMMENT "Updating ${CMAKE_BINARY_DIR}/version.h..."
 123                     VERBATIM)
 124 ELSE(GIT_EXECUTABLE)
 125   ADD_CUSTOM_TARGET(gitversion ALL
 126                     ${CMAKE_COMMAND} -E echo "#ifndef VERSION_H" > "${CMAKE_BINARY_DIR}/version.h.tmp"
 127                     COMMAND ${CMAKE_COMMAND} -E echo "#define VERSION_H" >> "${CMAKE_BINARY_DIR}/version.h.tmp"
 128                     COMMAND ${CMAKE_COMMAND} >> "${CMAKE_BINARY_DIR}/version.h.tmp" -E echo "#define PACKAGE_VERSION \"${SUPERTUX_VERSION}\""
 129                     COMMAND ${CMAKE_COMMAND} -E echo "#endif" >>  "${CMAKE_BINARY_DIR}/version.h.tmp"
 130                     COMMAND ${CMAKE_COMMAND} -E copy_if_different "${CMAKE_BINARY_DIR}/version.h.tmp" "${CMAKE_BINARY_DIR}/version.h"
 131                     COMMAND ${CMAKE_COMMAND} -E remove "${CMAKE_BINARY_DIR}/version.h.tmp"
 132                     WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
 133                     COMMENT "Updating ${CMAKE_BINARY_DIR}/version.h..."
 134                     VERBATIM)
 135 ENDIF(GIT_EXECUTABLE)
 136
 137 SET_SOURCE_FILES_PROPERTIES(${CMAKE_BINARY_DIR}/version.h
 138                             PROPERTIES GENERATED true)
 139 SET_SOURCE_FILES_PROPERTIES(${CMAKE_CURRENT_SOURCE_DIR}/src/supertux/main.cpp
 140                             PROPERTIES OBJECT_DEPENDS "${CMAKE_BINARY_DIR}/version.h")
 141 SET_SOURCE_FILES_PROPERTIES(${CMAKE_CURRENT_SOURCE_DIR}/src/supertux/title_screen.cpp
 142                             PROPERTIES OBJECT_DEPENDS "${CMAKE_BINARY_DIR}/version.h")
 143 SET_SOURCE_FILES_PROPERTIES(${CMAKE_CURRENT_SOURCE_DIR}/src/addon/addon_manager.cpp
 144                             PROPERTIES OBJECT_DEPENDS "${CMAKE_BINARY_DIR}/version.h")
 145 ## Check platform-dependent build options
 146
 147 INCLUDE(ConfigureChecks)
 148
 149 ## Also execute instructions in external/squirrel/CMakeLists.txt
 150
 151 ADD_SUBDIRECTORY(${CMAKE_CURRENT_SOURCE_DIR}/external/squirrel)
 152
 153 ## Add squirrel lib dir to search path
 154
 155 LINK_DIRECTORIES(${CMAKE_CURRENT_SOURCE_DIR}/external/squirrel)
 156
 157 ## Some additional include paths
 158
 159 include_directories (${CMAKE_BINARY_DIR}/)
 160 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/src/)
 161 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/external/squirrel/include/)
 162 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/external/tinygettext/include/)
 163 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/external/findlocale/)
 164 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/external/obstack/)
 165 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/external/binreloc/)
 166
 167 ## MSVC Compatibility headers and definitions
 168
 169 IF(MSVC)
 170 include_directories (${CMAKE_CURRENT_SOURCE_DIR}/mk/msvc)
 171 ADD_DEFINITIONS(-D_USE_MATH_DEFINES -DNOMINMAX)
 172 ENDIF(MSVC)
 173
 174 ## Build list of sources for supertux binary
 175
 176 FILE(GLOB SUPERTUX_SOURCES_C RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} external/obstack/*.c external/findlocale/findlocale.c)
 177
 178 FILE(GLOB SUPERTUX_SOURCES_CXX RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} src/main.cpp src/*/*.cpp src/supertux/menu/*.cpp src/video/sdl/*.cpp)
 179
 180 FILE(GLOB TINYGETTEXT_SOURCES_CXX RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} external/tinygettext/src/*.cpp)
 181 SET_SOURCE_FILES_PROPERTIES(${TINYGETTEXT_SOURCES_CXX} PROPERTIES COMPILE_DEFINITIONS HAVE_SDL)
 182
 183 IF(HAVE_OPENGL)
 184   FILE(GLOB SUPERTUX_OPENGL_SOURCES RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} src/video/gl/*.cpp)
 185   SET(SUPERTUX_SOURCES_CXX ${SUPERTUX_SOURCES_CXX} ${SUPERTUX_OPENGL_SOURCES})
 186 ENDIF(HAVE_OPENGL)
 187
 188 ## Build miniswig and generate miniswig wrapper
 189
 190 OPTION(GENERATE_WRAPPER "Build miniswig and generate the wrapper" OFF)
 191 IF(GENERATE_WRAPPER)
 192   ADD_SUBDIRECTORY(tools/miniswig)
 193   ADD_CUSTOM_COMMAND(
 194     OUTPUT ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.cpp ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.hpp
 195     COMMAND cd ${CMAKE_CURRENT_SOURCE_DIR} && ${CMAKE_CXX_COMPILER}
 196     ARGS -x "c++" -E -CC -DSCRIPTING_API src/scripting/wrapper.interface.hpp -o ${CMAKE_CURRENT_BINARY_DIR}/miniswig.tmp -I${CMAKE_CURRENT_SOURCE_DIR}/src
 197     COMMAND tools/miniswig/miniswig
 198     ARGS --input miniswig.tmp --output-cpp ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.cpp --output-hpp ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.hpp --module supertux --select-namespace scripting
 199     DEPENDS tools/miniswig/miniswig
 200     IMPLICIT_DEPENDS CXX ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.interface.hpp
 201   )
 202 ENDIF(GENERATE_WRAPPER)
 203
 204 IF(NOT EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.cpp)
 205   SET(SUPERTUX_SOURCES_CXX ${SUPERTUX_SOURCES_CXX} ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.cpp)
 206 ENDIF(NOT EXISTS ${CMAKE_CURRENT_SOURCE_DIR}/src/scripting/wrapper.cpp)
 207
 208 ## Compile everything at once (roughly equivalent to cat *.cpp | gcc)
 209
 210 OPTION(COMPILE_AMALGATION "Compile all the files together at once (experimental)" OFF)
 211 IF(COMPILE_AMALGATION)
 212   FILE(WRITE ${CMAKE_CURRENT_BINARY_DIR}/amalgation.cpp "// Includes all source files of the project\n")
 213   FOREACH(ST_FILE ${SUPERTUX_SOURCES_CXX})
 214     FILE(RELATIVE_PATH CXX_FILE ${CMAKE_CURRENT_SOURCE_DIR}/src "${CMAKE_CURRENT_SOURCE_DIR}/${ST_FILE}")
 215     FILE(APPEND ${CMAKE_CURRENT_BINARY_DIR}/amalgation.cpp "#include \"${CXX_FILE}\"\n")
 216   ENDFOREACH(ST_FILE)
 217   ## Build instead of CXX sources
 218   SET(SUPERTUX_SOURCES_CXX ${CMAKE_CURRENT_BINARY_DIR}/amalgation.cpp)
 219 ELSE(COMPILE_AMALGATION)
 220   IF(EXISTS ${CMAKE_CURRENT_BINARY_DIR}/amalgation.cpp)
 221     FILE(REMOVE ${CMAKE_CURRENT_BINARY_DIR}/amalgation.cpp)
 222   ENDIF(EXISTS ${CMAKE_CURRENT_BINARY_DIR}/amalgation.cpp)
 223 ENDIF(COMPILE_AMALGATION)
 224
 225 ## Debug options
 226
 227 OPTION(WERROR "Stop on first compiler warning" OFF)
 228 OPTION(WARNINGS "Enable long list of warnings for compiler to check" OFF)
 229
 230 # http://www.guyrutenberg.com/2014/01/05/enabling-c11-c0x-in-cmake/
 231 include(CheckCXXCompilerFlag)
 232 CHECK_CXX_COMPILER_FLAG("-std=c++11" COMPILER_SUPPORTS_CXX11)
 233 if(COMPILER_SUPPORTS_CXX11)
 234         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")
 235 else(COMPILER_SUPPORTS_CXX11)
 236   CHECK_CXX_COMPILER_FLAG("-std=c++0x" COMPILER_SUPPORTS_CXX0X)
 237   if(COMPILER_SUPPORTS_CXX0X)
 238         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++0x")
 239   else(COMPILER_SUPPORTS_CXX0X)
 240         message(STATUS "The compiler ${CMAKE_CXX_COMPILER} has no C++11 support. Please use a different C++ compiler.")
 241   endif(COMPILER_SUPPORTS_CXX0X)
 242 endif(COMPILER_SUPPORTS_CXX11)
 243
 244
 245 IF(CMAKE_COMPILER_IS_GNUCC)
 246   SET(CMAKE_CXX_FLAGS_DEBUG "-O0 -g" CACHE STRING "Debug flags")
 247   SET(CMAKE_C_FLAGS_DEBUG "-O0 -g" CACHE STRING "Debug flags")
 248   SET(CMAKE_CXX_FLAGS_PROFILE "-pg" CACHE STRING "Profile flags")
 249   SET(CMAKE_C_FLAGS_PROFILE "-pg" CACHE STRING "Profile flags")
 250   SET(CMAKE_LD_FLAGS_PROFILE "-lgmon" CACHE STRING "Profile flags")
 251   ADD_DEFINITIONS(-Wall -Wextra -Wno-unused-parameter -funit-at-a-time)
 252   IF(WERROR)
 253     ADD_DEFINITIONS(-Werror)
 254   ELSE(WERROR)
 255     REMOVE_DEFINITIONS(-Werror)
 256   ENDIF(WERROR)
 257   IF(WARNINGS)
 258     # temporarily disabled:
 259     #   -Wsign-conversion -Wfloat-equal -Wconversion -Wundef -Wshadow -Wswitch-default
 260     #   -Wswitch-enum -Wsign-promo -Wcast-qual -Woverloaded-virtual -Wmissing-format-attribute
 261     #   -Wold-style-cast -Wpadded -Wabi
 262     # fails on MinGW:
 263     #   -ansi
 264     SET(SUPERTUX2_EXTRA_WARNING_FLAGS "-fdiagnostics-show-option -pedantic -Wno-long-long -Wcast-align -Wdisabled-optimization -Winit-self -Winvalid-pch -Wlogical-op -Wmissing-include-dirs -Wmissing-noreturn -Wpacked -Wredundant-decls -Wstack-protector -Winline -Wunsafe-loop-optimizations  -Wstrict-overflow=5 -Wformat=2 -Weffc++ -Wctor-dtor-privacy -Wstrict-null-sentinel -Wno-unused-parameter")
 265   ENDIF(WARNINGS)
 266 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 267
 268 ## If xgettext is available, generate messages.pot for sources
 269
 270 OPTION(GENERATE_MESSAGESPOT "Generate messages.pot files" OFF)
 271 IF(GENERATE_MESSAGESPOT)
 272   MARK_AS_ADVANCED(
 273     XGETTEXT_EXECUTABLE
 274   )
 275   FIND_PROGRAM(XGETTEXT_EXECUTABLE xgettext)
 276   IF(NOT XGETTEXT_EXECUTABLE)
 277     MESSAGE(STATUS "Warning: xgettext not found - will not update messages.pot")
 278   ELSE(NOT XGETTEXT_EXECUTABLE)
 279     MESSAGE(STATUS "Found xgettext: ${XGETTEXT_EXECUTABLE}")
 280
 281     SET(MESSAGES_POT_FILE ${CMAKE_CURRENT_SOURCE_DIR}/data/locale/messages.pot)
 282     ADD_CUSTOM_COMMAND(
 283       OUTPUT ${MESSAGES_POT_FILE}
 284       COMMAND ${XGETTEXT_EXECUTABLE}
 285       ARGS --keyword=_ --language=C++ --output=${MESSAGES_POT_FILE} ${SUPERTUX_SOURCES_CXX}
 286       DEPENDS ${SUPERTUX_SOURCES_CXX}
 287       WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 288       COMMENT "Generating POT file ${MESSAGES_POT_FILE}"
 289     )
 290     LIST(APPEND MESSAGES_POT_FILES ${MESSAGES_POT_FILE})
 291
 292     FILE(GLOB SUPERTUX_LEVEL_DIRS RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} data/levels/*)
 293     LIST(REMOVE_ITEM SUPERTUX_LEVEL_DIRS "data/levels/.svn")
 294     FOREACH(SUPERTUX_LEVEL_DIR ${SUPERTUX_LEVEL_DIRS})
 295       FILE(GLOB SUPERTUX_LEVELS RELATIVE ${CMAKE_CURRENT_SOURCE_DIR} ${SUPERTUX_LEVEL_DIR}/*.stl ${SUPERTUX_LEVEL_DIR}/*.stwm ${SUPERTUX_LEVEL_DIR}/*.txt)
 296
 297       ## Do not add target if SUPERTUX_LEVELS is empty. This is needed for cmake <=2.4
 298       IF(SUPERTUX_LEVELS)
 299       SET(MESSAGES_POT_FILE ${CMAKE_CURRENT_SOURCE_DIR}/${SUPERTUX_LEVEL_DIR}/messages.pot)
 300       ADD_CUSTOM_COMMAND(
 301         OUTPUT ${MESSAGES_POT_FILE}
 302         COMMAND ${XGETTEXT_EXECUTABLE}
 303         ARGS --keyword="_:1" --language=Lisp --force-po --sort-by-file "--output=${MESSAGES_POT_FILE}" ${SUPERTUX_LEVELS}
 304         DEPENDS ${SUPERTUX_LEVELS}
 305         WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 306         COMMENT "Generating POT file ${MESSAGES_POT_FILE}"
 307       )
 308       LIST(APPEND MESSAGES_POT_FILES ${MESSAGES_POT_FILE})
 309       ENDIF(SUPERTUX_LEVELS)
 310
 311     ENDFOREACH(SUPERTUX_LEVEL_DIR)
 312
 313     ADD_CUSTOM_TARGET(
 314       supertux2-messages ALL
 315       DEPENDS ${MESSAGES_POT_FILES}
 316     )
 317
 318   ENDIF(NOT XGETTEXT_EXECUTABLE)
 319 ENDIF(GENERATE_MESSAGESPOT)
 320
 321 ## Some additional compiler switches
 322 IF(CMAKE_COMPILER_IS_GNUCC)
 323   ADD_DEFINITIONS(-fno-strict-aliasing)
 324 ENDIF(CMAKE_COMPILER_IS_GNUCC)
 325
 326 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 327   ADD_DEFINITIONS(-DMACOSX)
 328 ENDIF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 329
 330
 331 ## On Windows, add an icon
 332
 333 IF(WIN32)
 334 #  SET(SUPERTUX_SOURCES_C ${SUPERTUX_SOURCES_C} ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.rc)
 335   IF(MINGW)
 336     ADD_CUSTOM_COMMAND(
 337     OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/supertux_rc.o
 338     COMMAND windres.exe -I${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons -i${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.rc -o ${CMAKE_CURRENT_BINARY_DIR}/supertux_rc.o)
 339     SET(SUPERTUX_SOURCES_C ${SUPERTUX_SOURCES_C} ${CMAKE_CURRENT_BINARY_DIR}/supertux_rc.o)
 340   ELSE(MINGW)
 341     SET(SUPERTUX_EXE_SRCS ${SUPERTUX_EXE_SRCS} supertux.rc)
 342   ENDIF(MINGW)
 343 ENDIF(WIN32)
 344
 345 ## Add binreloc.c if enabled
 346 IF(ENABLE_BINRELOC)
 347   SET(SUPERTUX_SOURCES_C ${SUPERTUX_SOURCES_C} ${CMAKE_CURRENT_SOURCE_DIR}/external/binreloc/binreloc.c)
 348 ENDIF(ENABLE_BINRELOC)
 349
 350
 351 ## Generate supertux executable in the right place
 352
 353 SET(EXECUTABLE_OUTPUT_PATH ${CMAKE_CURRENT_SOURCE_DIR})
 354
 355 ## Add target for supertux binary
 356
 357 ADD_LIBRARY(supertux2_c OBJECT ${SUPERTUX_SOURCES_C})
 358 ADD_EXECUTABLE(supertux2 ${CMAKE_BINARY_DIR}/version.h ${SUPERTUX_SOURCES_CXX} ${TINYGETTEXT_SOURCES_CXX} $<TARGET_OBJECTS:supertux2_c>)
 359 ADD_DEPENDENCIES(supertux2 gitversion)
 360 SET_TARGET_PROPERTIES(supertux2 PROPERTIES COMPILE_FLAGS "${SUPERTUX2_EXTRA_WARNING_FLAGS}")
 361
 362 ## Link supertux binary with squirrel and other libraries
 363
 364 TARGET_INCLUDE_DIRECTORIES(supertux2 SYSTEM PUBLIC ${SDL2_INCLUDE_DIRS})
 365 TARGET_INCLUDE_DIRECTORIES(supertux2 SYSTEM PUBLIC ${SDL2IMAGE_INCLUDE_DIRS})
 366 TARGET_LINK_LIBRARIES(supertux2 ${SDL2_LIBRARIES})
 367 TARGET_LINK_LIBRARIES(supertux2 ${SDL2IMAGE_LIBRARIES})
 368
 369 TARGET_LINK_LIBRARIES(supertux2 squirrel)
 370 TARGET_LINK_LIBRARIES(supertux2 ${OPENAL_LIBRARY})
 371 TARGET_LINK_LIBRARIES(supertux2 ${OGGVORBIS_LIBRARIES})
 372 TARGET_LINK_LIBRARIES(supertux2 ${PHYSFS_LIBRARY})
 373 IF(HAVE_OPENGL)
 374     TARGET_LINK_LIBRARIES(supertux2 ${OPENGL_LIBRARY})
 375     TARGET_LINK_LIBRARIES(supertux2 ${GLEW_LIBRARY})
 376 ENDIF(HAVE_OPENGL)
 377 IF(HAVE_LIBCURL)
 378   TARGET_LINK_LIBRARIES(supertux2 ${CURL_LIBRARY})
 379 ENDIF(HAVE_LIBCURL)
 380
 381 ## Install stuff
 382
 383 IF(WIN32 AND NOT UNIX)
 384
 385   SET(INSTALL_SUBDIR_BIN "." CACHE STRING "Installation subdir for binaries")
 386   SET(INSTALL_SUBDIR_SHARE "data" CACHE STRING "Installation subdir for data")
 387   SET(INSTALL_SUBDIR_DOC "." CACHE STRING "Installation subdir for docs")
 388
 389   FILE(GLOB DLLS "${CMAKE_CURRENT_SOURCE_DIR}/*.dll")
 390   INSTALL(FILES ${DLLS} DESTINATION ${INSTALL_SUBDIR_BIN})
 391
 392   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.png ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.ico DESTINATION ".")
 393
 394 ELSE(WIN32 AND NOT UNIX)
 395 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 396
 397   SET(INSTALL_SUBDIR_BIN "SuperTux.app/Contents/MacOS" CACHE STRING "Installation subdir for binaries")
 398   SET(INSTALL_SUBDIR_SHARE "SuperTux.app/Contents/Resources/data" CACHE STRING "Installation subdir for data")
 399   SET(INSTALL_SUBDIR_DOC "SuperTux.app/Contents/Resources" CACHE STRING "Installation subdir for docs")
 400
 401   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/tools/darwin/info.plist DESTINATION "SuperTux.app/Contents/")
 402   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/tools/darwin/receipt DESTINATION "SuperTux.app/Contents/_MASReceipt/")
 403
 404   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.png ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.icns DESTINATION "SuperTux.app/Contents/Resources/")
 405
 406 ELSE(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 407
 408   SET(INSTALL_SUBDIR_BIN "games" CACHE STRING "Installation subdir for binaries")
 409   SET(INSTALL_SUBDIR_SHARE "share/games/supertux2" CACHE STRING "Installation subdir for data")
 410   SET(INSTALL_SUBDIR_DOC "share/doc/supertux2" CACHE STRING "Installation subdir for docs")
 411
 412   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/supertux2.desktop DESTINATION "share/applications")
 413
 414   INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.png ${CMAKE_CURRENT_SOURCE_DIR}/data/images/engine/icons/supertux.xpm DESTINATION "share/pixmaps/")
 415
 416 ENDIF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 417 ENDIF(WIN32 AND NOT UNIX)
 418
 419 INSTALL(TARGETS supertux2 DESTINATION ${INSTALL_SUBDIR_BIN})
 420
 421 INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/INSTALL.md ${CMAKE_CURRENT_SOURCE_DIR}/README.md ${CMAKE_CURRENT_SOURCE_DIR}/COPYING ${CMAKE_CURRENT_SOURCE_DIR}/WHATSNEW.txt DESTINATION ${INSTALL_SUBDIR_DOC})
 422
 423 INSTALL(FILES ${CMAKE_CURRENT_SOURCE_DIR}/data/credits.txt DESTINATION ${INSTALL_SUBDIR_SHARE})
 424
 425 INSTALL(DIRECTORY data/images
 426                   data/fonts
 427                   data/levels
 428                   data/music
 429                   data/scripts
 430                   data/speech
 431                   data/sounds
 432                   data/locale
 433                                DESTINATION ${INSTALL_SUBDIR_SHARE} PATTERN ".svn" EXCLUDE)
 434
 435 ## Create config.h now that INSTALL_SUBDIR_* have been set.
 436
 437 configure_file(config.h.cmake ${CMAKE_BINARY_DIR}/config.h )
 438
 439
 440 ## CPack/Installation-specific stuff
 441
 442 INCLUDE(InstallRequiredSystemLibraries)
 443 SET(CPACK_PACKAGE_DESCRIPTION_SUMMARY "Jump'n'Run Game featuring Tux")
 444 SET(CPACK_PACKAGE_VENDOR "SuperTux Devel Team")
 445 SET(CPACK_PACKAGE_CONTACT "SuperTux Devel Team <supertux-devel@lists.lethargik.org>")
 446 SET(CPACK_DEBIAN_PACKAGE_NAME "supertux2")
 447 SET(CPACK_DEBIAN_PACKAGE_DEPENDS "libc6 (>= 2.5), libgcc1 (>= 1:4.1), libgl1-mesa-glx | libgl1, libogg0 (>= 1.1.3), libopenal0a, libphysfs-1.0-0, libsdl-image1.2 (>= 1.2.5), libsdl1.2debian (>= 1.2.10-1), libstdc++6 (>= 4.1.2), libvorbis0a (>= 1.1.2), libvorbisfile3 (>= 1.1.2), libcurl3 (>= 7.16)")
 448 SET(CPACK_DEBIAN_PACKAGE_DESCRIPTION "Classic 2D jump 'n run sidescroller with Tux\n SuperTux is a classic 2D jump 'n run sidescroller game in a similar\n style like the original SuperMario games. This release of SuperTux\n features 9 enemies, 26 playable levels, software and OpenGL rendering\n modes, configurable joystick and keyboard input, new music and\n completely redone graphics.\n .\n This is a development snapshot of SuperTux. It may suffer from\n critical bugs and has not been fully tested. \n .\n Homepage: http://supertux.lethargik.org/")
 449 SET(CPACK_DEBIAN_PACKAGE_SECTION "games")
 450 SET(CPACK_RPM_PACKAGE_NAME "supertux2")
 451 SET(CPACK_RPM_PACKAGE_DESCRIPTION "Classic 2D jump 'n run sidescroller with Tux\n SuperTux is a classic 2D jump 'n run sidescroller game in a similar\n style like the original SuperMario games. This release of SuperTux\n features 9 enemies, 26 playable levels, software and OpenGL rendering\n modes, configurable joystick and keyboard input, new music and\n completely redone graphics.\n .\n This is a development snapshot of SuperTux. It may suffer from\n critical bugs and has not been fully tested. \n .\n Homepage: http://supertux.lethargik.org/")
 452 SET(CPACK_RPM_PACKAGE_LICENSE "GNU General Public License (GPL)")
 453 SET(CPACK_RPM_PACKAGE_GROUP "Amusements/Games/Action/Arcade")
 454 IF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 455   # The OS X PackageMaker doesn't seem to like files with no extension
 456 ELSE(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 457   SET(CPACK_PACKAGE_DESCRIPTION_FILE "${CMAKE_CURRENT_SOURCE_DIR}/README.md")
 458   SET(CPACK_RESOURCE_FILE_LICENSE "${CMAKE_CURRENT_SOURCE_DIR}/COPYING")
 459 ENDIF(${CMAKE_SYSTEM_NAME} MATCHES "Darwin")
 460 SET(CPACK_PACKAGE_VERSION_MAJOR "0")
 461 SET(CPACK_PACKAGE_VERSION_MINOR "3")
 462 SET(CPACK_PACKAGE_VERSION_PATCH "4-GIT")
 463 SET(CPACK_PACKAGE_INSTALL_DIRECTORY "SuperTux ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 464 SET(CPACK_PACKAGE_EXECUTABLES "..\\\\supertux2" "SuperTux ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 465 IF(WIN32 AND NOT UNIX)
 466   SET(CPACK_NSIS_INSTALLED_ICON_NAME "..\\\\supertux2")
 467   SET(CPACK_NSIS_DISPLAY_NAME "SuperTux ${CPACK_PACKAGE_VERSION_MAJOR}.${CPACK_PACKAGE_VERSION_MINOR}.${CPACK_PACKAGE_VERSION_PATCH}")
 468 ELSE(WIN32 AND NOT UNIX)
 469 ENDIF(WIN32 AND NOT UNIX)
 470 INCLUDE(CPack)
 471
 472 # move some config clutter to the advanced section
 473 MARK_AS_ADVANCED(
 474   INSTALL_SUBDIR_BIN
 475   INSTALL_SUBDIR_SHARE
 476   INSTALL_SUBDIR_DOC
 477 )
 478
 479 MARK_AS_ADVANCED(
 480         CMAKE_BACKWARDS_COMPATIBILITY
 481         CMAKE_BUILD_TYPE
 482         CMAKE_INSTALL_PREFIX
 483         EXECUTABLE_OUTPUT_PATH
 484         LIBRARY_OUTPUT_PATH
 485         CMAKE_OSX_ARCHITECTURES
 486         CMAKE_OSX_SYSROOT
 487 )
 488
 489 MARK_AS_ADVANCED(
 490         ENABLE_BINRELOC
 491         APPDATADIR
 492 )
 493
 494 MARK_AS_ADVANCED(
 495         Boost_INCLUDE_DIR
 496         Boost_LIBRARIES
 497 )
 498
 499 MARK_AS_ADVANCED(
 500         SDL2_INCLUDE_DIRS
 501         SDL2_LIBRARIES
 502 )
 503
 504 MARK_AS_ADVANCED(
 505         SDL2IMAGE_INCLUDE_DIRS
 506         SDL2IMAGE_LIBRARIES
 507 )
 508
 509 MARK_AS_ADVANCED(
 510         OPENAL_INCLUDE_DIR
 511         OPENAL_LIBRARY
 512 )
 513
 514 MARK_AS_ADVANCED(
 515         OGG_LIBRARY
 516         VORBISENC_LIBRARY
 517         VORBISFILE_LIBRARY
 518         VORBIS_INCLUDE_DIR
 519         VORBIS_LIBRARY
 520 )
 521
 522 MARK_AS_ADVANCED(
 523         PHYSFS_INCLUDE_DIR
 524         PHYSFS_LIBRARY
 525 )